view lisp/play/studly.el @ 69088:1e05f30609d3

(org-mark-ring-previous, org-mark-ring-set): New commands. (org-mark-ring): New variable. (org-mark-ring-length): New option. (org-open-at-point, org-goto, org-open-file): Push old position onto the mark ring. (org-add-hook): New function. (org-export-table-remove-special-lines): New option. (org-skip-comments, org-format-org-table-html): Respect new option `org-export-table-remove-special-lines'. (org-open-file): Allow special command configuration for directory link. (org-file-apps): Fixed bugs in customize type, added setting for directories. (org-activate-tags, org-format-agenda-item, org-complete) (org-get-tags-at, org-scan-tags, org-make-tags-matcher) (org-get-tags, org-get-buffer-tags, org-open-at-point) (org-link-search, org-make-org-heading-search-string) (org-make-org-heading-camel): Allow @ and 0-9 as tags characters. (org-radio-targets, org-file-link-context-use-camel-case) (org-activate-camels): New options. (org-update-radio-target-regexp, org-all-targets) (org-make-target-link-regexp, org-activate-target-links): New functions. (org-make-org-heading-search-string): New function. (org-store-link, org-insert-link): Use new option `org-file-link-context-use-camel-case'. (org-activate-camels): Use new option `org-activate-camels'. (org-link-regexp): Added mhe prefix. (org-open-at-point,org-store-link): Support for mhe links. (org-mhe-get-message-id, org-mhe-get-message-folder) (org-mhe-get-header,org-follow-mhe-link): New functions. (org-remove-angle-brackets, org-add-angle-brackets): New functions. (org-bracked-link-regexp): New constant. (org-read-date): Fixed bug that was rejecting all typed dates. (org-link-search): Make hierarchy above visible after a match. (org-follow-bbdb-link): Inhibit electric mode for BBDB. (org-store-link): Fixed bug with link creation when cursor is in an empty line. (org-open-at-point): Fixed bug with matching a link. Fixed buggy argument sequence in call to `org-view-tags'. (org-compile-prefix-format): Set `org-prefix-has-tag'. (org-prefix-has-tag): New variable. (org-format-agenda-item): Remove tags from headline if appropriate. (org-agenda-remove-tags-when-in-prefix): New option.

;;; studly.el --- StudlyCaps (tm)(r)(c)(xxx)

;;; This is in the public domain, since it was distributed
;;; by its author without a copyright notice in 1986.

;; This file is part of GNU Emacs.

;; Maintainer: FSF
;; Keywords: games

;;; Commentary:

;; Functions to studlycapsify a region, word, or buffer.  Possibly the
;; esoteric significance of studlycapsification escapes you; that is,
;; you suffer from autostudlycapsifibogotification.  Too bad.

;;; Code:

;;;###autoload
(defun studlify-region (begin end)
  "Studlify-case the region."
  (interactive "*r")
  (save-excursion
    (goto-char begin)
    (setq begin (point))
    (while (and (<= (point) end)
		(not (looking-at "\\W*\\'")))
      (forward-word 1)
      (backward-word 1)
      (setq begin (max (point) begin))
      (forward-word 1)
      (let ((offset 0)
	    (word-end (min (point) end))
	    c)
	(goto-char begin)
	(while (< (point) word-end)
	  (setq offset (+ offset (following-char)))
	  (forward-char 1))
	(setq offset (+ offset (following-char)))
	(goto-char begin)
	(while (< (point) word-end)
	  (setq c (following-char))
	  (if (and (= (% (+ c offset) 4) 2)
		   (let ((ch (following-char)))
		     (or (and (>= ch ?a) (<= ch ?z))
			 (and (>= ch ?A) (<= ch ?Z)))))
	      (progn
		(delete-char 1)
		(insert (logxor c ? ))))
	  (forward-char 1))
	(setq begin (point))))))

;;;###autoload
(defun studlify-word (count)
  "Studlify-case the current word, or COUNT words if given an argument."
  (interactive "*p")
  (let ((begin (point)) end rb re)
    (forward-word count)
    (setq end (point))
    (setq rb (min begin end) re (max begin end))
    (studlify-region rb re)))

;;;###autoload
(defun studlify-buffer ()
  "Studlify-case the current buffer."
  (interactive "*")
  (studlify-region (point-min) (point-max)))

(provide 'studly)

;;; arch-tag: 0dbf5a60-d2e6-48c2-86ae-77fc8575ac67
;;; studly.el ends here