annotate lisp/find-cmd.el @ 110523:a5ad4f188e19

Synch Semantic to CEDET 1.0. Move CEDET ChangeLog entries to new file lisp/cedet/ChangeLog. * semantic.el (semantic-version): Update to 2.0. (semantic-mode-map): Add "," and "m" bindings. (navigate-menu): Update. * semantic/symref.el (semantic-symref-calculate-rootdir): New function. (semantic-symref-detect-symref-tool): Use it. * semantic/symref/grep.el (semantic-symref-grep-shell): New var. (semantic-symref-perform-search): Use it. Calculate root dir with semantic-symref-calculate-rootdir. (semantic-symref-derive-find-filepatterns): Improve error message. * semantic/symref/list.el (semantic-symref-results-mode-map): New bindings. (semantic-symref-auto-expand-results): New option. (semantic-symref-results-dump): Obey auto-expand. (semantic-symref-list-expand-all, semantic-symref-regexp) (semantic-symref-list-contract-all) (semantic-symref-list-map-open-hits) (semantic-symref-list-update-open-hits) (semantic-symref-list-create-macro-on-open-hit) (semantic-symref-list-call-macro-on-open-hits): New functions. (semantic-symref-list-menu-entries) (semantic-symref-list-menu): New vars. (semantic-symref-list-map-open-hits): Move cursor to beginning of match before calling the mapped function. * semantic/doc.el (semantic-documentation-comment-preceeding-tag): Do nothing if the mode doesn't provide comment-start-skip. * semantic/scope.el (semantic-analyze-scope-nested-tags-default): Strip duplicates. (semantic-analyze-scoped-inherited-tag-map): Take the tag we are looking for as part of the scoped tags list. * semantic/html.el (semantic-default-html-setup): Add senator-step-at-tag-classes. * semantic/decorate/include.el (semantic-decoration-on-unknown-includes): Change light bgcolor. (semantic-decoration-on-includes-highlight-default): Check that the include tag has a postion. * semantic/complete.el (semantic-collector-local-members): (semantic-complete-read-tag-local-members) (semantic-complete-jump-local-members): New class and functions. (semantic-complete-self-insert): Save excursion before completing. * semantic/analyze/complete.el (semantic-analyze-possible-completions-default): If no completions are found, return the raw by-name-only completion list. Add FLAGS arguments. Add support for 'no-tc (type constraint) and 'no-unique, or no stripping duplicates. (semantic-analyze-possible-completions-default): Add FLAGS arg. * semantic/util-modes.el (semantic-stickyfunc-show-only-functions-p): New option. (semantic-stickyfunc-fetch-stickyline): Don't show stickytext for the very first line in a buffer. * semantic/util.el (semantic-hack-search) (semantic-recursive-find-nonterminal-by-name) (semantic-current-tag-interactive): Deleted. (semantic-describe-buffer): Fix expand-nonterminal. Add lex-syntax-mods, type relation separator char, and command separation char. (semantic-sanity-check): Only message if called interactively. * semantic/tag.el (semantic-tag-deep-copy-one-tag): Copy the :filename property and the tag position. * semantic/lex-spp.el (semantic-lex-spp-lex-text-string): Add recursion limit. * semantic/imenu.el (semantic-imenu-bucketize-type-members): Make this buffer local, not the obsoleted variable. * semantic/idle.el: Add breadcrumbs support. (semantic-idle-summary-current-symbol-info-default) (semantic-idle-tag-highlight) (semantic-idle-completion-list-default): Use semanticdb-without-unloaded-file-searches for speed, and to conform to the controls that specify if the idle timer is supposed to be parsing unparsed includes. (semantic-idle-symbol-highlight-face) (semantic-idle-symbol-maybe-highlight): Rename from *-summary-*. Callers changed. (semantic-idle-work-parse-neighboring-files-flag): Default to nil. (semantic-idle-work-update-headers-flag): New var. (semantic-idle-work-for-one-buffer): Use it. (semantic-idle-local-symbol-highlight): Rename from semantic-idle-tag-highlight. (semantic-idle-truncate-long-summaries): New option. * semantic/ia.el (semantic-ia-cache) (semantic-ia-get-completions): Deleted. Callers changed. (semantic-ia-show-variants): New command. (semantic-ia-show-doc): If doc is empty, don't make a temp buffer. (semantic-ia-show-summary): If there isn't anything to show, say so. * semantic/grammar.el (semantic-grammar-create-package): Save the buffer even in batch mode. * semantic/fw.el (semanticdb-without-unloaded-file-searches): New macro. * semantic/dep.el (semantic-dependency-find-file-on-path): Fix case dereferencing ede-object when it is a list. * semantic/db-typecache.el (semanticdb-expand-nested-tag) (semanticdb-typecache-faux-namespace): New functions. (semanticdb-typecache-file-tags) (semanticdb-typecache-merge-streams): Use them. (semanticdb-typecache-file-tags): When deriving tags from a file, give the mode a chance to monkey with the tag copy. (semanticdb-typecache-find-default): Wrap find in save-excursion. (semanticdb-typecache-find-by-name-helper): Merge found names down. * semantic/db-global.el (semanticdb-enable-gnu-global-in-buffer): Don't show messages if GNU Global is not available and we don't want to throw an error. * semantic/db-find.el (semanticdb-find-result-nth-in-buffer): When trying to normalize the tag to a buffer, don't error if set-buffer method doesn't exist. * semantic/db-file.el (semanticdb-save-db): Simplify msg. * semantic/db.el (semanticdb-refresh-table): If forcing a refresh on a file not in a buffer, use semantic-find-file-noselect and delete the buffer after use. (semanticdb-current-database-list): When calculating root via hooks, force it through true-filename and skip the list of possible roots. * semantic/ctxt.el (semantic-ctxt-imported-packages): New. * semantic/analyze/debug.el (semantic-analyzer-debug-insert-tag): Reset standard output to current buffer. (semantic-analyzer-debug-global-symbol) (semantic-analyzer-debug-missing-innertype): Change "prefix" to "symbol" in messages. * semantic/analyze/refs.el: (semantic-analyze-refs-impl) (semantic-analyze-refs-proto): When calculating value, make sure the found tag is 'similar' to the originating tag. (semantic--analyze-refs-find-tags-with-parent): Attempt to identify matches via imported symbols of parents. (semantic--analyze-refs-full-lookup-with-parents): Do a deep search during the brute search. * semantic/analyze.el (semantic-analyze-find-tag-sequence-default): Be robust to calculated scopes being nil. * semantic/bovine/c.el (semantic-c-describe-environment): Add project macro symbol array. (semantic-c-parse-lexical-token): Add recursion limit. (semantic-ctxt-imported-packages, semanticdb-expand-nested-tag): New overrides. (semantic-expand-c-tag-namelist): Split a full type from a typedef out to its own tag. (semantic-expand-c-tag-namelist): Do not split out a typedef'd inline type if it is an anonymous type. (semantic-c-reconstitute-token): Use the optional initializers as a clue that some function is probably a constructor. When defining the type of these constructors, split the parent name, and use only the class part, if applicable. * semantic/bovine/c-by.el: * semantic/wisent/python-wy.el: Regenerate.

;;; find-cmd.el --- Build a valid find(1) command with sexps

;; Copyright (C) 2008, 2009, 2010 Free Software Foundation, Inc.

;; Author: Philip Jackson <[e-mail]>
;; Version: 0.6

;; This file is part of GNU Emacs.

;; GNU Emacs is free software: you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.

;;; Commentary:

;; With this module you can build up a (hopefully) valid find(1)
;; string ready for the command line.  For example:

;; (find-cmd '(prune (name ".svn" ".git" ".CVS"))
;;           '(and (or (name "*.pl" "*.pm" "*.t")
;;                     (mtime "+1"))
;;                 (fstype "nfs" "ufs"))))

;; will become (un-wrapped):

;;     "find '/home/phil/' \\( \\( -name '.svn' -or -name '.git' -or
;;      -name '.CVS' \\) -prune -or -true \\) \\( \\( \\( -name '*.pl'
;;      -or -name '*.pm' -or -name '*.t' \\) -or -mtime '+1' \\) -and \\(
;;      -fstype 'nfs' -or -fstype 'ufs' \\) \\)"

;;; Code:

(defconst find-constituents
  '((and . find-and)
    (not . find-not)
    (or  . find-or)

    (a . find-and)
    (n . find-not)
    (o . find-or)

    (prune . find-prune)

    ;; switches
    (L . (0))
    (P . (0))
    (H . (0))

    ;; generic tests
    (amin       . (1))
    (anewer     . (1))
    (atime      . (1))
    (cmin       . (1))
    (cnewer     . (1))
    (ctime      . (1))
    (empty      . (0))
    (false      . (0))
    (fstype     . (1))
    (gid        . (1))
    (group      . (1))
    (ilname     . (1))
    (iname      . (1))
    (inum       . (1))
    (iwholename . (1))
    (iregex     . (1))
    (links      . (1))
    (lname      . (1))
    (mmin       . (1))
    (mtime      . (1))
    (name       . (1))
    (newer      . (1))
    (nouser     . (0))
    (nogroup    . (0))
    (path       . (1))
    (perm       . (0))
    (regex      . (1))
    (wholename  . (1))
    (size       . (1))
    (true       . (0))
    (type       . (1))
    (uid        . (1))
    (used       . (1))
    (user       . (1))
    (xtype      . (nil))

    ;; normal options (always true)
    (depth                 . (0))
    (maxdepth              . (1))
    (mindepth              . (1))
    (mount                 . (0))
    (noleaf                . (0))
    (xdev                  . (0))
    (ignore_readdir_race   . (0))
    (noignore_readdir_race . (0))

    ;; actions
    (delete  . (0))
    (print0  . (0))
    (printf  . (1))
    (fprintf . (2))
    (print   . (0))
    (fprint0 . (1))
    (fprint  . (1))
    (ls      . (0))
    (fls     . (1))
    (prune   . (0))
    (quit    . (0))

    ;; these need to be terminated with a ;
    (exec    . (1 find-command t))
    (ok      . (1 find-command t))
    (execdir . (1 find-command t))
    (okdir   . (1 find-command t)))
  "Holds details of each of the find options.
The car of each alist is the name.  The cdr is minimum args, the
function used to join many occurrences of the argument together,
and whether or not to leave quotes off the string (non-nil means
the string will be quoted).")

;;;###autoload
(defun find-cmd (&rest subfinds)
  "Initiate the building of a find command.
For example:

\(find-cmd '\(prune \(name \".svn\" \".git\" \".CVS\"\)\)
          '\(and \(or \(name \"*.pl\" \"*.pm\" \"*.t\"\)
                    \(mtime \"+1\"\)\)
                \(fstype \"nfs\" \"ufs\"\)\)\)\)

`default-directory' is used as the initial search path.  The
result is a string that should be ready for the command line."
  (concat
   "find " (shell-quote-argument (expand-file-name default-directory)) " "
           (cond
            ((cdr subfinds)
             (mapconcat 'find-to-string subfinds ""))
            (t
             (find-to-string (car subfinds))))))

(defun find-and (form)
  "And FORMs together, so:
  \(and \(mtime \"+1\"\) \(name \"something\"\)\)
will produce:
  find . \\\( -mtime '+1' -and -name 'something' \\\)"
  (if (< (length form) 2)
      (find-to-string (car form))
      (concat "\\( "
              (mapconcat 'find-to-string form "-and ")
              "\\) ")))

(defun find-or (form)
  "Or FORMs together, so:
  \(or \(mtime \"+1\"\) \(name \"something\"\)\)
will produce:
  find . \\\( -mtime '+1' -or -name 'something' \\\)"
  (if (< (length form) 2)
      (find-to-string (car form))
      (concat "\\( "
              (mapconcat 'find-to-string form "-or ")
              "\\) ")))

(defun find-not (form)
  "Or FORMs together and prefix with a -not, so:
  \(not \(mtime \"+1\"\) \(name \"something\"\)\)
will produce:
  -not \\\( -mtime '+1' -or -name 'something' \\\)
If you wanted the FORMs -and(ed) together instead then this would
suffice:
  \(not \(and \(mtime \"+1\"\) \(name \"something\"\)\)\)"
  (concat "-not " (find-or (mapcar 'find-to-string form))))

(defun find-prune (form)
  "-or together FORMs postfix '-prune' and then -or that with a
-true, so:
  \(prune \(name \".svn\" \".git\"\)\) \(name \"*.pm\"\)
will produce (unwrapped):
  \\\( \\\( \\\( -name '.svn' -or -name '.git' \\\) /
  -prune -or -true \\\) -and -name '*.pm' \\\)"
  (find-or
   (list
    (concat (find-or (mapcar 'find-to-string form)) (find-generic "prune"))
    (find-generic "true"))))

(defun find-generic (option &optional oper argcount args dont-quote)
  "Allow an arbitrary string to be used as a form.
OPTION is the name of the form, OPER is the function used to either
OR or AND multiple results together.  ARGCOUNT is the minimum of
args that OPTION can receive and ARGS are the arguments for OPTION.
If DONT-QUOTE is non-nil, arguments are quoted for passing them to
the shell."
  (when (and (numberp argcount) (< (length args) argcount))
    (error "'%s' needs at least %d arguments" option argcount))
  (let ((oper (or oper 'find-or)))
    (if (and args (length args))
        (funcall oper (mapcar (lambda (x)
                                (concat "-" option
                                        (if dont-quote
                                            (concat " " x " ")
                                            (concat " "
                                                    (shell-quote-argument x)
                                                    " "))))
                              args))
        (concat "-" option " "))))

(defun find-command (form)
  "For each item in FORM add a terminating semi-colon and turn
them into valid switches.  The result is -and(ed) together."
  (find-and (mapcar (lambda (x)
                      (concat (find-to-string x) "\\; "))
                    form)))

(defun find-to-string (form)
  "Parse FORM to produce a set of valid find arguments."
  (cond
    ((stringp form)
     form)
    ((consp form)
     (let ((option (cdr (assoc (car form) find-constituents))))
       (cond
         ((and (symbolp option) (fboundp option))
          (funcall option (cdr form)))
         ((consp option)
          (let ((option (symbol-name (car form)))
                (argcnt (car option))
                (oper (cadr option))
                (dont-quote (car (cddr option))))
            (find-to-string
             (find-generic option oper argcnt (cdr form) dont-quote))))
         (t
          (error "Sorry I don't know how to handle '%s'" (car form))))))))

(provide 'find-cmd)

;; arch-tag: 9687fd9e-4e90-4022-864a-f904526e2046
;;; find-cmd.el ends here