view lisp/erc/erc-menu.el @ 87315:34b619baa980

Replace all instances of string-to-int with string-to-number, insert-string with insert, and read-input with read-string. (top-level): No need to require imenu, reporter, dinotrace, vc, font-lock when compiling. Always require compile. Relegate remaining compatibility cruft to XEmacs. Don't require font-lock. (verilog-version): Remove superfluous concat. (dinotrace-unannotate-all, zmacs-activate-region) (customize-apropos): No need to define. (verilog-regexp-opt): On Emacs, just make it an alias for regexp-opt. (verilog-font-lock-keywords, verilog-font-lock-keywords-1) (verilog-font-lock-keywords-2, verilog-font-lock-keywords-3) (verilog-startup-message-displayed): These are variables, not constants. (verilog-batch-execute-func, verilog-auto-inst) (verilog-auto-inst-param): Use mapc rather than mapcar. (sigs-in, sigs-inout, sigs-out): Define for compiler rather than actually defining. (verilog-modi-get-decls, verilog-modi-get-sub-decls) (verilog-modi-get-outputs, verilog-modi-get-inouts) (verilog-modi-get-inputs, verilog-modi-get-wires) (verilog-modi-get-regs, verilog-modi-get-assigns) (verilog-modi-get-consts, verilog-modi-get-gparams) (verilog-modi-get-sub-outputs, verilog-modi-get-sub-inouts) (verilog-modi-get-sub-inputs): Move inline functions earlier in the file. (sigs-in, sigs-out): Don't declare multiple times. (got-sig, got-rvalue, uses-delayed): Define for compiler with just `defvar'. (verilog-auto): Call dinotrace-unannotate-all only if bound. (verilog-module-inside-filename-p): No need to wrap fboundp test in condition-case. (reporter-submit-bug-report): Autoload it. (verilog-mark-defun): Call zmacs-activate-region only if bound. (verilog-font-customize): Call customize-apropos only if bound. (verilog-getopt-flags, verilog-auto-reeval-locals): Use make-local-variable rather than make-variable-buffer-local. (verilog-company, verilog-project, verilog-modi-cache-list): Move make-variable-buffer-local calls to top-level. (font-lock-defaults-alist): Don't define it. (verilog-need-fld): Remove. (verilog-font-lock-init): Don't set font-lock-defaults-alist. (verilog-mode): Only call make-local-hook on XEmacs. Set font-lock-defaults rather than using verilog-font-lock-init.

;; erc-menu.el -- Menu-bar definitions for ERC

;; Copyright (C) 2001, 2002, 2004, 2005, 2006,
;;   2007 Free Software Foundation, Inc.

;; Author: Mario Lang <[e-mail]>
;; Keywords: comm, processes, menu

;; This file is part of GNU Emacs.

;; GNU Emacs is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation; either version 3, or (at your option)
;; any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs; see the file COPYING.  If not, write to the
;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
;; Boston, MA 02110-1301, USA.

;;; Commentary:

;; Loading this file defines a menu for ERC.

;;; Code:

(require 'erc)
(require 'easymenu)

(defvar erc-menu-definition
  (list "ERC"
	["Connect to server..." erc t]
	["Disconnect from server..." erc-quit-server erc-server-connected]
	"-"
	["List channels..." erc-list-channels
	 (and erc-server-connected (fboundp 'erc-list-channels))]
	["Join channel..." erc-join-channel erc-server-connected]
	["Start a query..." erc-cmd-QUERY erc-server-connected]
	["Input action..." erc-input-action (erc-default-target)]
	"-"
	(list
	 "Current channel"
	 ["List users in channel" erc-channel-names erc-channel-users]
	 ["List channel operators" erc-cmd-OPS erc-channel-users]
	 ["Set topic..." erc-set-topic
	  (and (and (erc-default-target) (not (erc-query-buffer-p)))
	       (or (not (member "t" erc-channel-modes))
		   (erc-channel-user-op-p (erc-current-nick))))]
	 (list "Channel modes"
	       ["Change mode..." erc-insert-mode-command
		(erc-channel-user-op-p (erc-current-nick))]
	       ["No external send" (erc-toggle-channel-mode "n")
		:active (erc-channel-user-op-p (erc-current-nick))
		:style toggle :selected (member "n" erc-channel-modes)]
	       ["Topic set by channel operator" (erc-toggle-channel-mode "t")
		:style toggle :selected (member "t" erc-channel-modes)
		:active (erc-channel-user-op-p (erc-current-nick))]
	       ["Invite only" (erc-toggle-channel-mode "i")
		:style toggle :selected (member "i" erc-channel-modes)
		:active (erc-channel-user-op-p (erc-current-nick))]
	       ["Private" (erc-toggle-channel-mode "p")
		:style toggle :selected (member "p" erc-channel-modes)
		:active (erc-channel-user-op-p (erc-current-nick))]
	       ["Secret" (erc-toggle-channel-mode "s")
		:style toggle :selected (member "s" erc-channel-modes)
		:active (erc-channel-user-op-p (erc-current-nick))]
	       ["Moderated" (erc-toggle-channel-mode "m")
		:style toggle :selected (member "m" erc-channel-modes)
		:active (erc-channel-user-op-p (erc-current-nick))]
	       ["Set a limit..." erc-set-channel-limit
		(erc-channel-user-op-p (erc-current-nick))]
	       ["Set a key..." erc-set-channel-key
		(erc-channel-user-op-p (erc-current-nick))])
	 ["Leave this channel..." erc-part-from-channel erc-channel-users])
	"-"
	(list "Pals, fools and other keywords"
	      ["Add pal..." erc-add-pal]
	      ["Delete pal..." erc-delete-pal]
	      ["Add fool..." erc-add-fool]
	      ["Delete fool..." erc-delete-fool]
	      ["Add keyword..." erc-add-keyword]
	      ["Delete keyword..." erc-delete-keyword]
	      ["Add dangerous host..." erc-add-dangerous-host]
	      ["Delete dangerous host..." erc-delete-dangerous-host])
	"-"
	(list "IRC services"
	      ["Identify to NickServ..." erc-nickserv-identify
	       (and erc-server-connected (functionp 'erc-nickserv-identify))])
	"-"
	["Save buffer in log" erc-save-buffer-in-logs
	 (fboundp 'erc-save-buffer-in-logs)]
	["Truncate buffer" erc-truncate-buffer (fboundp 'erc-truncate-buffer)]
	"-"
	["Customize ERC" (customize-group 'erc) t]
	["Enable/Disable ERC Modules" (customize-variable 'erc-modules) t]
	["Show ERC version" erc-version t])
  "ERC menu definition.")

(defvar erc-menu-defined nil
  "Internal variable used to keep track of whether we've defined the
ERC menu yet.")

;;;###autoload (autoload 'erc-menu-mode "erc-menu" nil t)
(define-erc-module menu nil
  "Enable a menu in ERC buffers."
  ((unless erc-menu-defined
     ;; make sure the menu only gets defined once, since Emacs 22
     ;; activates it immediately
     (easy-menu-define erc-menu erc-mode-map "ERC menu" erc-menu-definition)
     (setq erc-menu-defined t))
   (if (featurep 'xemacs)
       (progn
	 ;; the menu isn't automatically added to the menu bar in
	 ;; XEmacs
	 (add-hook 'erc-mode-hook 'erc-menu-add)
	 (dolist (buffer (erc-buffer-list))
	   (with-current-buffer buffer (erc-menu-add))))
     (erc-menu-add)))
  ((if (featurep 'xemacs)
       (progn
	 (remove-hook 'erc-mode-hook 'erc-menu-add)
	 (dolist (buffer (erc-buffer-list))
	   (with-current-buffer buffer (erc-menu-remove))))
     (erc-menu-remove)
     ;; `easy-menu-remove' is a no-op in Emacs 22
     (message "You might have to restart Emacs to remove the ERC menu"))))

;; silence byte-compiler warning
(eval-when-compile
  (defvar erc-menu nil))

(defun erc-menu-add ()
  "Add the ERC menu to the current buffer."
  (easy-menu-add erc-menu erc-mode-map))

(defun erc-menu-remove ()
  "Remove the ERC menu from the current buffer."
  (easy-menu-remove erc-menu))

(provide 'erc-menu)

;;; erc-menu.el ends here
;;
;; Local Variables:
;; indent-tabs-mode: t
;; tab-width: 8
;; End:

;; arch-tag: 671219f2-b082-4753-a185-1d0c7e0c05bd