view msdos/sed1.inp @ 20504:1b8aec1c12f1

Doc fixes. Changed `append' to `nconc' in a number of places. Changed the separator in menus from "---" to "--" to work in Windows 95. (msb--home-path): New internal variable to cache the value of $HOME. (msb--strip-path): Now handles MSDOG style of file names. (msb--init-file-alist): Now expands `buffer-file-name'. (msb--format-title): New subroutine for `msb--choose-file-menu'. (msb--choose-file-menu): Use msb--format-title. Minor simplifications.

# -sed1.inp-------------------------------------------------------------
# Configuration script for src/makefile
# ----------------------------------------------------------------------
#
# In case src/Makefile needs to rebuild `make-doc.exe' (might happen under
# Windows 95), make sure it gets built with commands that DOS
# understands (one command per line).
s/^#.*//
s/^[ \f\t][ \f\t]*$//
s/^ /	/
s/\.h\.in/.h-in/
s!^	\./temacs!	go32 temacs!
s!/bin/sh!command.com!
/^MAKE *=/s/^/# /
/^SHELL *=/s/^/# /
/^srcdir *=/s/@[^@\n]*@/./
/^VPATH *=/s/@[^@\n]*@/./
/^CC *=/s/@[^@\n]*@/gcc/
/^CPP *=/s/@[^@\n]*@/gcc -e/
/^CFLAGS *=/s/@[^@\n]*@/-O2 -g/
/^LN_S *=/s/@[^@\n]*@/ln -s/
/^M_FILE *=/s!@[^@\n]*@!m/intel386.h!
/^S_FILE *=/s!@[^@\n]*@!s/msdos.h!
/^@SET_MAKE@$/s/@SET_MAKE@//
/^.\${libsrc}make-docfile.*>/s!make-docfile!make-doc.exe -o ../etc/DOC!
/^.\${libsrc}make-doc/s!>.*$!!
/^\${libsrc}make-docfile:/c\
${libsrc}make-doc.exe:\
	cd ..\
	cd lib-src\
	$(MAKE) ${MFLAGS} make-docfile -W make-docfile.c\
	cd ..\
	cd src
/^	cd \${libsrc}; \${MAKE} \${MFLAGS} make-docfile/d
/\${libsrc}make-docfile/s/-docfile[ 	]/-doc.exe /
/^[ 	]*$/d
/^temacs:/s/prefix-args//
/^temacs:/s/stamp-oldxmenu//
/^	#/d