view lisp/emacs-lisp/benchmark.el @ 105870:26baacb565b0

* textmodes/tex-mode.el (tex-alt-dvi-print-command) (tex-dvi-print-command, tex-bibtex-command, tex-start-commands) (tex-start-options, slitex-run-command, latex-run-command) (tex-run-command, tex-directory): * textmodes/ispell.el (ispell-html-skip-alists) (ispell-tex-skip-alists, ispell-tex-skip-alists): * textmodes/fill.el (adaptive-fill-first-line-regexp): (adaptive-fill-regexp): * textmodes/dns-mode.el (auto-mode-alist): * progmodes/python.el (interpreter-mode-alist): * progmodes/etags.el (tags-compression-info-list): * progmodes/etags.el (tags-file-name): * net/browse-url.el (browse-url-galeon-program) (browse-url-firefox-program): * mail/sendmail.el (mail-signature-file) (mail-citation-prefix-regexp): * international/mule-conf.el (eight-bit): * international/latexenc.el (latex-inputenc-coding-alist): * international/fontset.el (x-pixel-size-width-font-regexp): * emacs-lisp/warnings.el (warning-type-format): * emacs-lisp/trace.el (trace-buffer): * emacs-lisp/lisp-mode.el (lisp-interaction-mode-map) (emacs-lisp-mode-map): * calendar/holidays.el (holiday-solar-holidays) (holiday-bahai-holidays, holiday-islamic-holidays) (holiday-christian-holidays, holiday-hebrew-holidays) (hebrew-holidays-4, hebrew-holidays-3, hebrew-holidays-2) (hebrew-holidays-1, holiday-oriental-holidays) (holiday-general-holidays): * x-dnd.el (x-dnd-known-types): * tool-bar.el (tool-bar): * startup.el (site-run-file): * shell.el (shell-dumb-shell-regexp): * rfn-eshadow.el (file-name-shadow-tty-properties) (file-name-shadow-properties): * paths.el (remote-shell-program, news-directory): * mouse.el ([C-down-mouse-3]): * menu-bar.el (menu-bar-tools-menu): * jka-cmpr-hook.el (jka-compr-load-suffixes) (jka-compr-mode-alist-additions, jka-compr-compression-info-list) (jka-compr-compression-info-list): * isearch.el (search-whitespace-regexp): * image-file.el (image-file-name-extensions): * find-dired.el (find-ls-option): * files.el (directory-listing-before-filename-regexp) (directory-free-space-args, insert-directory-program) (list-directory-brief-switches, magic-fallback-mode-alist) (magic-fallback-mode-alist, auto-mode-interpreter-regexp) (automount-dir-prefix): * faces.el (face-x-resources, x-font-regexp, x-font-regexp-head) (x-font-regexp-slant, x-font-regexp-weight, face-x-resources) (face-font-registry-alternatives, face-font-registry-alternatives) (face-font-family-alternatives): * facemenu.el (facemenu-add-new-face, facemenu-background-menu) (facemenu-foreground-menu, facemenu-face-menu): * epa-hook.el (epa-file-name-regexp): * dnd.el (dnd-protocol-alist): * textmodes/rst.el (auto-mode-alist): * button.el (default-button): Purecopy strings.

;;; benchmark.el --- support for benchmarking code

;; Copyright (C) 2003, 2004, 2005, 2006, 2007, 2008, 2009
;;   Free Software Foundation, Inc.

;; Author: Dave Love  <[e-mail]>
;; Keywords: lisp, extensions

;; This file is part of GNU Emacs.

;; GNU Emacs is free software: you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.

;;; Commentary:

;; Utilities for timing the execution of forms, including the time
;; taken for GC.  Note that prior to timing code you may want to
;; ensure things like:  there has just been a GC, the relevant code is
;; already loaded (so that there's no overhead from autoloading etc.),
;; and the code is compiled if appropriate (but see
;; `benchmark-run-compiled').

;;; Code:

(defmacro benchmark-elapse (&rest forms)
  "Return the time in seconds elapsed for execution of FORMS."
  (let ((t1 (make-symbol "t1"))
	(t2 (make-symbol "t2")))
    `(let (,t1 ,t2)
       (setq ,t1 (current-time))
       ,@forms
       (setq ,t2 (current-time))
       (+ (* (- (car ,t2) (car ,t1)) 65536.0)
	  (- (nth 1 ,t2) (nth 1 ,t1))
	  (* (- (nth 2 ,t2) (nth 2 ,t1)) 1.0e-6)))))
(put 'benchmark-elapse 'edebug-form-spec t)
(put 'benchmark-elapse 'lisp-indent-function 0)

;;;###autoload
(defmacro benchmark-run (&optional repetitions &rest forms)
  "Time execution of FORMS.
If REPETITIONS is supplied as a number, run forms that many times,
accounting for the overhead of the resulting loop.  Otherwise run
FORMS once.
Return a list of the total elapsed time for execution, the number of
garbage collections that ran, and the time taken by garbage collection.
See also `benchmark-run-compiled'."
  (unless (natnump repetitions)
    (setq forms (cons repetitions forms)
	  repetitions 1))
  (let ((i (make-symbol "i"))
	(gcs (make-symbol "gcs"))
	(gc (make-symbol "gc")))
    `(let ((,gc gc-elapsed)
	   (,gcs gcs-done))
       (list ,(if (> repetitions 1)
		  ;; Take account of the loop overhead.
		  `(- (benchmark-elapse (dotimes (,i ,repetitions)
					  ,@forms))
		      (benchmark-elapse (dotimes (,i ,repetitions))))
		`(benchmark-elapse ,@forms))
	     (- gcs-done ,gcs)
	     (- gc-elapsed ,gc)))))
(put 'benchmark-run 'edebug-form-spec t)
(put 'benchmark-run 'lisp-indent-function 2)

;;;###autoload
(defmacro benchmark-run-compiled (&optional repetitions &rest forms)
  "Time execution of compiled version of FORMS.
This is like `benchmark-run', but what is timed is a funcall of the
byte code obtained by wrapping FORMS in a `lambda' and compiling the
result.  The overhead of the `lambda's is accounted for."
  (unless (natnump repetitions)
    (setq forms (cons repetitions forms)
	  repetitions 1))
  (let ((i (make-symbol "i"))
	(gcs (make-symbol "gcs"))
	(gc (make-symbol "gc"))
	(code (byte-compile `(lambda () ,@forms)))
	(lambda-code (byte-compile `(lambda ()))))
    `(let ((,gc gc-elapsed)
	   (,gcs gcs-done))
       (list ,(if (> repetitions 1)
		  ;; Take account of the loop overhead.
		  `(- (benchmark-elapse (dotimes (,i ,repetitions)
					  (funcall ,code)))
		      (benchmark-elapse (dotimes (,i ,repetitions)
					  (funcall ,lambda-code))))
		`(benchmark-elapse (funcall ,code)))
	     (- gcs-done ,gcs) (- gc-elapsed ,gc)))))
(put 'benchmark-run-compiled 'edebug-form-spec t)
(put 'benchmark-run-compiled 'lisp-indent-function 2)

;;;###autoload
(defun benchmark (repetitions form)
  "Print the time taken for REPETITIONS executions of FORM.
Interactively, REPETITIONS is taken from the prefix arg.
For non-interactive use see also `benchmark-run' and
`benchmark-run-compiled'."
  (interactive "p\nxForm: ")
  (let ((result (eval `(benchmark-run ,repetitions ,form))))
    (if (zerop (nth 1 result))
	(message "Elapsed time: %fs" (car result))
      (message "Elapsed time: %fs (%fs in %d GCs)" (car result)
	       (nth 2 result) (nth 1 result)))))

(provide 'benchmark)

;; arch-tag: be570e24-4b51-4784-adf3-fa2b56c31946
;;; benchmark.el ends here