view lisp/emacs-lock.el @ 29402:3bb8d5adf524

byte-compile-dynamic since we typically don't use all the widgets. Don't require cl or widget. Remove eval-and-compile. Don't autoload finder-commentary. Doc fixes. (widget-read-event): Removed. Callers changed to use read-event. (widget-button-release-event-p): Renamed from button-release-event-p. (widget-field-add-space, widget-field-use-before-change): Uncustomize. (widget-specify-field): Use keymap property, not local-map. (widget-specify-button): Obey :suppress-face. (widget-specify-insert): Use modern backquote syntax. (widget-image-directory): Renamed from widget-glyph-directory. (widget-image-enable): Renamed from widget-glyph-enable. (widget-image-find): Replaces widget-glyph-find. (widget-button-pressed-face): Move defvar. (widget-image-insert): Replaces widget-glyph-insert. (widget-convert): Use keywordp. (widget-leave-text, widget-children-value-delete): Use mapc. (widget-keymap): Remove XEmacs stuff. (widget-field-keymap, widget-text-keymap): Define all inside defvar. (widget-button-click): Don't set point at the click, but re-centre if we scroll out of window. Rewritten for images v. glyphs &c. (widget-tabable-at): Use POS arg, not point. (widget-beginning-of-line, widget-end-of-line) (widget-item-value-create, widget-sublist, widget-princ-to-string) (widget-sexp-prompt-value, widget-echo-help): Simplify. (widget-default-create): Use widget-image-insert; some rewriting. (widget-visibility-value-create) (widget-push-button-value-create, widget-toggle-value-create): Use widget-image-insert. (checkbox): Create on and off images dynamically. (documentation-link): Change :help-echo. (widget-documentation-link-echo-help): Remove.

;;; emacs-lock.el --- prevents you from exiting emacs if a buffer is locked

;; Copyright (C) 1994, 1997 Free Software Foundation, Inc

;; Author: Tom Wurgler <[e-mail]>
;; Created: 12/8/94
;; Keywords: extensions, processes

;; This file is part of GNU Emacs.

;; GNU Emacs is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation; either version 2, or (at your option)
;; any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs; see the file COPYING.  If not, write to the
;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
;; Boston, MA 02111-1307, USA.

;;; Commentary:

;; This code sets a buffer-local variable to t if toggle-emacs-lock is run,
;; then if the user attempts to exit emacs, the locked buffer name will be
;; displayed and the exit aborted.  This is just a way of protecting
;; yourself from yourself.  For example, if you have a shell running a big
;; program and exiting emacs would abort that program, you may want to lock
;; that buffer, then if you forget about it after a while, you won't
;; accidentally exit emacs.  To unlock the buffer, just goto the buffer and
;; run toggle-emacs-lock again.

;;; Code:

(defvar emacs-lock-from-exiting nil
  "Whether emacs is locked to prevent exiting.  See `check-emacs-lock'.")
(make-variable-buffer-local 'emacs-lock-from-exiting)

(defvar emacs-lock-buffer-locked nil
  "Whether a shell or telnet buffer was locked when its process was killed.")
(make-variable-buffer-local 'emacs-lock-buffer-locked)
(put 'emacs-lock-buffer-locked 'permanent-local t)

(defun check-emacs-lock ()
  "Check if variable `emacs-lock-from-exiting' is t for any buffer.
If any t is found, signal error and display the locked buffer name."
  (let ((buffers (buffer-list)))
    (save-excursion
      (while buffers
	(set-buffer (car buffers))
	(if emacs-lock-from-exiting
	    (error "Emacs is locked from exit due to buffer: %s" (buffer-name))
	  (setq buffers (cdr buffers)))))))

(defun toggle-emacs-lock ()
  "Toggle `emacs-lock-from-exiting' between t and nil for the current buffer.
See `check-emacs-lock'."
  (interactive)
  (if emacs-lock-from-exiting
      (setq emacs-lock-from-exiting nil)
    (setq emacs-lock-from-exiting t))
  (if emacs-lock-from-exiting
      (message "Buffer is now locked")
    (message "Buffer is now unlocked")))

(defun emacs-lock-check-buffer-lock ()
  "Check if variable `emacs-lock-from-exiting' is t for a buffer.
If t is found, signal error and display the locked buffer name."
  (if emacs-lock-from-exiting
      (error "Buffer `%s' is locked, can't delete it" (buffer-name))))

; These next defuns make it so if you exit a shell that is locked,  the lock
; is shut off for that shell so you can exit emacs.  Same for telnet.
; Also, if a shell or a telnet buffer was locked and the process killed,
; turn the lock back on again if the process is restarted.

(defun emacs-lock-shell-sentinel ()
  (set-process-sentinel
   (get-buffer-process (buffer-name)) (function emacs-lock-clear-sentinel)))

(defun emacs-lock-clear-sentinel (proc str)
  (if emacs-lock-from-exiting
      (progn
	(setq emacs-lock-from-exiting nil)
	(setq emacs-lock-buffer-locked t)
	(message "Buffer is now unlocked"))
    (setq emacs-lock-buffer-locked nil)))

(defun emacs-lock-was-buffer-locked ()
  (if emacs-lock-buffer-locked
      (setq emacs-lock-from-exiting t)))

(add-hook 'kill-emacs-hook 'check-emacs-lock)
(add-hook 'kill-buffer-hook 'emacs-lock-check-buffer-lock)
(add-hook 'shell-mode-hook 'emacs-lock-was-buffer-locked)
(add-hook 'shell-mode-hook 'emacs-lock-shell-sentinel)
(add-hook 'telnet-mode-hook 'emacs-lock-was-buffer-locked)
(add-hook 'telnet-mode-hook 'emacs-lock-shell-sentinel)

(provide 'emacs-lock)

;;; emacs-lock.el ends here