view lisp/ledit.el @ 50217:10510d1bf1b6

* dispextern.h (Display_Info): Generic typedef for *_display_info. (NativeRectangle): Generic typedef for rectangle type. (enum window_part): Move here from window.c. (struct redisplay_interface): New members flush_display_optional, define_frame_cursor, clear_frame_area, draw_window_cursor, draw_vertical_window_border, shift_glyphs_for_insert. Rename member clear_mouse_face to clear_window_mouse_face. (estimate_mode_line_height_hook): Remove hook. (auto_raise_tool_bar_buttons_p): Don't declare extern. (tool_bar_item_info): Remove prototype. (help_echo_string, help_echo_window, help_echo_object) (previous_help_echo_string, help_echo_pos) (last_mouse_frame, last_tool_bar_item, mouse_autoselect_window): (x_stretch_cursor_p, output_cursor): Declare extern. (x_draw_glyphs, notice_overwritten_cursor): Remove prototypes. (x_write_glyphs), x_insert_glyphs, x_clear_end_of_line) (x_fix_overlapping_area, draw_phys_cursor_glyph, erase_phys_cursor) (display_and_set_cursor, set_output_cursor, x_cursor_to) (x_update_cursor, x_clear_cursor, x_draw_vertical_border) (frame_to_window_pixel_xy, get_glyph_string_clip_rect) (note_mouse_highlight, x_clear_window_mouse_face, cancel_mouse_face) (handle_tool_bar_click, clear_mouse_face, show_mouse_face) (cursor_in_mouse_face_p, expose_frame, x_intersect_rectangles): Add prototypes. (mode_line_string, marginal_area_string): Fix prototypes.

;;; ledit.el --- Emacs side of ledit interface

;; Copyright (C) 1985 Free Software Foundation, Inc.

;; Maintainer: FSF
;; Keywords: languages

;; This file is part of GNU Emacs.

;; GNU Emacs is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation; either version 2, or (at your option)
;; any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs; see the file COPYING.  If not, write to the
;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
;; Boston, MA 02111-1307, USA.

;;; Commentary:

;; This is a major mode for editing Liszt.  See etc/LEDIT for details.

;;; Code:

;;; To do:
;;; o lisp -> emacs side of things (grind-definition and find-definition)

(defvar ledit-mode-map nil)

(defconst ledit-zap-file
  (expand-file-name (concat (user-login-name) ".l1") temporary-file-directory)
  "File name for data sent to Lisp by Ledit.")
(defconst ledit-read-file
  (expand-file-name (concat (user-login-name) ".l2") temporary-file-directory)
  "File name for data sent to Ledit by Lisp.")
(defconst ledit-compile-file
  (expand-file-name (concat (user-login-name) ".l4") temporary-file-directory)
  "File name for data sent to Lisp compiler by Ledit.")
(defconst ledit-buffer "*LEDIT*"
  "Name of buffer in which Ledit accumulates data to send to Lisp.")

;;;###autoload
(defconst ledit-save-files t "\
*Non-nil means Ledit should save files before transferring to Lisp.")
;;;###autoload
(defconst ledit-go-to-lisp-string "%?lisp" "\
*Shell commands to execute to resume Lisp job.")
;;;###autoload
(defconst ledit-go-to-liszt-string "%?liszt" "\
*Shell commands to execute to resume Lisp compiler job.")

(defun ledit-save-defun ()
  "Save the current defun in the ledit buffer"
  (interactive)
  (save-excursion
   (end-of-defun)
   (let ((end (point)))
     (beginning-of-defun)
     (append-to-buffer ledit-buffer (point) end))
   (message "Current defun saved for Lisp")))

(defun ledit-save-region (beg end)
  "Save the current region in the ledit buffer"
  (interactive "r")
  (append-to-buffer ledit-buffer beg end)
  (message "Region saved for Lisp"))

(defun ledit-zap-defun-to-lisp ()
  "Carry the current defun to Lisp."
  (interactive)
  (ledit-save-defun)
  (ledit-go-to-lisp))

(defun ledit-zap-defun-to-liszt ()
  "Carry the current defun to liszt."
  (interactive)
  (ledit-save-defun)
  (ledit-go-to-liszt))

(defun ledit-zap-region-to-lisp (beg end)
  "Carry the current region to Lisp."
  (interactive "r")
  (ledit-save-region beg end)
  (ledit-go-to-lisp))

(defun ledit-go-to-lisp ()
  "Suspend Emacs and restart a waiting Lisp job."
  (interactive)
  (if ledit-save-files
      (save-some-buffers))
  (if (get-buffer ledit-buffer)
      (save-excursion
       (set-buffer ledit-buffer)
       (goto-char (point-min))
       (write-region (point-min) (point-max) ledit-zap-file)
       (erase-buffer)))
  (suspend-emacs ledit-go-to-lisp-string)
  (load ledit-read-file t t))

(defun ledit-go-to-liszt ()
  "Suspend Emacs and restart a waiting Liszt job."
  (interactive)
  (if ledit-save-files
      (save-some-buffers))
  (if (get-buffer ledit-buffer)
      (save-excursion
       (set-buffer ledit-buffer)
       (goto-char (point-min))
       (insert "(declare (macros t))\n")
       (write-region (point-min) (point-max) ledit-compile-file)
       (erase-buffer)))
  (suspend-emacs ledit-go-to-liszt-string)
  (load ledit-read-file t t))

(defun ledit-setup ()
  "Set up key bindings for the Lisp/Emacs interface."
  (unless ledit-mode-map
    (setq ledit-mode-map (make-sparse-keymap))
    (set-keymap-parent ledit-mode-map lisp-mode-shared-map))
  (define-key ledit-mode-map "\e\^d" 'ledit-save-defun)
  (define-key ledit-mode-map "\e\^r" 'ledit-save-region)
  (define-key ledit-mode-map "\^xz" 'ledit-go-to-lisp)
  (define-key ledit-mode-map "\e\^c" 'ledit-go-to-liszt))

(ledit-setup)

;;;###autoload
(defun ledit-mode ()
  "\\<ledit-mode-map>Major mode for editing text and stuffing it to a Lisp job.
Like Lisp mode, plus these special commands:
  \\[ledit-save-defun]	-- record defun at or after point
	   for later transmission to Lisp job.
  \\[ledit-save-region] -- record region for later transmission to Lisp job.
  \\[ledit-go-to-lisp] -- transfer to Lisp job and transmit saved text.
  \\[ledit-go-to-liszt] -- transfer to Liszt (Lisp compiler) job
	   and transmit saved text.
\\{ledit-mode-map}
To make Lisp mode automatically change to Ledit mode,
do (setq lisp-mode-hook 'ledit-from-lisp-mode)"
  (interactive)
  (lisp-mode)
  (ledit-from-lisp-mode))

;;;###autoload
(defun ledit-from-lisp-mode ()
  (use-local-map ledit-mode-map)
  (setq mode-name "Ledit")
  (setq major-mode 'ledit-mode)
  (run-hooks 'ledit-mode-hook))

(provide 'ledit)

;;; ledit.el ends here