view lisp/gnus/gnus-gravatar.el @ 110661:2b8ece636433

Merge changes made in Gnus trunk. nndraft.el (nndraft-request-expire-articles): Use the group name instead if "nndraft". gnus.texi (Using IMAP): Remove the @acronyms from the headings. nnregistry.el: Added. nnimap.el (nnimap-insert-partial-structure): Be way more permissive when interpreting the structures. GNUS-NEWS: Minor error in GNUS-NEWS - password-cache.el. nnimap.el (nnimap-request-accept-article): Add \r\n to the lines to make this work with Cyrus. gnus-registry.el: Don't prompt on load, which makes it impossible to build Gnus. gnus-gravatar.el: Add gnus-gravatar-properties. gnus-agent.el, gnus-art.el, gnus-bookmark.el, gnus-dired.el, gnus-group.el,\ gnus-int.el, gnus-msg.el, gnus-registry.el, gnus-score.el, gnus-srvr.el,\ gnus-sum.el, gnus-topic.el, gnus-util.el, gnus.el, mm-decode.el, mm-util.el,\ mm-view.el, mml-smime.el, mml.el, nnmairix.el, nnrss.el, smime.el:\ Introduce gnus-completing-read. gnus-util.el: Make completing-read function configurable. gnus-util.el: Add requires and fix history for iswitchb. webmail.el: Remove netscape/my-deja, since they no longer exist. gnus.el (gnus-local-domain): Declare variable obsolete. nnimap.el (nnimap-insert-partial-structure): Get the type from the correct slot, too. pop3.el (pop3-send-streaming-command, pop3-stream-length): New variable. nnimap.el (nnimap-open-connection): Revert the auto-network->starttls code. nnimap.el (nnimap-request-set-mark): Erase the buffer before issuing commands. nnimap.el (nnimap-split-rule): Mark as obsolete. gnus-sum.el (gnus-valid-move-group-p): Make sure that `group' is a symbol. nnimap.el (nnimap-split-incoming-mail): Allow `default' as nnimap-split-methods value. nnimap.el (nnimap-request-article): Downcase the NILs so that they are nil. nndoc.el (nndoc-retrieve-groups): New function. gnus.texi: Fix Gravatar documentation.

;;; gnus-gravatar.el --- Gnus Gravatar support

;; Copyright (C) 2010 Free Software Foundation, Inc.

;; Author: Julien Danjou <[e-mail]>
;; Keywords: news

;; This file is part of GNU Emacs.

;; GNU Emacs is free software: you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.

;;; Commentary:

;;; Code:

(require 'gravatar)

(defgroup gnus-gravatar nil
  "Gnus Gravatar."
  :group 'gnus-visual)

(defcustom gnus-gravatar-size 32
  "How big should gravatars be displayed."
  :type 'integer
  :version "24.1"
  :group 'gnus-gravatar)

(defcustom gnus-gravatar-properties '(:ascent center :relief 1)
  "List of image properties applied to Gravatar images."
  :type 'list
  :version "24.1"
  :group 'gnus-gravatar)

(defun gnus-gravatar-transform-address (header category)
  (gnus-with-article-headers
    (let ((addresses
           (mail-header-parse-addresses
            ;; mail-header-parse-addresses does not work (reliably) on
            ;; decoded headers.
            (or
             (ignore-errors
               (mail-encode-encoded-word-string
                (or (mail-fetch-field header) "")))
             (mail-fetch-field header)))))
      (let ((gravatar-size gnus-gravatar-size))
        (dolist (address addresses)
          (gravatar-retrieve
           (car address)
           'gnus-gravatar-insert
           (list header address category)))))))

(defun gnus-gravatar-insert (gravatar header address category)
  "Insert GRAVATAR for ADDRESS in HEADER in current article buffer.
Set image category to CATEGORY."
  (unless (eq gravatar 'error)
    (gnus-with-article-headers
      (gnus-article-goto-header header)
      (mail-header-narrow-to-field)
      (let ((real-name (cdr address))
            (mail-address (car address)))
        (when (if real-name             ; have a realname, go for it!
                  (and (search-forward real-name nil t)
                       (search-backward real-name nil t))
                (and (search-forward mail-address nil t)
                     (search-backward mail-address nil t)))
          (goto-char (1- (point)))
          ;; If we're on the " quoting the name, go backward
          (when (looking-at "\"")
            (goto-char (1- (point))))
          ;; Do not do anything if there's already a gravatar. This can
          ;; happens if the buffer has been regenerated in the mean time, for
          ;; example we were fetching someaddress, and then we change to
          ;; another mail with the same someaddress.
          (unless (memq 'gnus-gravatar (text-properties-at (point)))
            (let ((inhibit-read-only t)
                  (point (point))
                  (gravatar (append
                             gravatar
                             gnus-gravatar-properties)))
              (gnus-put-image gravatar nil category)
              (put-text-property point (point) 'gnus-gravatar address)
              (gnus-add-wash-type category)
              (gnus-add-image category gravatar))))))))

;;;###autoload
(defun gnus-treat-from-gravatar ()
  "Display gravatar in the From header.
If gravatar is already displayed, remove it."
  (interactive)
  (gnus-with-article-buffer
    (if (memq 'from-gravatar gnus-article-wash-types)
        (gnus-delete-images 'from-gravatar)
      (gnus-gravatar-transform-address "from" 'from-gravatar))))

;;;###autoload
(defun gnus-treat-mail-gravatar ()
  "Display gravatars in the Cc and To headers.
If gravatars are already displayed, remove them."
  (interactive)
    (gnus-with-article-buffer
      (if (memq 'mail-gravatar gnus-article-wash-types)
          (gnus-delete-images 'mail-gravatar)
        (gnus-gravatar-transform-address "cc" 'mail-gravatar)
        (gnus-gravatar-transform-address "to" 'mail-gravatar))))

(provide 'gnus-gravatar)

;;; gnus-gravatar.el ends here