view lisp/tabify.el @ 25002:28d5af43eeb6

Rewritten. (append_glyph): New. (update_end): Turn cursor on only if selected window's cursor_off_p flag is not set. (TS_cursor_visible): Renamed from TS_visual_mode. (TS_cursor_normal): Renamed from TS_end_visual_mode. (TS_cursor_invisible): New. (term_init): Initialize TS_cursor_invisible. (tty_hide_cursor): New. (tty_show_cursor): New. (update_end): Show tty cursor. (update_begin): Hide tty cursor to prevent cursor flickering during redisplays triggered by timers (stealth fontification). (estimate_mode_line_height): New. (estimate_mode_line_height_hook): New. (OUTPUT_IF): Make replacement text have statement form. (OUTPUT1_IF): Ditto. (TS_italic_mode, TS_end_italic_mode): Removed. (TS_bold_mode): Removed. (TS_underscore_mode, TS_end_underscore_mode): Removed. (TS_enter_bold_mode, TS_enter_dim_mode, TS_enter_blink_mode): New. (TS_enter_reverse_mode): New. (TS_enter_underline_mode, TS_exit_underline_mode): New. (TN_magic_cookie_glitch_ul): New. (TS_enter_alt_charset_mode, TS_exit_alt_charset_mode): New. (TS_exit_attribute_mode): New. (TN_max_colors, TN_max_pairs, TS_orig_pairs): New. (TS_set_foreground, TS_set_background): New. (reset_terminal_modes): Switch colors back to default. (write_glyphs): Turn face on before writing text, turn it off afterwards. (insert_glyphs): Ditto. (term_init): Initialize new terminal capability variables. (turn_on_face): Turn a face on. (turn_off_face): Turn a face off. (global): Rewrite for new glyphs.

;;; tabify.el --- tab conversion commands for Emacs

;; Copyright (C) 1985, 1994 Free Software Foundation, Inc.

;; Maintainer: FSF

;; This file is part of GNU Emacs.

;; GNU Emacs is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation; either version 2, or (at your option)
;; any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs; see the file COPYING.  If not, write to the
;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
;; Boston, MA 02111-1307, USA.

;;; Commentary:

;; Commands to optimize spaces to tabs or expand tabs to spaces in a region
;; (`tabify' and `untabify').  The variable tab-width does the obvious.

;;; Code:

;;;###autoload
(defun untabify (start end)
  "Convert all tabs in region to multiple spaces, preserving columns.
Called non-interactively, the region is specified by arguments
START and END, rather than by the position of point and mark.
The variable `tab-width' controls the spacing of tab stops."
  (interactive "r")
  (save-excursion
    (save-restriction
      (narrow-to-region (point-min) end)
      (goto-char start)
      (while (search-forward "\t" nil t)	; faster than re-search
	(forward-char -1)
	(let ((tab-beg (point))
	      (indent-tabs-mode nil)
	      column)
	  (skip-chars-forward "\t")
	  (setq column (current-column))
	  (delete-region tab-beg (point))
	  (indent-to column))))))

(defvar tabify-regexp "[ \t][ \t]+"
  "Regexp matching whitespace that tabify should consider.
Usually this will be \"[ \\t][ \\t]+\" to match two or more spaces or tabs.
\"^[ \\t]+\" is also useful, for tabifying only initial whitespace.")

;;;###autoload
(defun tabify (start end)
  "Convert multiple spaces in region to tabs when possible.
A group of spaces is partially replaced by tabs
when this can be done without changing the column they end at.
Called non-interactively, the region is specified by arguments
START and END, rather than by the position of point and mark.
The variable `tab-width' controls the spacing of tab stops."
  (interactive "r")
  (save-excursion
    (save-restriction
      ;; Include the beginning of the line in the narrowing
      ;; since otherwise it will throw off current-column.
      (goto-char start)
      (beginning-of-line)
      (narrow-to-region (point) end)
      (goto-char start)
      (while (re-search-forward tabify-regexp nil t)
	(let ((column (current-column))
	      (indent-tabs-mode t))
	  (delete-region (match-beginning 0) (point))
	  (indent-to column))))))

(provide 'tabify)

;;; tabify.el ends here