view m4/getopt.m4 @ 103406:2a3d145eef1e

Remove the term "on-line" (meaning "Info") throughout, since in this day and age the common meaning is "on the web". (copying): Use @copyright in all cases. (Basic keys): Remove reference to deleted manual node "Text Characters". (File-name conventions): Use GNU as an example rather than SERVICE. default.el lives in site-lisp. Update Info directory location. (Real meaning of copyleft): GPL actions have been brought, but all settled out of court. (Guidelines for newsgroup postings): Shorten section title. Simplify comp.emacs description. (Newsgroup archives): Change Google URL. Describe Gmane. (Unsubscribing from Emacs lists): Remove discussion of "distribution points". Mention List-Unsubscribe header. (Contacting the FSF): Update email and URLs. (Basic editing): Mention F1 for help. (Installing Texinfo documentation): Refer to Texinfo website rather than ftp server. (Printing a Texinfo file): Mention texi2pdf. (Informational files for Emacs): Don't describe FTP or SERVICE, they are just stubs nowadays. (Latest version of Emacs): Explain version numbers. (Spell-checkers, Checking TeX and *roff documents): Remove sections. (Turning on syntax highlighting): No need to mention hilit19 any more. (Finding Emacs on the Internet): Refer to URLs rather than DISTRIB, FTP. (Modes for various languages): Remove section. (Major packages and programs): Remove most version and maintainer information - it's hard to keep up-to-date, and adds nothing. Similarly with direct links to mailing lists. (Spell-checkers): Rename node from Ispell. Mention Aspell and Hunspell. (Mailcrypt): Remove section - mailcrypt has not been updated in mnay years, and Emacs comes with tools for this now. (Patch): Remove section - this is a standard tool. (Using function keys under X): Remove section.

# getopt.m4 serial 10
dnl Copyright (C) 2002,2003,2004,2005,2006,2007 Free Software Foundation, Inc.
dnl This file is free software; the Free Software Foundation
dnl gives unlimited permission to copy and/or distribute it,
dnl with or without modifications, as long as this notice is preserved.

# The getopt module assume you want GNU getopt, with getopt_long etc,
# rather than vanilla POSIX getopt.  This means your your code should
# always include <getopt.h> for the getopt prototypes.

AC_DEFUN([gl_GETOPT_SUBSTITUTE],
[
  AC_LIBOBJ([getopt])
  AC_LIBOBJ([getopt1])
  gl_GETOPT_SUBSTITUTE_HEADER
  gl_PREREQ_GETOPT
])

AC_DEFUN([gl_GETOPT_SUBSTITUTE_HEADER],
[
  GETOPT_H=getopt.h
  AC_DEFINE([__GETOPT_PREFIX], [[rpl_]],
    [Define to rpl_ if the getopt replacement functions and variables
     should be used.])
  AC_SUBST([GETOPT_H])
])

AC_DEFUN([gl_GETOPT_CHECK_HEADERS],
[
  GETOPT_H=
  AC_CHECK_HEADERS([getopt.h], [], [GETOPT_H=getopt.h])
  if test -z "$GETOPT_H"; then
    AC_CHECK_FUNCS([getopt_long_only], [], [GETOPT_H=getopt.h])
  fi

  dnl BSD getopt_long uses an incompatible method to reset option processing,
  dnl and (as of 2004-10-15) mishandles optional option-arguments.
  if test -z "$GETOPT_H"; then
    AC_CHECK_DECL([optreset], [GETOPT_H=getopt.h], [], [#include <getopt.h>])
  fi

  dnl Solaris 10 getopt doesn't handle `+' as a leading character in an
  dnl option string (as of 2005-05-05).
  if test -z "$GETOPT_H"; then
    AC_CACHE_CHECK([for working GNU getopt function], [gl_cv_func_gnu_getopt],
      [AC_RUN_IFELSE(
	[AC_LANG_PROGRAM([#include <getopt.h>],
	   [[
	     char *myargv[3];
	     myargv[0] = "conftest";
	     myargv[1] = "-+";
	     myargv[2] = 0;
	     return getopt (2, myargv, "+a") != '?';
	   ]])],
	[gl_cv_func_gnu_getopt=yes],
	[gl_cv_func_gnu_getopt=no],
	[dnl cross compiling - pessimistically guess based on decls
	 dnl Solaris 10 getopt doesn't handle `+' as a leading character in an
	 dnl option string (as of 2005-05-05).
	 AC_CHECK_DECL([getopt_clip],
	   [gl_cv_func_gnu_getopt=no], [gl_cv_func_gnu_getopt=yes],
	   [#include <getopt.h>])])])
    if test "$gl_cv_func_gnu_getopt" = "no"; then
      GETOPT_H=getopt.h
    fi
  fi
])

AC_DEFUN([gl_GETOPT_IFELSE],
[
  AC_REQUIRE([gl_GETOPT_CHECK_HEADERS])
  AS_IF([test -n "$GETOPT_H"], [$1], [$2])
])

AC_DEFUN([gl_GETOPT], [gl_GETOPT_IFELSE([gl_GETOPT_SUBSTITUTE])])

# Prerequisites of lib/getopt*.
AC_DEFUN([gl_PREREQ_GETOPT], [:])

ifelse(dnl	Do not change this comment
   arch-tag: 6c64a021-551c-4a7f-9c63-cd7e1ce54707
)dnl