view lisp/mail/vms-pmail.el @ 9704:39b34bbe59c9

(x_catch_errors, x_check_errors, x_had_errors_p) (x_uncatch_errors): Make the argument a display, not a frame. (XTread_socket_fake_io_error): New variable. (XTread_socket): Obey XTread_socket_fake_io_error. (x_initialize): Init x_noop_count, x_focus_frame and x_highlight_frame here. (x_term_init): Not here. (x_term_init): Open the connection first thing; if that fails, don't allocate dpyinfo. (x_delete_display): New function. (x_connection_closed): New args dpyinfo and error_message. Delete all frames on the dead display and all frames using them for minibuffers. Call x_delete_display. Maybe signal a Lisp error. (x_term_init): Don't report error here--just return 0. (x_scroll_bar_report_motion): Store proper value in *bar_window (the Emacs window, not the X window number). (x_scroll_bar_report_motion): Don't clear *fp. (x_wm_set_icon_pixmap): Use x_bitmap_pixmap. (show_mouse_face): New arg dpyinfo. All callers changed. (clear_mouse_face): New arg dpyinfo. All callers changed. (scratch_cursor_gc): Variable deleted. (dumpglyphs): Use scratch_cursor_gc in x_display_info. (syms_of_xterm): Don't staticpro mouse_face_window. (expose_all_windows, expose_all_icons): Variables deleted. (BLOCK_INPUT_mask): Variable deleted. (x_term_init): Set up x_id_name field. (x_id_name): Variable deleted. (x_font_table, x_font_table_size, x_n_fonts): Vars deleted. (x_new_font): Use new fields. (warp_mouse_on_deiconify): Unused variable deleted. (x_term_init): Set up dpyinfo->xrdb. Set up dpyinfo->vertical_scroll_bar_cursor. (x_scroll_bar_create): Use vertical_scroll_bar_cursor slot. (x_vertical_scroll_bar_cursor): Variable deleted. (x_term_init): Really return dpyinfo. (x_term_init): Call add_keyboard_wait_descriptor, not change_keyboard_wait_descriptor. (x_term_init): Pass new arg to init_sigio. Don't set old_fcntl_owner. Don't call change_input_fd. (XTread_socket): Loop over displays and process input from each. (x_display_name_list): New variable. (syms_of_xterm): staticpro it. Don't staticpro slots in the_x_screen. (x_term_init): Update x_display_name_list along with x_display_list. Actually malloc the x_display_info. (the_x_screen): Variable deleted.

;;; vms-pmail.el --- use Emacs as the editor within VMS mail.

;; Copyright (C) 1992 Free Software Foundation, Inc.

;; Author: Roland B Roberts <[e-mail]>
;; Keywords: vms

;; This file is part of GNU Emacs.

;; GNU Emacs is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation; either version 2, or (at your option)
;; any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs; see the file COPYING.  If not, write to
;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.

;;; Code:

;;;
;;; Quick hack to use emacs as mail editor.  There are a *bunch* of
;;; changes scattered throughout emacs to make this work, namely:
;;; (1) mod to sysdep.c to allow emacs to attach to a process other
;;;     than the one that originally spawned it.
;;; (2) mod to kepteditor.com to define the logical emacs_parent_pid
;;;     which is what sysdep.c looks for, and define the logical
;;;     emacs_command_args which contains the command line
;;; (3) mod to re-parse command line arguments from emacs_command_args
;;;     then execute them as though emacs were just starting up.
;;;
(defun vms-pmail-save-and-exit ()
  "Save current buffer and exit emacs.
If this emacs cannot be suspended, you will be prompted about modified
buffers other than the mail buffer.  BEWARE --- suspending emacs without
saving your mail buffer causes mail to abort the send (potentially useful
since the mail buffer is still here)."
  (interactive)
  (basic-save-buffer)
  (if (vms-system-info "LOGICAL" "DONT_SUSPEND_EMACS")
      (progn
        (save-some-buffers)
        (kill-emacs 1))
    (kill-buffer (current-buffer))
    (suspend-emacs)))

(defun vms-pmail-abort ()
  "Mark buffer as unmodified and exit emacs.
When the editor is exited without saving its buffer, VMS mail does not
send a message.  If you have other modified buffers you will be
prompted for what to do with them."
  (interactive)
  (if (not (yes-or-no-p "Really abort mail? "))
      (ding)
    (not-modified)
    (if (vms-system-info "LOGICAL" "DONT_SUSPEND_EMACS")
        (progn
          (save-some-buffers)
          (kill-emacs 1))
      (kill-buffer (current-buffer))
      (suspend-emacs))))

(defun vms-pmail-setup ()
  "Set up file assuming use by VMS MAIL utility.
The buffer is put into text-mode, auto-save is turned off and the
following bindings are established.

\\[vms-pmail-save-and-exit]	vms-pmail-save-and-exit
\\[vms-pmail-abort]	vms-pmail-abort

All other emacs commands are still available."
  (interactive)
  (auto-save-mode -1)
  (text-mode)
  (let ((default (vms-system-info "LOGICAL" "SYS$SCRATCH"))
        (directory (file-name-directory (buffer-file-name)))
        (filename (file-name-nondirectory (buffer-file-name))))
    (if (string= directory "SYS$SCRATCH:")
        (progn
          (cd default)
          (setq buffer-file-name (concat default filename))))
    (use-local-map (copy-keymap (current-local-map)))
    (local-set-key "\C-c\C-c" 'vms-pmail-save-and-exit)
    (local-set-key "\C-c\C-g" 'vms-pmail-abort)))

(defun indicate-mail-reply-text ()
  "Prepares received mail for re-sending by placing >'s on each line."
  (interactive)
  (goto-char (point-min))
  (while (not (eobp))
    (insert ">")
    (beginning-of-line)
    (forward-line 1))
  (set-buffer-modified-p nil)
  (goto-char (point-min)))

(defun insert-signature ()
  "Moves to the end of the buffer and inserts a \"signature\" file.
First try the file indicated by environment variable MAIL$TRAILER.
If that fails, try the file \"~/.signature\".
If neither file exists, fails quietly."
  (interactive)
  (end-of-buffer)
  (newline)
  (if (vms-system-info "LOGICAL" "MAIL$TRAILER")
      (if (file-attributes (vms-system-info "LOGICAL" "MAIL$TRAILER"))
	  (insert-file-contents (vms-system-info "LOGICAL" "MAIL$TRAILER"))
	(if (file-attributes "~/.signature")
	    (insert-file-contents "~/.signature")))))

;;; vms-pmail.el ends here