annotate lisp/elide-head.el @ 58556:8ff63943e93e

(bibtex-sort-entry-class) (bibtex-comment-start): Use defcustom. (bibtex-entry-field-alist): Use nil if initial content of the field is undefined. Fix docstring. (bibtex-parse-keys-timeout, bibtex-autokey-additional-names) (bibtex-generate-autokey, bibtex-parse-buffers-stealthily) (bibtex-mode, bibtex-field-list, bibtex-entry-updat) (bibtex-autofill-entry, bibtex-entry-index, bibtex-next-field): Fix docstring. (bibtex-autokey-title-terminators): Use only one regexp. (bibtex-string-maybe-empty-head): New variable. (bibtex-remove-delimiters-string): New function. (bibtex-text-in-field-bounds, bibtex-text-in-string): Use bibtex-remove-delimiters-string. (bibtex-progress-message, bibtex-field-left-delimiter) (bibtex-field-right-delimiter, bibtex-entry-left-delimiter) (bibtex-entry-right-delimiter, bibtex-search-entry): Use eq. (bibtex-insert-kill): Rename from `bibtex-insert-current-kill'. Simplify. (bibtex-format-entry): Use save-excursion for inherited booktitle. Use eq and bibtex-remove-delimiters-string. For end markers use insertion type so that marker stays after inserted text. (bibtex-autokey-get-names): Return empty string if name is missing. (bibtex-autokey-demangle-name): Call bibtex-autokey-abbrev before calling bibtex-autokey-name-case-convert. (bibtex-autokey-demangle-title): Call bibtex-autokey-titleword-case-convert. Remove call to bibtex-autokey-titleword-case-convert from bibtex-autokey-get-title. (bibtex-global-key-alist, bibtex-read-string-key): New functions. (bibtex-read-key): New optional arg global. (bibtex-files-expand): New optional arg force. (bibtex-complete-string-cleanup): Expansion of abbrev can be absent. (bibtex-complete-crossref-cleanup): Rename from bibtex-complete-key-cleanup. Simplify code. (bibtex-copy-summary-as-kill): Remove arg key. Operate on current entry. Use looking-at. (bibtex-button): Add docstring. (bibtex-entry): Simplify. (bibtex-make-field): Replace optional arg called-by-yank with more specific args move and interactive. (bibtex-end-of-entry): Use forward-sexp. (bibtex-find-entry-globally): Remove. (bibtex-find-crossref): Allow for crossref key located in other buffer. Bound to C-c C-x. (bibtex-find-entry): New optional args global and display. (bibtex-find-text): Fix docstring. Remove arg as-if-interactive. (bibtex-validate): Use arg force of bibtex-files-expand. (bibtex-clean-entry): Bugfix, clean string entries properly. Always keep point at beginning of entry. (bibtex-complete): Bugfix. Handle string entries properly. Call cleanup functions only if needed. (bibtex-String): Use bibtex-read-string-key. (bibtex-url): Use bibtex-remove-delimiters-string. Do not alter case of replacement text.

;;; elide-head.el --- hide headers in files

;; Copyright (C) 1999 Free Software Foundation, Inc.

;; Author: Dave Love <[e-mail]>
;; Keywords: outlines tools

;; This file is part of GNU Emacs.

;; GNU Emacs is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation; either version 2, or (at your option)
;; any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs; see the file COPYING.  If not, write to the
;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
;; Boston, MA 02111-1307, USA.

;;; Commentary:

;; Functionality for eliding boilerplate text (normally copyright
;; notices) in file headers to avoid clutter when you know what it
;; says.
;;
;; `elide-head-headers-to-hide' controls what is elided by the command
;; `elide-head'.  A buffer-local invisible overlay manages the
;; elision.

;; You might add `elide-head' to appropriate major mode hooks or to
;; `find-file-hook'.  Please do not do this in site init files.  If
;; you do, information may be hidden from users who don't know it
;; already.

;; Note that `hs-minor-mode' will do a similar job by default, but
;; it's not selective about what leading commentary it hides.

;; Inspired by jwz's hide-copyleft.el, for which we don't have an
;; assignment.

;;; Code:

(defgroup elide-head nil
  "Eliding copyright headers and the like in source files."
  :version "21.1"
  :prefix "elide-head"
  :group 'tools)

(defcustom elide-head-headers-to-hide
  '(("is free software; you can redistribute it" . ; GNU boilerplate
     "Boston, MA 02111-1307, USA\\.")
    ("The Regents of the University of California\\.  All rights reserved\\." .
     "SUCH DAMAGE\\.")			; BSD
    ("Permission is hereby granted, free of charge" . ; X11
     "authorization from the X Consortium\\."))
  "Alist of regexps defining start end end of text to elide.

The cars of elements of the list are searched for in order.  Text is
elided with an invisible overlay from the end of the line where the
first match is found to the end of the match for the corresponding
cdr."
  :group 'elide-head
  :type '(alist :key-type  (string :tag "Start regexp")
		:value-type (string :tag "End regexp")))

(defvar elide-head-overlay nil)
(make-variable-buffer-local 'elide-head-overlay)

;;;###autoload
(defun elide-head (&optional arg)
  "Hide header material in buffer according to `elide-head-headers-to-hide'.

The header is made invisible with an overlay.  With a prefix arg, show
an elided material again.

This is suitable as an entry on `find-file-hook' or appropriate mode hooks."
  (interactive "P")
  (if arg
      (elide-head-show)
    (save-excursion
      (save-restriction
	(let ((rest elide-head-headers-to-hide)
	      beg end)
	  (widen)
	  (goto-char (point-min))
	  (while rest
	    (save-excursion
	      (when (re-search-forward (caar rest) nil t)
		(setq beg (point))
		(when (re-search-forward (cdar rest) nil t)
		  (setq end (point-marker)
			rest nil))))
	    (if rest (setq rest (cdr rest))))
	  (if (not (and beg end))
	      (if (interactive-p)
		  (message "No header found"))
	    (goto-char beg)
	    (end-of-line)
	    (if (overlayp elide-head-overlay)
		(move-overlay elide-head-overlay (point-marker) end)
	      (setq elide-head-overlay (make-overlay (point-marker) end)))
	    (overlay-put elide-head-overlay 'invisible t)
	    (overlay-put elide-head-overlay 'evaporate t)
	    (overlay-put elide-head-overlay 'after-string "...")))))))

(defun elide-head-show ()
  "Show a header elided current buffer by \\[elide-head]."
  (interactive)
  (if (and (overlayp elide-head-overlay)
	   (overlay-buffer elide-head-overlay))
      (delete-overlay elide-head-overlay)
    (if (interactive-p)
	(message "No header hidden"))))

(provide 'elide-head)

;;; arch-tag: a00e6b5b-6aeb-45b1-b734-63e23df80928
;;; elide-head.el ends here