diff lisp/password-cache.el @ 87036:fcc71de0dc1c

Move to here from gnus/password.el.

--- /dev/null	Thu Jan 01 00:00:00 1970 +0000
+++ b/lisp/password-cache.el	Tue Dec 04 04:09:15 2007 +0000
@@ -0,0 +1,141 @@
+;;; password-cache.el --- Read passwords, possibly using a password cache.
+
+;; Copyright (C) 1999, 2000, 2003, 2004, 2005, 2006, 2007
+;;   Free Software Foundation, Inc.
+
+;; Author: Simon Josefsson <[e-mail]>
+;; Created: 2003-12-21
+;; Keywords: password cache passphrase key
+
+;; This file is part of GNU Emacs.
+
+;; GNU Emacs is free software; you can redistribute it and/or modify
+;; it under the terms of the GNU General Public License as published by
+;; the Free Software Foundation; either version 3, or (at your option)
+;; any later version.
+
+;; GNU Emacs is distributed in the hope that it will be useful,
+;; but WITHOUT ANY WARRANTY; without even the implied warranty of
+;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;; GNU General Public License for more details.
+
+;; You should have received a copy of the GNU General Public License
+;; along with GNU Emacs; see the file COPYING.  If not, write to the
+;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
+;; Boston, MA 02110-1301, USA.
+
+;;; Commentary:
+
+;; Greatly influenced by pgg.el written by Daiki Ueno, with timer
+;; fixes for XEmacs by Katsumi Yamaoka.  In fact, this is mostly just
+;; a rip-off.
+;;
+;; (password-read "Password? " "test")
+;; ;; Minibuffer prompt for password.
+;;  => "foo"
+;;
+;; (password-cache-add "test" "foo")
+;;  => nil
+
+;; Note the previous two can be replaced with:
+;; (password-read-and-add "Password? " "test")
+;; ;; Minibuffer prompt for password.
+;; => "foo"
+;; ;; "foo" is now cached with key "test"
+
+
+;; (password-read "Password? " "test")
+;; ;; No minibuffer prompt
+;;  => "foo"
+;;
+;; (password-read "Password? " "test")
+;; ;; No minibuffer prompt
+;;  => "foo"
+;;
+;; ;; Wait `password-cache-expiry' seconds.
+;;
+;; (password-read "Password? " "test")
+;; ;; Minibuffer prompt for password is back.
+;;  => "foo"
+
+;;; Code:
+
+(eval-when-compile
+  (require 'cl))
+
+(defcustom password-cache t
+  "Whether to cache passwords."
+  :group 'password
+  :type 'boolean)
+
+(defcustom password-cache-expiry 16
+  "How many seconds passwords are cached, or nil to disable expiring.
+Whether passwords are cached at all is controlled by `password-cache'."
+  :group 'password
+  :type '(choice (const :tag "Never" nil)
+		 (integer :tag "Seconds")))
+
+(defvar password-data (make-vector 7 0))
+
+(defun password-read-from-cache (key)
+  "Obtain passphrase for KEY from time-limited passphrase cache.
+Custom variables `password-cache' and `password-cache-expiry'
+regulate cache behavior."
+  (and password-cache
+       key
+       (symbol-value (intern-soft key password-data))))
+
+(defun password-read (prompt &optional key)
+  "Read password, for use with KEY, from user, or from cache if wanted.
+KEY indicate the purpose of the password, so the cache can
+separate passwords.  The cache is not used if KEY is nil.  It is
+typically a string.
+The variable `password-cache' control whether the cache is used."
+  (or (password-read-from-cache key)
+      (read-passwd prompt)))
+
+(defun password-read-and-add (prompt &optional key)
+  "Read password, for use with KEY, from user, or from cache if wanted.
+Then store the password in the cache.  Uses `password-read' and
+`password-cache-add'.
+Custom variables `password-cache' and `password-cache-expiry'
+regulate cache behavior."
+  (let ((password (password-read prompt key)))
+    (when (and password key)
+      (password-cache-add key password))
+    password))
+
+(defun password-cache-remove (key)
+  "Remove password indexed by KEY from password cache.
+This is typically run be a timer setup from `password-cache-add',
+but can be invoked at any time to forcefully remove passwords
+from the cache.  This may be useful when it has been detected
+that a password is invalid, so that `password-read' query the
+user again."
+  (let ((password (symbol-value (intern-soft key password-data))))
+    (when password
+      (if (fboundp 'clear-string)
+	  (clear-string password)
+	(fillarray password ?_))
+      (unintern key password-data))))
+
+(defun password-cache-add (key password)
+  "Add password to cache.
+The password is removed by a timer after `password-cache-expiry'
+seconds."
+  (when (and password-cache-expiry (null (intern-soft key password-data)))
+    (run-at-time password-cache-expiry nil
+		 #'password-cache-remove
+		 key))
+  (set (intern key password-data) password)
+  nil)
+
+(defun password-reset ()
+  "Clear the password cache."
+  (interactive)
+  (fillarray password-data 0))
+
+(provide 'password-cache)
+
+;;; arch-tag: ab160494-16c8-4c68-a4a1-73eebf6686e5
+;;; password-cache.el ends here