view lisp/play/studly.el @ 13413:12b63cc21bdb

[HAVE_NTGUI]: Include w32term.h. [HAVE_NTGUI] (KBD_BUFFER_SIZE): Increase for NT window system. [HAVE_NTGUI] (POLL_FOR_INPUT): Define. [HAVE_NTGUI] (kbd_buffer_get_event): Enable windowing and menu events. [HAVE_NTGUI] (lispy_function_keys): Define array for NT. [HAVE_NTGUI] (make_lispy_event): Enable menu bar events. [HAVE_NTGUI] (modify_event_symbol): Map symbol to keysym. [HAVE_NTGUI] (read_char_x_menu_prompt): Display menus. (FUNCTION_KEY_OFFSET): New macro. (make_lispy_event): Use FUNCTION_KEY_OFFSET to modify event codes before applying modifiers. Use HAVE_WINDOW_SYSTEM instead of testing for specific window systems.

;;; studly.el --- StudlyCaps (tm)(r)(c)(xxx)

;;; This is in the public domain, since it was distributed
;;; by its author without a copyright notice in 1986.

;; Keywords: games

;;; Commentary:

;; Functions to studlycapsify a region, word, or buffer.  Possibly the
;; esoteric significance of studlycapsification escapes you; that is,
;; you suffer from autostudlycapsifibogotification.  Too bad.

;;; Code:

(defun studlify-region (begin end)
  "Studlify-case the region"
  (interactive "*r")
  (save-excursion
    (goto-char begin)
    (setq begin (point))
    (while (and (<= (point) end)
		(not (looking-at "\\W*\\'")))
      (forward-word 1)
      (backward-word 1)
      (setq begin (max (point) begin))
      (forward-word 1)
      (let ((offset 0)
	    (word-end (min (point) end))
	    c)
	(goto-char begin)
	(while (< (point) word-end)
	  (setq offset (+ offset (following-char)))
	  (forward-char 1))
	(setq offset (+ offset (following-char)))
	(goto-char begin)
	(while (< (point) word-end)
	  (setq c (following-char))
	  (if (and (= (% (+ c offset) 4) 2)
		   (let ((ch (following-char)))
		     (or (and (>= ch ?a) (<= ch ?z))
			 (and (>= ch ?A) (<= ch ?Z)))))
	      (progn
		(delete-char 1)
		(insert (logxor c ? ))))
	  (forward-char 1))
	(setq begin (point))))))

(defun studlify-word (count)
  "Studlify-case the current word, or COUNT words if given an argument"
  (interactive "*p")
  (let ((begin (point)) end rb re)
    (forward-word count)
    (setq end (point))
    (setq rb (min begin end) re (max begin end))
    (studlify-region rb re)))

(defun studlify-buffer ()
  "Studlify-case the current buffer"
  (interactive "*")
  (studlify-region (point-min) (point-max)))

;;; studly.el ends here