view msdos/sed1v2.inp @ 55749:230865f1c59d

(gdb-server-prefix): New variable. (gud-watch, gdb-send-item, gdb-breakpoints-mode, gdb-frames-mode) (gdb-locals-mode, gdb-send-item, gdb-toggle-breakpoint) (gdb-delete-breakpoint, gdb-frames-select, gdb-threads-buffer) (gdb-registers-buffer, gdb-reset, gdb-assembler-buffer): Handle new value for gud-minor-mode (gdbmi). (gdb-buffer-type, gdb-input-queue, gdb-prompting) (gdb-output-sink, gdb-current-item, gdb-pending-triggers): Change from local to global gdb variable set. (gdb-ann3): Initialise above gdb variable set. (gdb-var-update, gdb-var-update-handler, gdb-enqueue-input) (gdb-dequeue-input, gdb-source, gdb-pre-prompt, gdb-prompt) (gdb-subprompt, gdb-starting, gdb-stopping, gdb-frame-begin) (gdb-stopped, gdb-post-prompt, gdb-concat-output) (def-gdb-auto-update-trigger, def-gdb-auto-update-handler) (gdb-info-locals-handler, gdb-invalidate-assembler) (gdb-get-current-frame, gdb-frame-handler): Handle gdb variable set as global variables. (gdb-get-create-buffer): Don't make gud-comint buffer-local. Handle gdbmi. (gdb-info-breakpoints-custom): Fix regexp. (def-gdb-var): Delete.

# -sed1v2.inp-----------------------------------------------------------
# Configuration script for src/Makefile under DJGPP v2.x
# ----------------------------------------------------------------------
#
# Copyright (C) 1996, 1997, 1999, 2000, 2002
#   Free Software Foundation, Inc.
#
# This file is part of GNU Emacs.
#
# This file is free software; as a special exception, the author gives
# unlimited permission to copy and/or distribute it, with or without
# modifications, as long as this notice is preserved.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
#
# ----------------------------------------------------------------------
s/^#.*//
s/^[ \f\t][ \f\t]*$//
s/^ /	/
s/\.h\.in/.h-in/
/^	LC_ALL=C \.\/temacs/i\
	stubedit temacs.exe minstack=100k
/^	LC_ALL=C.*temacs/s/LC_ALL=C/set &;/
/^MAKE *=/s/^/# /
/^SHELL *=/s/^/# /
/^srcdir *=/s/@[^@\n]*@/./
/^VPATH *=/s/@[^@\n]*@/./
/^CC *=/s/@[^@\n]*@/gcc/
/^CPP *=/s/@[^@\n]*@/gcc -e/
/^CFLAGS *=/s/@[^@\n]*@/-O2 -gcoff/
/^CPPFLAGS *=/s/@[^@\n]*@//
/^LDFLAGS *=/s/@[^@\n]*@//
/^LIBS *=/s/@[^@\n]*@//
/^LIBOBJS *=/s/@[^@\n]*@/getloadavg.o/
/^GETLOADAVG_LIBS *=/s/@[^@\n]*@//
/^LIBSOUND *=/s/@LIBSOUND@//
/^EXEEXT *=/s/@EXEEXT@//
/^LN_S *=/s/@[^@\n]*@/ln -s/
/^M_FILE *=/s!@[^@\n]*@!m/intel386.h!
/^S_FILE *=/s!@[^@\n]*@!s/msdos.h!
/^@SET_MAKE@$/s/@SET_MAKE@//
/^.\${libsrc}make-docfile.*>/s!make-docfile!make-docfile -o ../etc/DOC!
/^.\${libsrc}make-doc/s!>.*$!!
/^[ 	]*$/d
/^temacs:/s/prefix-args//
/^temacs:/s/stamp-oldxmenu//
/^	mv \.\/\.gdbinit/d
/^	if test -f/c\
	command.com /c if exist .gdbinit rm -f _gdbinit
/^	else mv \.\/\.gdbinit/d
/^	#/d
/^	cd.*make-docfile/s!$!; cd ${dot}${dot}/src!
s/bootstrap-emacs/b-emacs/
s/bootstrap-temacs/b-temacs/
s/bootstrap-doc/b-doc/
/rm -f bootstrap-emacs/s/b-emacs/b-emacs b-emacs.exe/
/^	els=/c\
	${libsrc}make-docfile -o ${etc}DOC -d ${srcdir} ${SOME_MACHINE_LISP:.elc=.el} ${shortlisp:.elc=.el} ${SOME_MACHINE_OBJECTS} ${obj}
/^	mv -f emacs/a\
	stubify b-emacs\
	stubedit b-emacs.exe minstack=1024k\
	rm -f emacs.exe temacs.exe emacs
/^	rm -f/s/\\#/#/

# arch-tag: c7e3aacb-4162-460e-99f9-4252bca68d2c