view m4/getopt.m4 @ 109555:05e7e7c46ff0

Use const, move declarations to header files. * src/buffer.c (Fset_buffer_multibyte): Remove local extern declaration. * src/character.c (strwidth, parse_str_to_multibyte): Add const. * src/character.h (strwidth, parse_str_to_multibyte): Likewise. * src/charset.c (add_to_log): Remove declaration. * src/composite.c (syms_of_composite): Remove local extern declarations. * src/data.c (Finteractive_form): Use const. * src/dired.c (scmp): Add const. (directory_files_internal): Remove local extern declaration. * src/dispextern.h (add_to_log): Remove declaration. (x_get_arg, x_frame_get_arg, x_frame_get_and_record_arg) (x_frame_get_and_record_arg, x_default_parameter): Add const. * src/dispnew.c: Remove duplicate #include <unistd.h>. (update_window, update_frame_1, init_display): Remove local extern declarations. * src/editfns.c (region_limit, syms_of_editfns): Remove local extern declarations. * src/emacs.c (main): Remove local extern declaration. * src/font.c (Qnormal, QCtype, QCfamily, QCweight, QCslant, QCwidth) (QCheight, QCsize, QCname): Remove declarations. * src/frame.c (x_get_resource_string, x_get_string_resource) (x_get_arg, x_frame_get_arg, x_frame_get_and_record_arg) (x_default_parameter): Use const. * src/image.c (QCwidth, QCheight, QCforeground, QCbackground, QCfile) (QCdata, QCtype, Qcenter): Remove declarations. * src/keyboard.h (do_mouse_tracking): Add declaration. * src/minibuf.c (Qmouse_face): Remove declaration. * src/msdos.c (IT_note_mouse_highlight): Remove local extern declaration. * src/xdisp.c (do_mouse_tracking): Remove declaration. (add_to_log): Use const. * src/xfaces.c (Qmouse_face): Remove declaration. (face_color_gray_p, tty_defined_color, defined_color) (face_color_gray_p, face_color_supported_p). Add const. * src/xfns.c: Include xlwmenu.h when USE_LUCID. (x_defined_color, xic_set_xfontset): Use const. (Fx_hide_tip): Remove local extern declaration. * src/xselect.c (selection_data_to_lisp_data) (x_property_data_to_lisp): * src/xrdb.c (x_get_string_resource, file_p) (x_get_customization_string, magic_file_p, search_magic_path) (get_system_app, get_user_app, x_load_resources, x_get_resource) (x_get_string_resource): Use const. * src/xterm.c (xlwmenu_window_p, xlwmenu_redisplay): Remove declarations. (x_text_icon, x_check_errors, x_connection_closed): Use const. * src/xterm.h (x_get_customization_string, x_load_resources) (x_get_resource, x_text_icon, x_text_icon, x_check_errors) (x_check_errors, x_property_data_to_lisp, defined_color) (xic_set_xfontset, x_defined_color): Use const.

# getopt.m4 serial 10
dnl Copyright (C) 2002,2003,2004,2005,2006,2007 Free Software Foundation, Inc.
dnl This file is free software; the Free Software Foundation
dnl gives unlimited permission to copy and/or distribute it,
dnl with or without modifications, as long as this notice is preserved.

# The getopt module assume you want GNU getopt, with getopt_long etc,
# rather than vanilla POSIX getopt.  This means your your code should
# always include <getopt.h> for the getopt prototypes.

AC_DEFUN([gl_GETOPT_SUBSTITUTE],
[
  AC_LIBOBJ([getopt])
  AC_LIBOBJ([getopt1])
  gl_GETOPT_SUBSTITUTE_HEADER
  gl_PREREQ_GETOPT
])

AC_DEFUN([gl_GETOPT_SUBSTITUTE_HEADER],
[
  GETOPT_H=getopt.h
  AC_DEFINE([__GETOPT_PREFIX], [[rpl_]],
    [Define to rpl_ if the getopt replacement functions and variables
     should be used.])
  AC_SUBST([GETOPT_H])
])

AC_DEFUN([gl_GETOPT_CHECK_HEADERS],
[
  GETOPT_H=
  AC_CHECK_HEADERS([getopt.h], [], [GETOPT_H=getopt.h])
  if test -z "$GETOPT_H"; then
    AC_CHECK_FUNCS([getopt_long_only], [], [GETOPT_H=getopt.h])
  fi

  dnl BSD getopt_long uses an incompatible method to reset option processing,
  dnl and (as of 2004-10-15) mishandles optional option-arguments.
  if test -z "$GETOPT_H"; then
    AC_CHECK_DECL([optreset], [GETOPT_H=getopt.h], [], [#include <getopt.h>])
  fi

  dnl Solaris 10 getopt doesn't handle `+' as a leading character in an
  dnl option string (as of 2005-05-05).
  if test -z "$GETOPT_H"; then
    AC_CACHE_CHECK([for working GNU getopt function], [gl_cv_func_gnu_getopt],
      [AC_RUN_IFELSE(
	[AC_LANG_PROGRAM([#include <getopt.h>],
	   [[
	     char *myargv[3];
	     myargv[0] = "conftest";
	     myargv[1] = "-+";
	     myargv[2] = 0;
	     return getopt (2, myargv, "+a") != '?';
	   ]])],
	[gl_cv_func_gnu_getopt=yes],
	[gl_cv_func_gnu_getopt=no],
	[dnl cross compiling - pessimistically guess based on decls
	 dnl Solaris 10 getopt doesn't handle `+' as a leading character in an
	 dnl option string (as of 2005-05-05).
	 AC_CHECK_DECL([getopt_clip],
	   [gl_cv_func_gnu_getopt=no], [gl_cv_func_gnu_getopt=yes],
	   [#include <getopt.h>])])])
    if test "$gl_cv_func_gnu_getopt" = "no"; then
      GETOPT_H=getopt.h
    fi
  fi
])

AC_DEFUN([gl_GETOPT_IFELSE],
[
  AC_REQUIRE([gl_GETOPT_CHECK_HEADERS])
  AS_IF([test -n "$GETOPT_H"], [$1], [$2])
])

AC_DEFUN([gl_GETOPT], [gl_GETOPT_IFELSE([gl_GETOPT_SUBSTITUTE])])

# Prerequisites of lib/getopt*.
AC_DEFUN([gl_PREREQ_GETOPT], [:])

ifelse(dnl	Do not change this comment
   arch-tag: 6c64a021-551c-4a7f-9c63-cd7e1ce54707
)dnl