comparison lisp/emacs-lisp/easy-mmode.el @ 53056:a9d324df91c7

(easy-mmode-define-navigation): Take additional optional arg NARROWFUN. For the generated functions: Add local var `was-narrowed-p'. Also, if NARROWFUN is specified, include frags that arrange to check for and save narrowing state before the move and then conditionally call NARROWFUN after the move.

53055:4cb0d5b004e9


;;;
;;; easy-mmode-define-navigation
;;;

(defmacro easy-mmode-define-navigation (base re &optional name endfun)
  "Define BASE-next and BASE-prev to navigate in the buffer.
RE determines the places the commands should move point to.
NAME should describe the entities matched by RE.  It is used to build
  the docstrings of the two functions.
BASE-next also tries to make sure that the whole entry is visible by
  searching for its end (by calling ENDFUN if provided or by looking for
  the next entry) and recentering if necessary.
ENDFUN should return the end position (with or without moving point)."
  (let* ((base-name (symbol-name base))
	 (prev-sym (intern (concat base-name "-prev")))
	 (next-sym (intern (concat base-name "-next"))))
    (unless name (setq name base-name))
    `(progn
       (add-to-list 'debug-ignored-errors
		    ,(concat "^No \\(previous\\|next\\) " (regexp-quote name)))
       (defun ,next-sym (&optional count)
	 ,(format "Go to the next COUNT'th %s." name)
	 (interactive)
	 (unless count (setq count 1))
	 (if (< count 0) (,prev-sym (- count))
	   (if (looking-at ,re) (setq count (1+ count)))
	   (if (not (re-search-forward ,re nil t count))
	       (if (looking-at ,re)
		   (goto-char (or ,(if endfun `(,endfun)) (point-max)))
		 (error "No next %s" ,name))
	     (goto-char (match-beginning 0))
	     (when (and (eq (current-buffer) (window-buffer (selected-window)))
			(interactive-p))
	       (let ((endpt (or (save-excursion
				  ,(if endfun `(,endfun)
				     `(re-search-forward ,re nil t 2)))
				(point-max))))
		 (unless (pos-visible-in-window-p endpt nil t)
		   (recenter '(0))))))))
       (defun ,prev-sym (&optional count)
	 ,(format "Go to the previous COUNT'th %s" (or name base-name))
	 (interactive)
	 (unless count (setq count 1))
	 (if (< count 0) (,next-sym (- count))
	   (unless (re-search-backward ,re nil t count)
	     (error "No previous %s" ,name)))))))

(provide 'easy-mmode)

;;; arch-tag: d48a5250-6961-4528-9cb0-3c9ea042a66a
;;; easy-mmode.el ends here

53056:a9d324df91c7


;;;
;;; easy-mmode-define-navigation
;;;

(defmacro easy-mmode-define-navigation (base re &optional name endfun narrowfun)
  "Define BASE-next and BASE-prev to navigate in the buffer.
RE determines the places the commands should move point to.
NAME should describe the entities matched by RE.  It is used to build
  the docstrings of the two functions.
BASE-next also tries to make sure that the whole entry is visible by
  searching for its end (by calling ENDFUN if provided or by looking for
  the next entry) and recentering if necessary.
ENDFUN should return the end position (with or without moving point).
NARROWFUN non-nil means to check for narrowing before moving, and if
found, do widen first and then call NARROWFUN with no args after moving."
  (let* ((base-name (symbol-name base))
	 (prev-sym (intern (concat base-name "-prev")))
	 (next-sym (intern (concat base-name "-next")))
         (check-narrow-maybe (when narrowfun
                               '(setq was-narrowed-p
                                      (prog1 (or (/= (point-min) 1)
                                                 (/= (point-max)
                                                     (1+ (buffer-size))))
                                        (widen)))))
         (re-narrow-maybe (when narrowfun
                            `(when was-narrowed-p (,narrowfun)))))
    (unless name (setq name base-name))
    `(progn
       (add-to-list 'debug-ignored-errors
		    ,(concat "^No \\(previous\\|next\\) " (regexp-quote name)))
       (defun ,next-sym (&optional count)
	 ,(format "Go to the next COUNT'th %s." name)
	 (interactive)
	 (unless count (setq count 1))
	 (if (< count 0) (,prev-sym (- count))
	   (if (looking-at ,re) (setq count (1+ count)))
           (let (was-narrowed-p)
             ,check-narrow-maybe
             (if (not (re-search-forward ,re nil t count))
                 (if (looking-at ,re)
                     (goto-char (or ,(if endfun `(,endfun)) (point-max)))
                   (error "No next %s" ,name))
               (goto-char (match-beginning 0))
               (when (and (eq (current-buffer) (window-buffer (selected-window)))
                          (interactive-p))
                 (let ((endpt (or (save-excursion
                                    ,(if endfun `(,endfun)
                                       `(re-search-forward ,re nil t 2)))
                                  (point-max))))
                   (unless (pos-visible-in-window-p endpt nil t)
                     (recenter '(0))))))
             ,re-narrow-maybe)))
       (defun ,prev-sym (&optional count)
	 ,(format "Go to the previous COUNT'th %s" (or name base-name))
	 (interactive)
	 (unless count (setq count 1))
	 (if (< count 0) (,next-sym (- count))
           (let (was-narrowed-p)
             ,check-narrow-maybe
             (unless (re-search-backward ,re nil t count)
               (error "No previous %s" ,name))
             ,re-narrow-maybe))))))


(provide 'easy-mmode)

;;; arch-tag: d48a5250-6961-4528-9cb0-3c9ea042a66a
;;; easy-mmode.el ends here