annotate msdos/sedleim.inp @ 32305:ca771411a7fd

Don't require font-lock any more. (jit-lock-functions): Make buffer-local. (jit-lock-saved-fontify-buffer-function): Remove. (jit-lock-mode): Remove autoload cookie. Remove font-lock specific code. (jit-lock-unregister): Don't bother handling complex hooks any more. (jit-lock-refontify): New function. (jit-lock-fontify-buffer): Use it. (jit-lock-function-1): Replaced by jit-lock-fontify-now. (jit-lock-fontify-now): Renamed from jit-lock-function-1. Add optional args START and END. Never call font-lock-fontify-region directly. (jit-lock-function, jit-lock-stealth-fontify): Use it.

# -sedleim.inp-----------------------------------------------------------
# Configuration script for leim/Makefile under DJGPP v2.x
# ----------------------------------------------------------------------
/^SHELL *=/c\
SHELL=/xyzzy/command\
MAKESHELL=/xyzzy/command

/^version=/d
/^prefix=/d
/^datadir=/s|@datadir@|../..|
/^srcdir=/s|@srcdir@|.|

/^INSTALLDIR=/c\
INSTALLDIR=.

/RUN-EMACS *=/,/^$/c\
export EMACSLOADPATH=${buildlisppath}\
RUN-EMACS = ${BUILT-EMACS} -batch --no-init-file --no-site-file --multibyte

/^	cd ../c\
	${MAKE} -C ../src ${MFLAGS} emacs

/else make quail/c\
	if not exist quail\\nul make quail

/^leim-list.el:/,/^$/ {
	/^	if/d
	/^	else/,/^	fi/d
	s|	 *|	|
	/^	--eval/,/; \\$/s|\; \\||
}

/^install:/,/^$/c\
install: all\

/^	if test -f/d