annotate msdos/sedleim.inp @ 24354:6a438ef0b573

Set version to 1.4.1. Changed mail address to [e-mail]. Mention the mailin listg [e-mail]. (sql-input-ring-separator): Doc fix. (sql-mode-syntax-table): double-dash starts comments is defined as ". 56" instead of ". 12b" for XEmacs. (sql-stop, sql-interactive-mode): Doc fixes. (sql-postgres): Queries for database and server, not just one. (sql-set-sqli-buffer): sql-set-sqli-hook must be quoted.

# -sedleim.inp-----------------------------------------------------------
# Configuration script for leim/Makefile under DJGPP v2.x
# ----------------------------------------------------------------------
/^SHELL *=/c\
SHELL=/dos/command\
MAKESHELL=/dos/command

/^version=/d
/^prefix=/d
/^datadir=/s|@datadir@|../..|
/^srcdir=/s|@srcdir@|.|

/^INSTALLDIR=/c\
INSTALLDIR=.

/^	cd ../c\
	${MAKE} -C ../src ${MFLAGS} emacs

/else make quail/c\
	if not exist quail\\nul make quail

/^leim-list.el:/,/^$/ {
	/^	if/d
	/^	else/,/^	fi/d
	s|	 *|	|
	/^	--eval/,/; \\$/s|\; \\||
}

/^install:/,/^$/c\
install: all\

/^	ELC=/,/^	rm -f/c\
	rm -f ${TIT} $(shell echo ${TIT} | sed 's/\.el/.elc/g') leim-list.elc

/^	if test -f/d