view lisp/cedet/srecode/el.el @ 110309:14a601b405fc

SQL Mode, Version 2.6 * progmodes/sql.el: Version 2.6 (sql-dialect): Synonym for "sql-product". (sql-find-sqli-buffer, sql-set-sqli-buffer-generally) (sql-set-sqli-buffer, sql-show-sqli-buffer, sql-interactive-mode): Set "sql-buffer" to buffer name not buffer object so multiple sql interactive buffers work properly. Reverts misguided changes in earlier work. (sql-comint): Make sure different buffer name is used if "*SQL*" buffer is for a different product. (sql-make-alternate-buffer-name): Fix bug with "sql-database" login param. (sql-oracle, sql-sybase, sql-informix, sql-sqlite, sql-mysql) (sql-solid, sql-ingres, sql-ms, sql-postgres, sql-interbase) (sql-db2, sql-linter, sql-product-interactive, sql-rename-buffer): Accept new buffer name or prompt for one. (sql-port): Default to zero. (sql-comint-mysql): Handle "sql-port" as a numeric. (sql-port-history): Delete unused variable. (sql-get-login): Default "sql-port" to a number. (sql-product-alist): Correct Postgres prompt and terminator regexp. (sql-sqlite-program): Dynamically detect presence of "sqlite" or "sqlite3" executables. (sql-sqlite-login-params): Add "*.sqlite[23]?" database name pattern. (sql-buffer-live-p): New function. (sql-mode-menu, sql-send-string): Use it. (sql-mode-oracle-font-lock-keywords): Improve SQL*Plus REMARK syntax pattern. (sql-mode-postgres-font-lock-keywords): Support Postgres V9. (sql-mode-sqlite-font-lock-keywords): Hilight sqlite commands.

;;; srecode/el.el --- Emacs Lisp specific arguments

;; Copyright (C) 2008, 2009, 2010  Free Software Foundation, Inc.

;; Author: Eric M. Ludlam <[e-mail]>

;; This file is part of GNU Emacs.

;; GNU Emacs is free software: you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.

;;; Commentary:
;;
;; Emacs Lisp specific handlers.  To use these handlers in your
;; template, add the :name part to your template argument list.
;;
;; Error if not in a Emacs Lisp mode

;;; Code:

(require 'srecode)
(require 'srecode/semantic)

(declare-function semanticdb-brute-find-tags-by-class "semantic/db-find")

;;;###autoload
(defun srecode-semantic-handle-:el (dict)
  "Add macros into the dictionary DICT based on the current Emacs Lisp file.
Adds the following:
  PRENAME - The common name prefix of this file."
  (let* ((names (append (semantic-find-tags-by-class 'function (current-buffer))
			(semantic-find-tags-by-class 'variable (current-buffer)))
		)
	 (common (try-completion "" names)))

    (srecode-dictionary-set-value dict "PRENAME" common)
    ))

;;;###autoload
(defun srecode-semantic-handle-:el-custom (dict)
  "Add macros into the dictionary DICT based on the current Emacs Lisp file.
Adds the following:
  GROUP - The 'defgroup' name we guess you want for variables.
  FACEGROUP - The `defgroup' name you might want for faces."
  (require 'semantic/db-find)
  (let ((groups (semanticdb-strip-find-results
		 (semanticdb-brute-find-tags-by-class 'customgroup)))
	(varg nil)
	(faceg nil)
	)

    ;; Pick the best group
    (while groups
      (cond ((string-match "face" (semantic-tag-name (car groups)))
	     (setq faceg (car groups)))
	    ((not varg)
	     (setq varg (car groups)))
	    (t
	     ;; What about other groups?
	     ))
      (setq groups (cdr groups)))

    ;; Double check the facegroup.
    (setq faceg (or faceg varg))

    ;; Setup some variables
    (srecode-dictionary-set-value dict "GROUP" (semantic-tag-name varg))
    (srecode-dictionary-set-value dict "FACEGROUP" (semantic-tag-name faceg))

    ))

(define-mode-local-override srecode-semantic-apply-tag-to-dict
  emacs-lisp-mode (tagobj dict)
  "Apply Emacs Lisp specific features from TAGOBJ into DICT.
Calls `srecode-semantic-apply-tag-to-dict-default' first."
  (srecode-semantic-apply-tag-to-dict-default tagobj dict)

  ;; Pull out the tag for the individual pieces.
  (let* ((tag (oref tagobj :prime))
	 (doc (semantic-tag-docstring tag)))

    ;; It is much more common to have doc on ELisp.
    (srecode-dictionary-set-value dict "DOC" doc)

    (cond
     ;;
     ;; FUNCTION
     ;;
     ((eq (semantic-tag-class tag) 'function)
      (if (semantic-tag-get-attribute tag :user-visible-flag)
	  (srecode-dictionary-set-value dict "INTERACTIVE" "  (interactive)\n  ")
	(srecode-dictionary-set-value dict "INTERACTIVE" ""))))))


(provide 'srecode/el)

;; Local variables:
;; generated-autoload-file: "loaddefs.el"
;; generated-autoload-load-name: "srecode/el"
;; End:

;; arch-tag: c1852a36-d45b-4263-8f3e-03f4f3c795d9
;;; srecode/el.el ends here