annotate lisp/mh-e/mh-inc.el @ 65980:4520ae2624f2

* mh-init.el (mh-image-load-path): New function that adds the path to the MH-E images to the image-load-path or load-path depending on the version of Emacs. * mh-customize.el: Call mh-image-load-path just before mh-tool-bar-define so that the toolbar images can be found. * mh-customize.el (mh-invisible-header-fields-internal) (mh-invisible-header-fields-internal): Add Received-SPF header and X-Gmail- prefixes seen from Gmail. Jeffrey C Honig <[e-mail]> * mh-customize.el (mh-customize): Use customization group mh-e. * mh-e.el (desktop-buffer-mode-handlers): Only add to this list if the variable exists. Not present pre-version 22. (Version, mh-version): Added +cvs to version. * mh-unit.el (mh-unit): Changed lm-verify test to Emacs 22. * Makefile: Incorporated ideas from Clemens Fruhwirth to generalize mh-loaddefs.el to make it work for both GNU Emacs and XEmacs. (EMACS_OPTIONS, XEMACS_OPTIONS): Use double-dash for all long options. (EMACS_LOADDEFS_COOKIE): New variable for generate-autoload-cookie setting. Obsoletes XEMACS_LOADDEFS_COOKIE. (EMACS_EXPORT_MH_LOADDEFS): New variable for GNU Emacs commands to rebuild mh-loaddefs.el. (XEMACS_EXPORT_MH_LOADDEFS): New variable for XEmacs commands to rebuild mh-loaddefs.el. Obsoletes XEMACS_LOADDEFS_FILE and XEMACS_LOADDEFS_PKG_NAME. (MH-E-LOADDEFS-SRC): New variable which is set to $(MH-E-SRC) on GNU Emacs, and adds $(MH-E-XEMACS-SRC) on XEmacs. (all): Modify EMACS_EXPORT_MH_LOADDEFS and MH-E-LOADDEFS-SRC on XEMacs. (mh-loaddefs.el): Now depends on $(MH-E-LOADDEFS-SRC) and has generic compile command that works on both GNU Emacs XEmacs. (xemacs): Depend on autoloads instead of deleted loaddefs-xemacs. (loaddefs-xemacs): Deleted. * mh-comp.el (mh-font-lock-field-data): Fix a bug where the function would return t but match-data was being set to nil (closes SF #1241017). Satyaki Das <[e-mail]>. * mh-comp.el (mh-insert-auto-fields): Inset identity regardless of whether one was already set, since if one used a default identity it would never be overridden. Peter S Galbraith <[e-mail]> * mh-init.el (mh-path): Use customization group mh-e. Thanks to Peter Whaite for these patches (closes SF #1213716). * mh-mime.el (mh-compose-forward): Only use mh-sent-from-msg as a default message if it's a number (as is done elsewhere). Otherwise, an error is thrown if this function is called from a draft created by mh-forward since this variable is a list. Also added a space after the "Messages [%s]:" prompt. * mh-mime.el (mh-compose-forward): Allow insertion of multiple forwarded messages by range (including sequences). For the sent folder the default message presented is the sent message. For other folders, the default message is "cur", if it exists. Jeffrey C Honig <[e-mail]>

;;; mh-inc.el --- MH-E `inc' and separate mail spool handling
;;
;; Copyright (C) 2003, 2004 Free Software Foundation, Inc.

;; Author: Peter S. Galbraith <[e-mail]>
;; Maintainer: Bill Wohler <[e-mail]>
;; Keywords: mail
;; See: mh-e.el

;; This file is part of GNU Emacs.

;; GNU Emacs is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation; either version 2, or (at your option)
;; any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs; see the file COPYING.  If not, write to the
;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
;; Boston, MA 02110-1301, USA.

;;; Commentary:

;;  Support for inc. In addition to reading from the system mailbox, inc can
;;  also be used to incorporate mail from multiple spool files into separate
;;  folders. See `C-h v mh-inc-spool-list'.

;;; Change Log:

;;; Code:

(eval-when-compile (require 'mh-acros))
(mh-require-cl)

(defvar mh-inc-spool-map (make-sparse-keymap)
  "Keymap for MH-E's mh-inc-spool commands.")

(defvar mh-inc-spool-map-help nil
  "Help text to for `mh-inc-spool-map'.")

(define-key mh-inc-spool-map "?"
  '(lambda ()
     (interactive)
     (if mh-inc-spool-map-help
         (let ((mh-help-messages (list (list nil mh-inc-spool-map-help))))
           (mh-help))
       (mh-ephem-message
        "There are no keys defined yet.  Customize `mh-inc-spool-list'"))))

(defun mh-inc-spool-generator (folder spool)
  "Create a command to inc into FOLDER from SPOOL file."
  (let ((folder1 (make-symbol "folder"))
        (spool1 (make-symbol "spool")))
    (set folder1 folder)
    (set spool1 spool)
    (setf (symbol-function (intern (concat "mh-inc-spool-" folder)))
          `(lambda ()
             ,(format "Inc spool file %s into folder %s" spool folder)
             (interactive)
             (mh-inc-folder ,spool1 (concat "+" ,folder1))))))

(defun mh-inc-spool-def-key (key folder)
  "Define a KEY in `mh-inc-spool-map' to inc FOLDER and collect help string."
  (when (not (= 0 key))
    (define-key mh-inc-spool-map (format "%c" key)
       (intern (concat "mh-inc-spool-" folder)))
    (setq mh-inc-spool-map-help (concat mh-inc-spool-map-help "["
                                        (char-to-string key)
                                        "] inc " folder " folder\n"))))

;; Avoid compiler warning
(defvar mh-inc-spool-list)

(defun mh-inc-spool-make ()
  "Make all commands and defines keys for contents of `mh-inc-spool-list'."
  (when mh-inc-spool-list
    (setq mh-inc-spool-map-help nil)
    (loop for elem in mh-inc-spool-list
          do (let ((spool (nth 0 elem))
                   (folder (nth 1 elem))
                   (key (nth 2 elem)))
               (progn
                 (mh-inc-spool-generator folder spool)
                 (mh-inc-spool-def-key key folder))))))

;;;###mh-autoload
(defun mh-inc-spool-list-set (symbol value)
  "Set-default SYMBOL to VALUE to update the `mh-inc-spool-list' variable.
Also rebuilds the user commands.
This is called after 'customize is used to alter `mh-inc-spool-list'."
  (set-default symbol value)
  (mh-inc-spool-make))

(provide 'mh-inc)

;;; Local Variables:
;;; indent-tabs-mode: nil
;;; sentence-end-double-space: nil
;;; End:

;;; arch-tag: 3713cf2a-6082-4cb4-8ce2-99d9acaba835
;;; mh-inc.el ends here