annotate lisp/talk.el @ 83025:c66ebcc29777

Removed %T in mode-line-format. Trivial documentation changes. lisp/bindings.el (mode-line-buffer-identification): Use the conditional formatting feature instead of builtin support. src/buffer.c (Vmode_line_format): Removed %T documentation. src/xdisp.c (decode_mode_spec): Removed %T processing. lib-src/emacsclient.c (pass_signal_to_emacs, init_signals): Added comment. src/cm.c: Cosmetic changes. src/termchar.h: Ditto. src/keyboard.c (interrupt_signal, handle_interrupt): Updated documentation. src/process.c (add_keyboard_wait_descriptor): Added docs. src/sysdep.c (init_all_sys_modes, init_sys_modes) (reset_all_sys_modes): Added docs. src/term.c (tty_ring_bell, tty_set_terminal_modes) (tty_reset_terminal_modes, tty_update_end, set_terminal_window) (tty_set_terminal_window, clear_to_end, tty_clear_to_end) (tty_clear_frame, tty_clear_end_of_line, write_glyphs) (tty_write_glyphs, insert_glyphs, tty_insert_glyphs, delete_glyphs) (tty_delete_glyphs, tty_ins_del_lines, get_named_tty_display) (init_initial_display, delete_tty): Added docs. git-archimport-id: [e-mail]--2004/emacs--multi-tty--0--patch-65

;;; talk.el --- allow several users to talk to each other through Emacs

;; Copyright (C) 1995 Free Software Foundation, Inc.

;; Maintainer: FSF
;; Keywords: comm, frames

;; This file is part of GNU Emacs.

;; GNU Emacs is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation; either version 2, or (at your option)
;; any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs; see the file COPYING.  If not, write to the
;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
;; Boston, MA 02111-1307, USA.

;;; Commentary:

;; This is a multi-user talk package that runs in Emacs.
;; Use talk-connect to bring a new person into the conversation.

;;; Code:

(defvar talk-display-alist nil
  "Alist of displays on which Emacs talk is now running.
Each element has the form (DISPLAY FRAME BUFFER).")

;;;###autoload
(defun talk-connect (display)
  "Connect to display DISPLAY for the Emacs talk group."
  (interactive "sTalk to display: ")
  ;; Make sure we have an entry for the current display.
  (let ((mydisp (cdr (assq 'display (frame-parameters (selected-frame))))))
    (talk-add-display mydisp))
  ;; Make sure we have an entry for the specified display.
  (talk-add-display display)
  ;; Add the new buffers to all talk frames.
  (talk-update-buffers))

;;;###autoload
(defun talk ()
  "Connect to the Emacs talk group from the current X display or tty frame."
  (interactive)
  (let ((type (frame-live-p (selected-frame))))
    (if (eq type t)
	;; Termcap frame
	(talk-add-tty-frame (selected-frame))
      (if (eq type 'x)
	  ;; X frame
	  (talk-add-display (frame-parameter (selected-frame) 'display))
	(error "Could not determine frame type"))))
  (talk-update-buffers))

(defun talk-add-display (display)
  (let* ((elt (assoc display talk-display-alist))
	 (name (concat "*talk-" display "*"))
	 buffer frame)
    (if (not (and elt (frame-live-p (setq frame (nth 1 elt)))))
	(setq frame (make-frame-on-display display (list (cons 'name name)))))
    (if (not (and elt (buffer-name (get-buffer (setq buffer (nth 2 elt))))))
	(setq buffer (get-buffer-create name)))
    (setq talk-display-alist
	  (cons (list display frame buffer) (delq elt talk-display-alist)))))

(defun talk-add-tty-frame (frame)
  (let* ((elt (assoc (frame-tty-name frame) talk-display-alist))
	 (name (concat "*talk-" (frame-tty-name frame) "*"))
	 buffer)
    (if (not (and elt (buffer-name (get-buffer (setq buffer (nth 2 elt))))))
	(setq buffer (get-buffer-create name)))
    (add-to-list 'delete-tty-after-functions 'talk-handle-delete-tty)
    (setq talk-display-alist
	  (cons (list (frame-tty-name frame) frame buffer) (delq elt talk-display-alist)))))

(defun talk-handle-delete-tty (tty)
  (let ((elt (assoc tty talk-display-alist)))
    (setq talk-display-alist (delq elt talk-display-alist))
    (talk-update-buffers)))

(defun talk-disconnect ()
  "Disconnect this display from the Emacs talk group."
  (interactive)
  (let* ((mydisp (cdr (assq 'display (frame-parameters (selected-frame)))))
	 (elt (assoc mydisp talk-display-alist)))
    (delete-frame (nth 1 elt))
    (kill-buffer (nth 2 elt))
    (setq talk-display-alist (delq elt talk-display-alist))
    (talk-update-buffers)))

(defun talk-update-buffers ()
  "Update all the talk frames so that each shows all the talk buffers."
  (let ((tail talk-display-alist))
    (while tail
      (let ((frame (nth 1 (car tail)))
	    (this-buffer (nth 2 (car tail)))
	    (buffers
	     (mapcar (function (lambda (elt) (nth 2 elt)))
		     talk-display-alist)))
	;; Put this display's own talk buffer
	;; at the front of the list.
	(setq buffers (cons this-buffer (delq this-buffer buffers)))
	(talk-split-up-frame frame buffers))
      (setq tail (cdr tail)))))

(defun talk-split-up-frame (frame buffers)
  "Split FRAME into equal-sized windows displaying the buffers in BUFFERS.
Select the first of these windows, displaying the first of the buffers."
  (let ((lines-per-buffer (/ (frame-height frame) (length buffers)))
	(old-frame (selected-frame)))
    (unwind-protect
	(progn
	  (select-frame frame)
	  (select-window (frame-first-window frame))
	  (delete-other-windows)
	  (while (progn
		   (switch-to-buffer (car buffers))
		   (setq buffers (cdr buffers)))
	    (split-window-vertically lines-per-buffer)
	    (other-window 1))
	  (select-window (frame-first-window frame)))
      (select-frame old-frame))))

(provide 'talk)

;;; arch-tag: 7ab0ad88-1788-4886-a44c-ae685e6f8a1a
;;; talk.el ends here