view lisp/scroll-all.el @ 99298:225286546090

Fix typos in docstrings. * cus-edit.el (customize-apropos-options, custom-comment) (custom-comment-tag, custom-face-edit-attribute-tag): Fix typos in docstrings. (custom-buffer-done-kill): Remove * from defcustom docstring. (custom-file): Fix typo in doc of defcustom choice. * frame.el (display-visual-class): Fix typo in docstring. (initial-frame-alist, minibuffer-frame-alist, pop-up-frame-alist) (special-display-frame-alist, show-trailing-whitespace) (auto-hscroll-mode, blink-cursor-delay, blink-cursor-interval) (display-hourglass, hourglass-delay, cursor-in-non-selected-windows): Remove * from defcustom docstrings. * md4.el (md4-buffer): Fix typo in docstring. (md4, md4-64): Doc fixes. (md4-pack-int32): Reflow docstring. * paths.el (rmail-file-name): Remove * from defcustom docstring. (prune-directory-list, gnus-nntp-service): Fix typos in docstrings. * rect.el (open-rectangle): Reflow docstring. (spaces-string): Fix docstring typo. Use "?\s" instead of "? ". * select.el (x-get-cut-buffer): Fix typo in docstring. * timezone.el (timezone-zone-to-minute, timezone-time-from-absolute) (timezone-time-zone-from-absolute, timezone-leap-year-p): Fix typos in docstrings. * emacs-lisp/assoc.el (asort, aelement, aput, aget, amake): Fix typos in docstrings.

;;; scroll-all.el --- scroll all buffers together minor mode

;; Copyright (C) 1997, 2001, 2002, 2003, 2004, 2005,
;;   2006, 2007, 2008 Free Software Foundation, Inc.

;; Author: Gary D. Foster <[e-mail]>
;; Keywords: scroll crisp brief lock

;; This file is part of GNU Emacs.

;; GNU Emacs is free software: you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.

;;; Commentary:
;;    This mode allows multiple buffers to be 'locked' so that scrolling
;;    up or down lines in any buffer causes all the buffers to mirror
;;    the scrolling.  It hooks into the post-command-hook to check for
;;    potential scrolling commands and if we're locked, mirrors them in all
;;    windows.  This allows us to grab line-at-a-time scrolling as well as
;;    screen-at-a-time scrolling, and doesn't remap any of the keyboard
;;    commands to do it.

;; You can enable and disable this mode with the 'scroll-all-mode' command.

;; Suggestions/ideas from:
;;    Rick Macdonald <[e-mail]>
;;    Anders Lindgren <[e-mail]>

;;; Code:

(defun scroll-all-function-all (func arg)
  "Apply function FUNC with argument ARG to all visible windows."
  (let ((num-windows (count-windows))
	(count 1))
    (when (> num-windows 1)
      (other-window 1)
      (while (< count num-windows)
	(condition-case nil
	    (funcall func arg)
	  ;; Ignore beginning- or end-of-buffer error in other windows.
	  (error nil)
	  )
	(other-window 1)
	(setq count (1+ count))))))

(defun scroll-all-scroll-down-all (arg)
  "Scroll down in all visible windows."
  (interactive "p")
  (scroll-all-function-all 'next-line arg))

(defun scroll-all-scroll-up-all (arg)
  "Scroll up in all visible windows."
  (interactive "p")
  (scroll-all-function-all 'previous-line arg))

(defun scroll-all-page-down-all (arg)
  "Page down in all visible windows."
  (interactive "P")
  (scroll-all-function-all 'scroll-up arg))

(defun scroll-all-page-up-all (arg)
  "Page up in all visible windows."
  (interactive "P")
  (scroll-all-function-all 'scroll-down arg))

(defun scroll-all-beginning-of-buffer-all (arg)
  "Go to the beginning of the buffer in all visible windows."
  (interactive "P")
  (scroll-all-function-all 'beginning-of-buffer arg))

(defun scroll-all-end-of-buffer-all (arg)
  "Go to the end of the buffer in all visible windows."
  (interactive "P")
  (scroll-all-function-all 'end-of-buffer arg))


(defun scroll-all-check-to-scroll ()
  "Check `this-command' to see if a scroll is to be done."
  (cond ((eq this-command 'next-line)
	 (call-interactively 'scroll-all-scroll-down-all))
	((eq this-command 'previous-line)
	 (call-interactively 'scroll-all-scroll-up-all))
	((eq this-command 'scroll-up)
	 (call-interactively 'scroll-all-page-down-all))
	((eq this-command 'scroll-down)
	 (call-interactively 'scroll-all-page-up-all))
	((eq this-command 'beginning-of-buffer)
	 (call-interactively 'scroll-all-beginning-of-buffer-all))
	((eq this-command 'end-of-buffer)
	 (call-interactively 'scroll-all-end-of-buffer-all))))


;;;###autoload
(define-minor-mode scroll-all-mode
  "Toggle Scroll-All minor mode.
With ARG, turn Scroll-All minor mode on if ARG is positive, off otherwise.
When Scroll-All mode is on, scrolling commands entered in one window
apply to all visible windows in the same frame."
  nil " *SL*" nil
  :global t
  :group 'windows
  :group 'scrolling
  (if scroll-all-mode
      (add-hook 'post-command-hook 'scroll-all-check-to-scroll)
    (remove-hook 'post-command-hook 'scroll-all-check-to-scroll)))

(provide 'scroll-all)

;; arch-tag: db20089a-b157-45df-b5d4-2430e60acdd8
;;; scroll-all.el ends here