view lisp/net/hmac-def.el @ 87315:34b619baa980

Replace all instances of string-to-int with string-to-number, insert-string with insert, and read-input with read-string. (top-level): No need to require imenu, reporter, dinotrace, vc, font-lock when compiling. Always require compile. Relegate remaining compatibility cruft to XEmacs. Don't require font-lock. (verilog-version): Remove superfluous concat. (dinotrace-unannotate-all, zmacs-activate-region) (customize-apropos): No need to define. (verilog-regexp-opt): On Emacs, just make it an alias for regexp-opt. (verilog-font-lock-keywords, verilog-font-lock-keywords-1) (verilog-font-lock-keywords-2, verilog-font-lock-keywords-3) (verilog-startup-message-displayed): These are variables, not constants. (verilog-batch-execute-func, verilog-auto-inst) (verilog-auto-inst-param): Use mapc rather than mapcar. (sigs-in, sigs-inout, sigs-out): Define for compiler rather than actually defining. (verilog-modi-get-decls, verilog-modi-get-sub-decls) (verilog-modi-get-outputs, verilog-modi-get-inouts) (verilog-modi-get-inputs, verilog-modi-get-wires) (verilog-modi-get-regs, verilog-modi-get-assigns) (verilog-modi-get-consts, verilog-modi-get-gparams) (verilog-modi-get-sub-outputs, verilog-modi-get-sub-inouts) (verilog-modi-get-sub-inputs): Move inline functions earlier in the file. (sigs-in, sigs-out): Don't declare multiple times. (got-sig, got-rvalue, uses-delayed): Define for compiler with just `defvar'. (verilog-auto): Call dinotrace-unannotate-all only if bound. (verilog-module-inside-filename-p): No need to wrap fboundp test in condition-case. (reporter-submit-bug-report): Autoload it. (verilog-mark-defun): Call zmacs-activate-region only if bound. (verilog-font-customize): Call customize-apropos only if bound. (verilog-getopt-flags, verilog-auto-reeval-locals): Use make-local-variable rather than make-variable-buffer-local. (verilog-company, verilog-project, verilog-modi-cache-list): Move make-variable-buffer-local calls to top-level. (font-lock-defaults-alist): Don't define it. (verilog-need-fld): Remove. (verilog-font-lock-init): Don't set font-lock-defaults-alist. (verilog-mode): Only call make-local-hook on XEmacs. Set font-lock-defaults rather than using verilog-font-lock-init.

;;; hmac-def.el --- A macro for defining HMAC functions.

;; Copyright (C) 1999, 2001, 2007  Free Software Foundation, Inc.

;; Author: Shuhei KOBAYASHI <[e-mail]>
;; Keywords: HMAC, RFC 2104

;; This file is part of GNU Emacs.

;; GNU Emacs is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation; either version 3, or (at your option)
;; any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs; see the file COPYING.  If not, write to the
;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
;; Boston, MA 02110-1301, USA.

;;; Commentary:

;; This program is implemented from RFC 2104,
;; "HMAC: Keyed-Hashing for Message Authentication".

;;; Code:

(defmacro define-hmac-function (name H B L &optional bit)
  "Define a function NAME(TEXT KEY) which computes HMAC with function H.

HMAC function is H(KEY XOR opad, H(KEY XOR ipad, TEXT)):

H is a cryptographic hash function, such as SHA1 and MD5, which takes
a string and return a digest of it (in binary form).
B is a byte-length of a block size of H. (B=64 for both SHA1 and MD5.)
L is a byte-length of hash outputs. (L=16 for MD5, L=20 for SHA1.)
If BIT is non-nil, truncate output to specified bits."
  `(defun ,name (text key)
     ,(concat "Compute "
	      (upcase (symbol-name name))
	      " over TEXT with KEY.")
     (let ((key-xor-ipad (make-string ,B ?\x36))
	   (key-xor-opad (make-string ,B ?\x5C))
	   (len (length key))
	   (pos 0))
       (unwind-protect
	   (progn
	     ;; if `key' is longer than the block size, apply hash function
	     ;; to `key' and use the result as a real `key'.
	     (if (> len ,B)
		 (setq key (,H key)
		       len ,L))
	     (while (< pos len)
	       (aset key-xor-ipad pos (logxor (aref key pos) ?\x36))
	       (aset key-xor-opad pos (logxor (aref key pos) ?\x5C))
	       (setq pos (1+ pos)))
	     (setq key-xor-ipad (unwind-protect
				    (concat key-xor-ipad text)
				  (fillarray key-xor-ipad 0))
		   key-xor-ipad (unwind-protect
				    (,H key-xor-ipad)
				  (fillarray key-xor-ipad 0))
		   key-xor-opad (unwind-protect
				    (concat key-xor-opad key-xor-ipad)
				  (fillarray key-xor-opad 0))
		   key-xor-opad (unwind-protect
				    (,H key-xor-opad)
				  (fillarray key-xor-opad 0)))
	     ;; now `key-xor-opad' contains
	     ;; H(KEY XOR opad, H(KEY XOR ipad, TEXT)).
	     ,(if (and bit (< (/ bit 8) L))
		  `(substring key-xor-opad 0 ,(/ bit 8))
		;; return a copy of `key-xor-opad'.
		`(concat key-xor-opad)))
	 ;; cleanup.
	 (fillarray key-xor-ipad 0)
	 (fillarray key-xor-opad 0)))))

(provide 'hmac-def)

;;; arch-tag: 645adcef-b835-4900-a10a-11f636c982b9
;;; hmac-def.el ends here