view msdos/sed1.inp @ 26789:03a6016a38bf

(#includes): Allow compilation with only Xaw. (xaw3d_arrow_scroll, xaw3d_pick_top): New variables. (xt_action_hook): Replace XAW3D by XAW. (xaw3d_jump_callback): Renamed to xaw_jump_callback. (xaw_jump_callback): Renamed from xaw3d_jump_callback. Determine epsilon dynamically and don't try to be too clever. (xaw3d_scroll_callback): Renamed to xaw_scroll_callback. (xaw_scroll_callback): Renamed from xaw3d_scroll_callback. Handle both Xaw3d with arrow-scrollbars and with Xaw-style scrollbar (using `ratio'). (x_create_toolkit_scroll_bar): Try to detect which style of Xaw3d scrollbar we have so as to set it up more optimally and to fix xaw3d_arrow_scroll and xaw3d_pick_top. (x_set_toolkit_scroll_bar_thumb): Try to maintain 2 spare pixels at the bottom of the Xaw3d scrollbar, to work around its tendency to refuse shrinking the thumb. Also make sure that `XawScrollbarSetThumb' is not ignored, using a major gross hack. (x_initialize): Init default values for xaw3d_arrow_scroll and xaw3d_pick_top.

# -sed1.inp-------------------------------------------------------------
# Configuration script for src/makefile
# ----------------------------------------------------------------------
#
# In case src/Makefile needs to rebuild `make-doc.exe' (might happen under
# Windows 95), make sure it gets built with commands that DOS
# understands (one command per line).
s/^#.*//
s/^[ \f\t][ \f\t]*$//
s/^ /	/
s/\.h\.in/.h-in/
s!^	\./temacs!	go32 temacs!
s!/bin/sh!command.com!
/^MAKE *=/s/^/# /
/^SHELL *=/s/^/# /
/^srcdir *=/s/@[^@\n]*@/./
/^VPATH *=/s/@[^@\n]*@/./
/^CC *=/s/@[^@\n]*@/gcc/
/^CPP *=/s/@[^@\n]*@/gcc -e/
/^CFLAGS *=/s/@[^@\n]*@/-O2 -g/
/^LN_S *=/s/@[^@\n]*@/ln -s/
/^M_FILE *=/s!@[^@\n]*@!m/intel386.h!
/^S_FILE *=/s!@[^@\n]*@!s/msdos.h!
/^@SET_MAKE@$/s/@SET_MAKE@//
/^.\${libsrc}make-docfile.*>/s!make-docfile!make-doc.exe -o ../etc/DOC!
/^.\${libsrc}make-doc/s!>.*$!!
/^\${libsrc}make-docfile:/c\
${libsrc}make-doc.exe:\
	cd ..\
	cd lib-src\
	$(MAKE) ${MFLAGS} make-docfile -W make-docfile.c\
	cd ..\
	cd src
/^	cd \${libsrc}; \${MAKE} \${MFLAGS} make-docfile/d
/\${libsrc}make-docfile/s/-docfile[ 	]/-doc.exe /
/^[ 	]*$/d
/^temacs:/s/prefix-args//
/^temacs:/s/stamp-oldxmenu//
/^	#/d