Mercurial > emacs

view msdos/sed1.inp @ 8261:3eab4db14a5d

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
(add-change-log-entry): Use <...> around mail address.
author Richard M. Stallman <rms@gnu.org>
date Sat, 16 Jul 1994 19:30:21 +0000
parents d6a441681fb4
children b36d5e88cccc
line wrap: on
line source

# -sed1.inp-------------------------------------------------------------
# Configuration script for src/makefile
# ----------------------------------------------------------------------
s/^#.*//
s/^[ \f\t][ \f\t]*$//
s/^ /	/
/^obj=/s!$! dosfns.o msdos.o!
s/\.h\.in/.h-in/
s!^	\./temacs!	go32 temacs!
s!/bin/sh!command.com!
/^MAKE *=/s/^/# /
/^SHELL *=/s/^/# /
/^srcdir *=/s/@[^@\n]*@/./
/^VPATH *=/s/@[^@\n]*@/./
/^CC *=/s/@[^@\n]*@/gcc/
/^CPP *=/s/@[^@\n]*@/gcc -e/
/^CFLAGS *=/s/@[^@\n]*@/-O2 -g/
/^LN_S *=/s/@[^@\n]*@/ln -s/
/^M_FILE *=/s!@[^@\n]*@!m/intel386.h!
/^S_FILE *=/s!@[^@\n]*@!s/msdos.h!
/^@SET_MAKE@$/s/@SET_MAKE@//
/^.\${libsrc}make-doc/s!>.*$!!
/^.\${libsrc}make-docfile/s!make-docfile!make-docfile -o ../etc/DOC!
/^.\${libsrc}make-docfile/s/\$/go32 $/
/^[ 	]*$/d