view msdos/sed1.inp @ 16361:032601b9959b

(ps-print-prologue-1): Fix bug in postscript comment lines. (ps-nb-pages): Call ps-setup _before_ switching to the other buffer, because of buffer variables. Major rewrite. (ps-page-dimensions-database, ps-paper-type): Replace the following global variables: (ps-a4-page-height, ps-a4-page-width, ps-legal-page-height, ps-legal-page-width, ps-letter-page-height, ps-letter-page-width, ps-pages-alist, ps-page-dimensions): Variables deleted. (ps-page-height-i, ps-page-width-i): Variables deleted. (ps-print-prologue): Variable deleted. (ps-print-prologue-1, ps-print-prologue-2): New variables. Major rewrite of the postscript code to handle landscape mode, multiple columns and new font management. (ps-landscape-mode, ps-number-of-columns, ps-inter-column): New variables. Add landscape mode and multiple columns with interspacing. (ps-font-info-database, ps-font-family, ps-font-size, ps-header-font-family, ps-header-font-size, ps-header-title-font, ps-header-title-font-size): New variables. New font management interface. (ps-header-line-pad, ps-header-offset): New variables. (ps-header-font, ps-landscape-page-height): New internal variables. (ps-top-margin): Change its semantics. It is now really the top margin, not anymore twice the top margin. (/ReportAllFontInfo): New postscript function to get all the font families of the printer. (ps-setup): New function. (ps-line-lengths, ps-nb-pages-buffer, ps-nb-pages-region): New utility functions. (ps-page-dimensions-get-width, ps-page-dimensions-get-height): New macros. (/HeaderOffset): Fix bug with /PrintStartY. (/SetHeaderLines): Fix bug.

# -sed1.inp-------------------------------------------------------------
# Configuration script for src/makefile
# ----------------------------------------------------------------------
#
# In case src/Makefile needs to rebuild `make-doc.exe' (might happen under
# Windows 95), make sure it gets built with commands that DOS
# understands (one command per line).
s/^#.*//
s/^[ \f\t][ \f\t]*$//
s/^ /	/
s/\.h\.in/.h-in/
s!^	\./temacs!	go32 temacs!
s!/bin/sh!command.com!
/^MAKE *=/s/^/# /
/^SHELL *=/s/^/# /
/^srcdir *=/s/@[^@\n]*@/./
/^VPATH *=/s/@[^@\n]*@/./
/^CC *=/s/@[^@\n]*@/gcc/
/^CPP *=/s/@[^@\n]*@/gcc -e/
/^CFLAGS *=/s/@[^@\n]*@/-O2 -g/
/^LN_S *=/s/@[^@\n]*@/ln -s/
/^M_FILE *=/s!@[^@\n]*@!m/intel386.h!
/^S_FILE *=/s!@[^@\n]*@!s/msdos.h!
/^@SET_MAKE@$/s/@SET_MAKE@//
/^.\${libsrc}make-docfile.*>/s!make-docfile!make-doc.exe -o ../etc/DOC!
/^.\${libsrc}make-doc/s!>.*$!!
/^\${libsrc}make-docfile:/c\
${libsrc}make-doc.exe:\
	cd ..\
	cd lib-src\
	$(MAKE) ${MFLAGS} make-docfile -W make-docfile.c\
	cd ..\
	cd src
/^	cd \${libsrc}; \${MAKE} \${MFLAGS} make-docfile/d
/\${libsrc}make-docfile/s/-docfile[ 	]/-doc.exe /
/^[ 	]*$/d
/^temacs:/s/prefix-args//
/^	#/d