view m4/getopt.m4 @ 93808:2c72483f42c9

(diary-view-entries-initially-flag): Rename view-diary-entries-initially. Keep old name as alias, update users. (calendar-mark-diary-entries-flag): Rename mark-diary-entries-in-calendar. Keep old name as alias, update users. (calendar-view-holidays-initially-flag): Rename view-calendar-holidays-initially. Keep old name as alias, update users. (calendar-mark-holidays-flag): Rename mark-holidays-in-calendar. Keep old name as alias, update users. (calendar-initial-window-hook): Rename initial-calendar-window-hook. Keep old name as alias, update users. (calendar-today-visible-hook): Rename today-visible-calendar-hook. Keep old name as alias, update users. (calendar-today-invisible-hook): Rename today-invisible-calendar-hook. Keep old name as alias, update users. (diary-iso-date-forms): Rename iso-date-diary-pattern. Update users. (diary-american-date-forms): Rename american-date-diary-pattern. Keep old name as alias, update users. (diary-european-date-forms): Rename european-date-diary-pattern. Keep old name as alias, update users. (calendar-iso-date-display-form): Rename iso-calendar-display-form. Keep old name as alias, update users. (calendar-european-date-display-form): Rename european-calendar-display-form. Keep old name as alias, update users. (calendar-american-date-display-form): Rename european-calendar-display-form. Keep old name as alias, update users. (diary-show-holidays-flag): Rename holidays-in-diary-buffer. Keep old name as alias, update users. (holiday-general-holidays): Rename general-holidays. Keep old name as alias, update users. (holiday-oriental-holidays): Rename oriental-holidays. Keep old name as alias, update users. (holiday-local-holidays): Rename local-holidays. Keep old name as alias, update users. (holiday-other-holidays): Rename other-holidays. Keep old name as alias, update users. (holiday-hebrew-holidays): Rename hebrew-holidays. Keep old name as alias, update users. (holiday-christian-holidays): Rename christian-holidays. Keep old name as alias, update users. (holiday-islamic-holidays): Rename islamic-holidays. Keep old name as alias, update users. (holiday-bahai-holidays): Rename bahai-holidays. Keep old name as alias, update users. (holiday-solar-holidays): Rename solar-holidays. Keep old name as alias, update users. (diary-fancy-buffer): Rename fancy-diary-buffer. Keep old name as alias, update users. (calendar-other-calendars-buffer): Rename other-calendars-buffer. Update users. (calendar-hebrew-yahrzeit-buffer): Rename cal-hebrew-yahrzeit-buffer. Update users. (calendar-increment-month): Rename increment-calendar-month. Keep old name as alias, update callers. (calendar-increment-month-cons): Rename old calendar-increment-month. Update callers. (calendar-extract-month): Rename extract-calendar-month. Keep old name as alias, update callers (calendar-extract-day): Rename extract-calendar-day. Keep old name as alias, update callers. (calendar-extract-year): Rename extract-calendar-year. Keep old name as alias, update callers. (calendar-generate-window): Rename generate-calendar-window. Update callers. (calendar-generate): Rename generate-calendar. Update callers. (calendar-generate-month): Rename generate-calendar-month. Update callers. (calendar-redraw): Rename redraw-calendar. Update callers. (calendar-describe-mode): Rename describe-calendar-mode. Update uses. (calendar-mouse-other-month): Rename mouse-calendar-other-month. Update callers. (calendar-update-mode-line): Rename update-calendar-mode-line. Update callers. (calendar-exit): Rename exit-calendar. Keep old name as alias, update callers. (calendar-mark-visible-date): Rename mark-visible-calendar-date. Keep old name as alias, update callers.

# getopt.m4 serial 10
dnl Copyright (C) 2002,2003,2004,2005,2006,2007 Free Software Foundation, Inc.
dnl This file is free software; the Free Software Foundation
dnl gives unlimited permission to copy and/or distribute it,
dnl with or without modifications, as long as this notice is preserved.

# The getopt module assume you want GNU getopt, with getopt_long etc,
# rather than vanilla POSIX getopt.  This means your your code should
# always include <getopt.h> for the getopt prototypes.

AC_DEFUN([gl_GETOPT_SUBSTITUTE],
[
  AC_LIBOBJ([getopt])
  AC_LIBOBJ([getopt1])
  gl_GETOPT_SUBSTITUTE_HEADER
  gl_PREREQ_GETOPT
])

AC_DEFUN([gl_GETOPT_SUBSTITUTE_HEADER],
[
  GETOPT_H=getopt.h
  AC_DEFINE([__GETOPT_PREFIX], [[rpl_]],
    [Define to rpl_ if the getopt replacement functions and variables
     should be used.])
  AC_SUBST([GETOPT_H])
])

AC_DEFUN([gl_GETOPT_CHECK_HEADERS],
[
  GETOPT_H=
  AC_CHECK_HEADERS([getopt.h], [], [GETOPT_H=getopt.h])
  if test -z "$GETOPT_H"; then
    AC_CHECK_FUNCS([getopt_long_only], [], [GETOPT_H=getopt.h])
  fi

  dnl BSD getopt_long uses an incompatible method to reset option processing,
  dnl and (as of 2004-10-15) mishandles optional option-arguments.
  if test -z "$GETOPT_H"; then
    AC_CHECK_DECL([optreset], [GETOPT_H=getopt.h], [], [#include <getopt.h>])
  fi

  dnl Solaris 10 getopt doesn't handle `+' as a leading character in an
  dnl option string (as of 2005-05-05).
  if test -z "$GETOPT_H"; then
    AC_CACHE_CHECK([for working GNU getopt function], [gl_cv_func_gnu_getopt],
      [AC_RUN_IFELSE(
	[AC_LANG_PROGRAM([#include <getopt.h>],
	   [[
	     char *myargv[3];
	     myargv[0] = "conftest";
	     myargv[1] = "-+";
	     myargv[2] = 0;
	     return getopt (2, myargv, "+a") != '?';
	   ]])],
	[gl_cv_func_gnu_getopt=yes],
	[gl_cv_func_gnu_getopt=no],
	[dnl cross compiling - pessimistically guess based on decls
	 dnl Solaris 10 getopt doesn't handle `+' as a leading character in an
	 dnl option string (as of 2005-05-05).
	 AC_CHECK_DECL([getopt_clip],
	   [gl_cv_func_gnu_getopt=no], [gl_cv_func_gnu_getopt=yes],
	   [#include <getopt.h>])])])
    if test "$gl_cv_func_gnu_getopt" = "no"; then
      GETOPT_H=getopt.h
    fi
  fi
])

AC_DEFUN([gl_GETOPT_IFELSE],
[
  AC_REQUIRE([gl_GETOPT_CHECK_HEADERS])
  AS_IF([test -n "$GETOPT_H"], [$1], [$2])
])

AC_DEFUN([gl_GETOPT], [gl_GETOPT_IFELSE([gl_GETOPT_SUBSTITUTE])])

# Prerequisites of lib/getopt*.
AC_DEFUN([gl_PREREQ_GETOPT], [:])

ifelse(dnl	Do not change this comment
   arch-tag: 6c64a021-551c-4a7f-9c63-cd7e1ce54707
)dnl