comparison lisp/files.el @ 78608:b2efc009415c

(backup-buffer-copy): Check backup directory is writable, to avoid infloop deleting old backup.

78607:dc94a4a60666

			(setq targets (cdr targets))))
		  setmodes)
	    (file-error nil))))))

(defun backup-buffer-copy (from-name to-name modes)
  (let ((umask (default-file-modes)))
    (unwind-protect
	(progn
	  ;; Create temp files with strict access rights.  It's easy to
	  ;; loosen them later, whereas it's impossible to close the
	  ;; time-window of loose permissions otherwise.
	  (set-default-file-modes ?\700)
	  (while (condition-case ()
		     (progn
		       (condition-case nil
			   (delete-file to-name)
			 (file-error nil))
		       (copy-file from-name to-name nil t)
		       nil)
		   (file-already-exists t))
	    ;; The file was somehow created by someone else between
	    ;; `delete-file' and `copy-file', so let's try again.
	    nil))
      ;; Reset the umask.
      (set-default-file-modes umask)))
  (and modes
       (set-file-modes to-name (logand modes #o1777))))

78608:b2efc009415c

			(setq targets (cdr targets))))
		  setmodes)
	    (file-error nil))))))

(defun backup-buffer-copy (from-name to-name modes)
  (let ((umask (default-file-modes))
	(dir (or (file-name-directory to-name)
		 default-directory)))
    ;; Can't delete or create files in a read-only directory.
    (unless (file-writable-p dir)
      (signal 'file-error (list "Directory is not writable" dir)))
    (unwind-protect
	(progn
	  ;; Create temp files with strict access rights.  It's easy to
	  ;; loosen them later, whereas it's impossible to close the
	  ;; time-window of loose permissions otherwise.
	  (set-default-file-modes ?\700)
	  (while (condition-case ()
		     (progn
		       ;; If we allow for the possibility of something
		       ;; creating the file between delete and copy
		       ;; (below), we must also allow for the
		       ;; possibility of something deleting it between
		       ;; a file-exists-p check and a delete.
		       (condition-case nil
			   (delete-file to-name)
			 (file-error nil))
		       (copy-file from-name to-name nil t)
		       nil)
		   (file-already-exists t))
	    ;; The file was somehow created by someone else between
	    ;; `delete-file' and `copy-file', so let's try again.
	    ;; Does that every actually happen in practice?
	    ;; This is a potential infloop, which seems bad...
	    ;; rms says "I think there is also a possible race
	    ;; condition for making backup files" (emacs-devel 20070821).
	    nil))
      ;; Reset the umask.
      (set-default-file-modes umask)))
  (and modes
       (set-file-modes to-name (logand modes #o1777))))