view lisp/gnus/nngateway.el @ 112432:27320025ed54

Merge chages made in Gnus trunk. mailcap.el (mailcap-mime-extensions): Rename text/org to text/x-org. gnus-draft.el (gnus-group-send-queue): Update the queue group in the group buffer after sending the queue. gnus-draft.el (gnus-group-send-queue): Really refresh the queue group after sending. gnus-agent.el (gnus-agent-send-mail): Ditto. gnus-group.el (gnus-group-refresh-group): New convenience function. message.el (message-bogus-addresses): Remove commented-out value. message.el (message-check-recipients): Display the encoded version of the bogus address if they differ. flow-fill.el (fill-flowed): Make `delete-space' option correspond to "DelSp" parameter in RFC3676. gnus-sum.el (gnus-summary-move-article): Protect against backends (i.e., nnimap) returning nil as the article number.

;;; nngateway.el --- posting news via mail gateways

;; Copyright (C) 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004,
;;   2005, 2006, 2007, 2008, 2009, 2010, 2011 Free Software Foundation, Inc.

;; Author: Lars Magne Ingebrigtsen <[e-mail]>
;; Keywords: news, mail

;; This file is part of GNU Emacs.

;; GNU Emacs is free software: you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.

;;; Commentary:

;;; Code:

(eval-when-compile (require 'cl))
(require 'nnoo)
(require 'message)

(nnoo-declare nngateway)

(defvoo nngateway-address nil
  "Address of the mail-to-news gateway.")

(defvoo nngateway-header-transformation 'nngateway-simple-header-transformation
  "Function to be called to rewrite the news headers into mail headers.
It is called narrowed to the headers to be transformed with one
parameter -- the gateway address.")

;;; Interface functions

(nnoo-define-basics nngateway)

(deffoo nngateway-open-server (server &optional defs)
  (if (nngateway-server-opened server)
      t
    (unless (assq 'nngateway-address defs)
      (setq defs (append defs (list (list 'nngateway-address server)))))
    (nnoo-change-server 'nngateway server defs)))

(deffoo nngateway-request-post (&optional server)
  (when (or (nngateway-server-opened server)
	    (nngateway-open-server server))
    ;; Rewrite the header.
    (let ((buf (current-buffer)))
      (with-temp-buffer
	(insert-buffer-substring buf)
	(message-narrow-to-head)
	(funcall nngateway-header-transformation nngateway-address)
	(goto-char (point-max))
	(insert mail-header-separator "\n")
	(widen)
	(let (message-required-mail-headers)
	  (funcall (or message-send-mail-real-function
		       message-send-mail-function)))
	t))))

;;; Internal functions

(defun nngateway-simple-header-transformation (gateway)
  "Transform the headers to use GATEWAY."
  (let ((newsgroups (mail-fetch-field "newsgroups")))
    (message-remove-header "to")
    (message-remove-header "cc")
    (goto-char (point-min))
    (insert "To: " (nnheader-replace-chars-in-string newsgroups ?. ?-)
	    "@" gateway "\n")))

(defun nngateway-mail2news-header-transformation (gateway)
  "Transform the headers for sending to a mail2news gateway."
  (message-remove-header "to")
  (message-remove-header "cc")
  (goto-char (point-min))
  (insert "To: " gateway "\n"))

(nnoo-define-skeleton nngateway)

(provide 'nngateway)

;;; nngateway.el ends here