view lisp/textmodes/po.el @ 61394:31aa9a390538

* mh-customize.el (mh-speedbar-selected-folder-face): Special case high number of colors displays. * textmodes/table.el (table-cell-face): Add special case for displays supporting a high number of colors. * progmodes/vhdl-mode.el (vhdl-font-lock-prompt-face) (vhdl-font-lock-reserved-words-face) (vhdl-speedbar-architecture-face) (vhdl-speedbar-instantiation-face) (vhdl-speedbar-architecture-selected-face) (vhdl-speedbar-instantiation-selected-face): Likewise. * progmodes/sh-script.el (sh-heredoc-face): Likewise. * progmodes/idlw-help.el (idlwave-help-link-face): Likewise. * progmodes/ebrowse.el (ebrowse-tree-mark-face) (ebrowse-root-class-face, ebrowse-member-attribute-face) (ebrowse-progress-face): Likewise. * progmodes/compile.el (compilation-info-face): Likewise. * progmodes/cc-fonts.el (c-invalid-face): Likewise. * emacs-lisp/re-builder.el (reb-match-3): Likewise. * calendar/calendar.el (diary-face): Likewise. * woman.el (woman-italic-face, woman-bold-face) (woman-unknown-face): Likewise. * wid-edit.el (widget-button-pressed-face): Likewise. * whitespace.el (whitespace-highlight-face): Likewise. * smerge-mode.el (smerge-mine-face, smerge-base-face): Likewise. * pcvs-info.el (cvs-marked-face): Likewise. * info.el (info-xref): Likewise. * ido.el (ido-subdir-face, ido-indicator-face): Likewise. * hilit-chg.el (highlight-changes-face) (highlight-changes-delete-face): Likewise. * hi-lock.el (hi-yellow, hi-green, hi-blue-b, hi-green-b) (hi-red-b): Likewise. * generic-x.el (show-tabs-tab-face, show-tabs-space-face): Likewise. * font-lock.el (font-lock-keyword-face) (font-lock-function-name-face, font-lock-warning-face): Likewise. * cus-edit.el (custom-invalid-face, custom-modified-face) (custom-set-face, custom-changed-face, custom-variable-tag-face) (custom-group-tag-face-1, custom-group-tag-face): Likewise. * comint.el (comint-highlight-prompt): Likewise.

;;; po.el --- basic support of PO translation files -*- coding: latin-1; -*-

;; Copyright (C) 1995-1998, 2000-2002 Free Software Foundation, Inc.

;; Authors: François Pinard <[e-mail]>,
;;          Greg McGary <[e-mail]>,
;;          Bruno Haible <[e-mail]>.
;; Keywords: i18n, files

;; This file is part of GNU Emacs.

;; GNU Emacs is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation; either version 2, or (at your option)
;; any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs; see the file COPYING.  If not, write to the
;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
;; Boston, MA 02111-1307, USA.

;;; Commentary:

;; This package makes sure visiting PO files decodes them correctly,
;; according to the Charset= header in the PO file.  For more support
;; for editing PO files, see po-mode.el.

;;; Code:

(defconst po-content-type-charset-alist
  '(("ASCII" . undecided)
    ("ANSI_X3.4-1968" . undecided)
    ("US-ASCII" . undecided))
  "Alist of coding system versus GNU libc/libiconv canonical charset name.
Contains canonical charset names that don't correspond to coding systems.")

(defun po-find-charset (filename)
  "Return PO charset value for FILENAME."
  (let ((charset-regexp
	 "^\"Content-Type:[ \t]*text/plain;[ \t]*charset=\\(.*\\)\\\\n\"")
	(short-read nil))
    ;; Try the first 4096 bytes.  In case we cannot find the charset value
    ;; within the first 4096 bytes (the PO file might start with a long
    ;; comment) try the next 4096 bytes repeatedly until we'll know for sure
    ;; we've checked the empty header entry entirely.
    (while (not (or short-read (re-search-forward "^msgid" nil t)))
      (save-excursion
        (goto-char (point-max))
	(let ((pair (insert-file-contents-literally filename nil
						    (1- (point))
						    (1- (+ (point) 4096)))))
	  (setq short-read (< (nth 1 pair) 4096)))))
    (cond ((re-search-forward charset-regexp nil t) (match-string 1))
	  (short-read nil)
	  ;; We've found the first msgid; maybe, only a part of the msgstr
	  ;; value was loaded.  Load the next 1024 bytes; if charset still
	  ;; isn't available, give up.
	  (t (save-excursion
	       (goto-char (point-max))
	       (insert-file-contents-literally filename nil
					       (1- (point))
					       (1- (+ (point) 1024))))
	     (if (re-search-forward charset-regexp nil t)
		 (match-string 1))))))

(defun po-find-file-coding-system-guts (operation filename)
  "Return a (DECODING . ENCODING) pair for OPERATION on PO file FILENAME.
Do so according to FILENAME's declared charset."
  (and
   (eq operation 'insert-file-contents)
   (file-exists-p filename)
   (with-temp-buffer
     (let* ((coding-system-for-read 'no-conversion)
	    (charset (or (po-find-charset filename) "ascii"))
	    assoc)
       (list (cond
	      ((setq assoc
		     (assoc-ignore-case charset
					po-content-type-charset-alist))
	       (cdr assoc))
	      ((or (setq assoc (assoc-ignore-case charset coding-system-alist))
		   (setq assoc
			 (assoc-ignore-case (subst-char-in-string ?_ ?-
								  charset)
					    coding-system-alist)))
	       (intern (car assoc)))
	      ;; In principle we should also check the `mime-charset'
	      ;; property of everything in the base coding system
	      ;; list, but there should always be a coding system
	      ;; corresponding to the MIME name.
	      ((featurep 'code-pages)
	       ;; Give up.
	       'raw-text)
	      (t
	       ;; Try again with code-pages loaded.  Maybe it's best
	       ;; to require it initially?
	       (require 'code-pages nil t)
	       (if (or
		    (setq assoc (assoc-ignore-case charset coding-system-alist))
		    (setq assoc (assoc-ignore-case (subst-char-in-string
						    ?_ ?- charset)
						   coding-system-alist)))
		   (intern (car assoc))
		 'raw-text))))))))

;;;###autoload
(defun po-find-file-coding-system (arg-list)
  "Return a (DECODING . ENCODING) pair, according to PO file's charset.
Called through `file-coding-system-alist', before the file is visited for real."
  (po-find-file-coding-system-guts (car arg-list) (car (cdr arg-list))))
;; This is for XEmacs.
;(defun po-find-file-coding-system (operation filename)
;  "\
;Return a Mule (DECODING . ENCODING) pair, according to PO file charset.
;Called through file-coding-system-alist, before the file is visited for real."
;  (po-find-file-coding-system-guts operation filename))

(provide 'po)

;;; arch-tag: 56748a57-d64c-4200-8f6b-c3a70496eb8c
;;; po.el ends here