Mercurial > emacs

view msdos/sed1.inp @ 7228:14df71736eae

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
(gnus-summary-mode-map): Bind # to gnus-uu-mark-article. (gnus-uu-mark-article): Autoload it from gnus-uu.
author Richard M. Stallman <rms@gnu.org>
date Sat, 30 Apr 1994 20:15:08 +0000
parents 9f8b6ebe1d7e
children 520d3d20651f
line wrap: on
line source

# -sed1.inp-------------------------------------------------------------
# Configuration script for makefile.in-in
# ----------------------------------------------------------------------
s/^#.*//
s/^[ \f\t][ \f\t]*$//
s/^ /	/
/^obj=/s!$! dosfns.o msdos.o!
/window.elc/s!window.elc!window.elc ${lispdir}dos-fns.elc!
s/\.h\.in/.h-in/
s!^.-if.*inc-vers.*$!#!
s!^	\./temacs!	go32 temacs!
s!/bin/sh!command.com!
/^MAKE *=/s/^/# /
/^SHELL *=/s/^/# /
/^srcdir *=/s/@[^@\n]+@/./
/^VPATH *=/s/@[^@\n]+@/./
/^CC *=/s/@[^@\n]+@/gcc/
/^CPP *=/s/@[^@\n]+@/gcc -e/
/^CFLAGS *=/s/@[^@\n]+@/-O2 -g/
/^LN_S *=/s/@[^@\n]+@/ln -s/
/^M_FILE *=/s!@[^@\n]+@!m/dos386.h!
/^S_FILE *=/s!@[^@\n]+@!s/msdos.h!
/^@SET_MAKE@$/s/@SET_MAKE@//
/DEBUG_MOLE *=/s/=.*$/=/
/^.\${libsrc}make-doc/s!>.*$!!
/^.\${libsrc}make-docfile/s!make-docfile!make-docfile -o ../etc/DOC!
/^.\${libsrc}make-docfile/s/\$/go32 $/
/^[ 	]*$/d