view msdos/sed1.inp @ 30341:2ad638704621

(IT_note_mode_line_highlight, IT_note_mouse_highlight): Record the object that generated the help echo and the position of that object in help_echo_object and help_echo_pos. Record that some glyphs in a row are displayed in mouse-face. (IT_update_begin): Don't clear mouse highlight unless one of the enabled glyph rows is marked as being displayed in mouse-face. (dos_rawgetc): Generate 2 events for HELP_EVENT. Pass the object and position recorded in help_echo_object and help_echo_pos to the event queue. (IT_menu_display): Accept a new argument PN: the pane number of the current menu pane. Record the pane number and the item number of the item which has associated help string. (XMenuActivate): Update the prototype for help_callback in function declaration. Call IT_menu_display with the current menu pane number as an additional argument. Call help_callback with two additional arguments: the pane number and the item number of the menu item associated with the help text. (help_echo_object, help_echo_pos): New variables. (syms_of_msdos): Initialize them and staticpro help_echo_object. (help_echo_window): New variable. (syms_of_msdos): Initialize and staticpro it. (IT_note_mode_line_highlight): Set help_echo_window. (IT_note_mouse_highlight): Ditto. (dos_rawgetc): Store help_echo_window in the second event produced for HELP_EVENTs.

# -sed1.inp-------------------------------------------------------------
# Configuration script for src/makefile
# ----------------------------------------------------------------------
#
# In case src/Makefile needs to rebuild `make-doc.exe' (might happen under
# Windows 95), make sure it gets built with commands that DOS
# understands (one command per line).
s/^#.*//
s/^[ \f\t][ \f\t]*$//
s/^ /	/
s/\.h\.in/.h-in/
s!^	\./temacs!	go32 temacs!
s!/bin/sh!command.com!
/^MAKE *=/s/^/# /
/^SHELL *=/s/^/# /
/^srcdir *=/s/@[^@\n]*@/./
/^VPATH *=/s/@[^@\n]*@/./
/^CC *=/s/@[^@\n]*@/gcc/
/^CPP *=/s/@[^@\n]*@/gcc -e/
/^CFLAGS *=/s/@[^@\n]*@/-O2 -g/
/^LIBS *=/s/@[^@\n]*@//
/^LIBOBJS *=/s/@[^@\n]*@//
/^LN_S *=/s/@[^@\n]*@/ln -s/
/^M_FILE *=/s!@[^@\n]*@!m/intel386.h!
/^S_FILE *=/s!@[^@\n]*@!s/msdos.h!
/^@SET_MAKE@$/s/@SET_MAKE@//
/^.\${libsrc}make-docfile.*>/s!make-docfile!make-doc.exe -o ../etc/DOC!
/^.\${libsrc}make-doc/s!>.*$!!
/^\${libsrc}make-docfile:/c\
${libsrc}make-doc.exe:\
	cd ..\
	cd lib-src\
	$(MAKE) ${MFLAGS} make-docfile -W make-docfile.c\
	cd ..\
	cd src
/^	cd \${libsrc}; \${MAKE} \${MFLAGS} make-docfile/d
/\${libsrc}make-docfile/s/-docfile[ 	]/-doc.exe /
/^[ 	]*$/d
/^temacs:/s/prefix-args//
/^temacs:/s/stamp-oldxmenu//
/^	#/d