view lisp/makesum.el @ 87348:3d42d5ccb130

(nxml-faces): Rename from nxml-highlighting-faces. Parent group is font-lock-faces. (nxml-light-blue-color, nxml-dark-blue-color, nxml-green-color) (nxml-sky-blue-color, nxml-dark-green-color, nxml-light-green-color): (nxml-version): Remove. (nxml-delimited-data, nxml-name, nxml-ref, nxml-delimiter) (nxml-text, nxml-comment-content, nxml-comment-delimiter) (nxml-processing-instruction-delimiter) (nxml-processing-instruction-target) (nxml-processing-instruction-content, nxml-cdata-section-delimiter) (nxml-cdata-section-CDATA, nxml-cdata-section-content) (nxml-char-ref-number, nxml-char-ref-delimiter, nxml-entity-ref-name) (nxml-entity-ref-delimiter, nxml-tag-delimiter, nxml-tag-slash) (nxml-element-prefix, nxml-element-colon, nxml-element-local-name) (nxml-attribute-prefix, nxml-attribute-colon) (nxml-attribute-local-name, nxml-namespace-attribute-xmlns) (nxml-namespace-attribute-colon, nxml-namespace-attribute-prefix) (nxml-attribute-value, nxml-attribute-value-delimiter) (nxml-namespace-attibute-value) (nxml-namespace-attribure-value-delimiter) (nxml-prolog-literal-delimiter, nxml-prolog-literal-content) (nxml-prolog-keyword, nxml-markup-declaration-delimiter, nxml-hash) (nxml-glyph): Rename, removing -face suffix. Inherit from existing font-lock faces. (nxml-apply-fontify-rule, nxml-char-ref-display-extra): Use new face names.

;;; makesum.el --- generate key binding summary for Emacs

;; Copyright (C) 1985, 2001, 2002, 2003, 2004, 2005,
;;   2006, 2007 Free Software Foundation, Inc.

;; Maintainer: FSF
;; Keywords: help

;; This file is part of GNU Emacs.

;; GNU Emacs is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation; either version 3, or (at your option)
;; any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs; see the file COPYING.  If not, write to the
;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
;; Boston, MA 02110-1301, USA.

;;; Commentary:

;; Displays a nice human-readable summary of all keybindings in a
;; two-column format.

;;; Code:

;;;###autoload
(defun make-command-summary ()
  "Make a summary of current key bindings in the buffer *Summary*.
Previous contents of that buffer are killed first."
  (interactive)
  (message "Making command summary...")
  ;; This puts a description of bindings in a buffer called *Help*.
  (save-window-excursion
   (describe-bindings))
  (with-output-to-temp-buffer "*Summary*"
    (save-excursion
     (let ((cur-mode mode-name))
       (set-buffer standard-output)
       (erase-buffer)
       (insert-buffer-substring "*Help*")
       (goto-char (point-min))
       (delete-region (point) (progn (forward-line 1) (point)))
       (while (search-forward "         " nil t)
	 (replace-match "  "))
       (goto-char (point-min))
       (while (search-forward "-@ " nil t)
	 (replace-match "-SP"))
       (goto-char (point-min))
       (while (search-forward "  .. ~ " nil t)
	 (replace-match "SP .. ~"))
       (goto-char (point-min))
       (while (search-forward "C-?" nil t)
	 (replace-match "DEL"))
       (goto-char (point-min))
       (while (search-forward "C-i" nil t)
	 (replace-match "TAB"))
       (goto-char (point-min))
       (if (re-search-forward "^Local Bindings:" nil t)
	   (progn
	    (forward-char -1)
	    (insert " for " cur-mode " Mode")
	    (while (search-forward "??\n" nil t)
	      (delete-region (point)
			     (progn
			      (forward-line -1)
			      (point))))))
       (goto-char (point-min))
       (insert "Emacs command summary, " (substring (current-time-string) 0 10)
	       ".\n")
       ;; Delete "key    binding" and underlining of dashes.
       (delete-region (point) (progn (forward-line 2) (point)))
       (forward-line 1)			;Skip blank line
       (while (not (eobp))
	 (let ((beg (point)))
	   (or (re-search-forward "^$" nil t)
	       (goto-char (point-max)))
	   (double-column beg (point))
	   (forward-line 1)))
       (goto-char (point-min)))))
  (message "Making command summary...done"))

(defun double-column (start end)
  (interactive "r")
  (let (half cnt
        line lines nlines
	(from-end (- (point-max) end)))
    (setq nlines (count-lines start end))
    (if (<= nlines 1)
	nil
      (setq half (/ (1+ nlines) 2))
      (goto-char start)
      (save-excursion
       (forward-line half)
       (while (< half nlines)
	 (setq half (1+ half))
	 (setq line (buffer-substring (point) (save-excursion (end-of-line) (point))))
	 (setq lines (cons line lines))
	 (delete-region (point) (progn (forward-line 1) (point)))))
      (setq lines (nreverse lines))
      (while lines
	(end-of-line)
	(indent-to 41)
	(insert (car lines))
	(forward-line 1)
	(setq lines (cdr lines))))
    (goto-char (- (point-max) from-end))))

(provide 'makesum)

;;; arch-tag: c2383336-fc89-46ad-8110-ded42bffaee3
;;; makesum.el ends here