annotate msdos/sed1.inp @ 16996:2d67501c45b9

(eldoc-message-commands): Doc fixes. (eldoc-message): Make function, not macro. (eldoc-last-message): New internal variable. (eldoc-mode): Initialize it to nil. (eldoc-message): Use it. (eldoc-print-current-symbol-info): Use it. (eldoc-pre-command-refresh-echo-area): New function. (eldoc-mode): Put it on pre-command-hook if in XEmacs or using idle timers in Emacs. (eldoc-message-commands-table-size): New constant. (eldoc-add-command): Use it to initialize eldoc-message-commands. (eldoc-display-message-no-interference-p): New function. (eldoc-display-message-p): Use it. (eldoc-print-fnsym-args, eldoc-print-var-docstring): Arg sym no longer optional. Do not initialize arg if nil. (eldoc-forward-sexp-safe): Function deleted. (eldoc-beginning-of-sexp): New function. (eldoc-fnsym-in-current-sexp): Use eldoc-beginning-of-sexp. Use eldoc-current-symbol to get symbol at point. (eldoc-function-argstring-from-docstring-method-table): Forge docstrings for `and', `or', `list', `+', and `-'. (eldoc-add-command-completions): New function. (eldoc-add-command): Take list of args. No longer interactive. (eldoc-remove-command-completions): New function. (eldoc-remove-command): Take list of args. No longer interactive. top level: Initialize eldoc-message-commands using eldoc-add-command-completions.

# -sed1.inp-------------------------------------------------------------
# Configuration script for src/makefile
# ----------------------------------------------------------------------
#
# In case src/Makefile needs to rebuild `make-doc.exe' (might happen under
# Windows 95), make sure it gets built with commands that DOS
# understands (one command per line).
s/^#.*//
s/^[ \f\t][ \f\t]*$//
s/^ /	/
s/\.h\.in/.h-in/
s!^	\./temacs!	go32 temacs!
s!/bin/sh!command.com!
/^MAKE *=/s/^/# /
/^SHELL *=/s/^/# /
/^srcdir *=/s/@[^@\n]*@/./
/^VPATH *=/s/@[^@\n]*@/./
/^CC *=/s/@[^@\n]*@/gcc/
/^CPP *=/s/@[^@\n]*@/gcc -e/
/^CFLAGS *=/s/@[^@\n]*@/-O2 -g/
/^LN_S *=/s/@[^@\n]*@/ln -s/
/^M_FILE *=/s!@[^@\n]*@!m/intel386.h!
/^S_FILE *=/s!@[^@\n]*@!s/msdos.h!
/^@SET_MAKE@$/s/@SET_MAKE@//
/^.\${libsrc}make-docfile.*>/s!make-docfile!make-doc.exe -o ../etc/DOC!
/^.\${libsrc}make-doc/s!>.*$!!
/^\${libsrc}make-docfile:/c\
${libsrc}make-doc.exe:\
	cd ..\
	cd lib-src\
	$(MAKE) ${MFLAGS} make-docfile -W make-docfile.c\
	cd ..\
	cd src
/^	cd \${libsrc}; \${MAKE} \${MFLAGS} make-docfile/d
/\${libsrc}make-docfile/s/-docfile[ 	]/-doc.exe /
/^[ 	]*$/d
/^temacs:/s/prefix-args//
/^	#/d