annotate lisp/misc.el @ 83037:03a73693678e

Merged in changes from CVS HEAD Patches applied: * [e-mail]--gnu-2004/emacs--cvs-trunk--0--patch-71 Update from CVS * [e-mail]--gnu-2004/emacs--cvs-trunk--0--patch-72 Update from CVS * [e-mail]--gnu-2004/emacs--cvs-trunk--0--patch-73 Update from CVS * [e-mail]--gnu-2004/emacs--cvs-trunk--0--patch-74 Update from CVS * [e-mail]--gnu-2004/emacs--cvs-trunk--0--patch-75 Update from CVS * [e-mail]--gnu-2004/emacs--cvs-trunk--0--patch-76 Update from CVS * [e-mail]--gnu-2004/emacs--cvs-trunk--0--patch-77 Update from CVS * [e-mail]--gnu-2004/emacs--cvs-trunk--0--patch-78 Update from CVS * [e-mail]--gnu-2004/emacs--cvs-trunk--0--patch-79 Update from CVS * [e-mail]--gnu-2004/emacs--cvs-trunk--0--patch-80 Update from CVS * [e-mail]--gnu-2004/emacs--cvs-trunk--0--patch-81 Update from CVS * [e-mail]--gnu-2004/emacs--cvs-trunk--0--patch-82 Update from CVS * [e-mail]--gnu-2004/emacs--cvs-trunk--0--patch-83 Update from CVS * [e-mail]--gnu-2004/emacs--cvs-trunk--0--patch-84 Add lisp/emacs-lisp/macroexp.el * [e-mail]--gnu-2004/emacs--cvs-trunk--0--patch-85 Update from CVS * [e-mail]--gnu-2004/emacs--cvs-trunk--0--patch-86 Update from CVS * [e-mail]--gnu-2004/emacs--cvs-trunk--0--patch-87 Update from CVS * [e-mail]--gnu-2004/emacs--cvs-trunk--0--patch-88 Update from CVS * [e-mail]--gnu-2004/emacs--cvs-trunk--0--patch-89 Update from CVS * [e-mail]--gnu-2004/emacs--cvs-trunk--0--patch-90 Update from CVS * [e-mail]--gnu-2004/emacs--cvs-trunk--0--patch-91 Update from CVS * [e-mail]--gnu-2004/emacs--cvs-trunk--0--patch-92 Update from CVS * [e-mail]--gnu-2004/emacs--cvs-trunk--0--patch-93 Update from CVS * [e-mail]--gnu-2004/emacs--cvs-trunk--0--patch-94 Update from CVS * [e-mail]--gnu-2004/emacs--cvs-trunk--0--patch-95 Update from CVS * [e-mail]--gnu-2004/emacs--cvs-trunk--0--patch-96 Update from CVS * [e-mail]--gnu-2004/emacs--cvs-trunk--0--patch-97 Update from CVS git-archimport-id: [e-mail]--2004/emacs--multi-tty--0--patch-77

;;; misc.el --- some nonstandard basic editing commands for Emacs

;; Copyright (C) 1989, 2003 Free Software Foundation, Inc.

;; Maintainer: FSF
;; Keywords: convenience

;; This file is part of GNU Emacs.

;; GNU Emacs is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation; either version 2, or (at your option)
;; any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs; see the file COPYING.  If not, write to the
;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
;; Boston, MA 02111-1307, USA.

;;; Commentary:

;;; Code:

(defun copy-from-above-command (&optional arg)
  "Copy characters from previous nonblank line, starting just above point.
Copy ARG characters, but not past the end of that line.
If no argument given, copy the entire rest of the line.
The characters copied are inserted in the buffer before point."
  (interactive "P")
  (let ((cc (current-column))
	n
	(string ""))
    (save-excursion
      (beginning-of-line)
      (backward-char 1)
      (skip-chars-backward "\ \t\n")
      (move-to-column cc)
      ;; Default is enough to copy the whole rest of the line.
      (setq n (if arg (prefix-numeric-value arg) (point-max)))
      ;; If current column winds up in middle of a tab,
      ;; copy appropriate number of "virtual" space chars.
      (if (< cc (current-column))
	  (if (= (preceding-char) ?\t)
	      (progn
		(setq string (make-string (min n (- (current-column) cc)) ?\ ))
		(setq n (- n (min n (- (current-column) cc)))))
	    ;; In middle of ctl char => copy that whole char.
	    (backward-char 1)))
      (setq string (concat string
			   (buffer-substring
			    (point)
			    (min (save-excursion (end-of-line) (point))
				 (+ n (point)))))))
    (insert string)))

;; Variation of `zap-to-char'.

(defun zap-up-to-char (arg char)
  "Kill up to, but not including ARG'th occurrence of CHAR.
Case is ignored if `case-fold-search' is non-nil in the current buffer.
Goes backward if ARG is negative; error if CHAR not found.
Ignores CHAR at point."
  (interactive "p\ncZap up to char: ")
  (let ((direction (if (>= arg 0) 1 -1)))
    (kill-region (point)
		 (progn
		   (forward-char direction)
		   (unwind-protect
		       (search-forward (char-to-string char) nil nil arg)
		     (backward-char direction))
		   (point)))))

;; These were added with an eye to making possible a more CCA-compatible
;; command set; but that turned out not to be interesting.

(defun mark-beginning-of-buffer ()
  "Set mark at the beginning of the buffer."
  (interactive)
  (push-mark (point-min)))

(defun mark-end-of-buffer ()
  "Set mark at the end of the buffer."
  (interactive)
  (push-mark (point-max)))

(defun upcase-char (arg)
  "Uppercasify ARG chars starting from point.  Point doesn't move."
  (interactive "p")
  (save-excursion
    (upcase-region (point) (progn (forward-char arg) (point)))))

(defun forward-to-word (arg)
  "Move forward until encountering the beginning of a word.
With argument, do this that many times."
  (interactive "p")
  (or (re-search-forward (if (> arg 0) "\\W\\b" "\\b\\W") nil t arg)
      (goto-char (if (> arg 0) (point-max) (point-min)))))

(defun backward-to-word (arg)
  "Move backward until encountering the end of a word.
With argument, do this that many times."
  (interactive "p")
  (forward-to-word (- arg)))

(provide 'misc)

;;; arch-tag: 908f7884-c19e-4388-920c-9cfa425e449b
;;; misc.el ends here