view lisp/gnus/gnus-mh.el @ 64631:4556f884d581

Revision: [e-mail]--gnu-2005/emacs--cvs-trunk--0--patch-495 Merge from gnus--rel--5.10 Patches applied: * gnus--rel--5.10 (patch 95) - Update from CVS 2005-07-25 Katsumi Yamaoka <[e-mail]> * lisp/gnus/gnus-art.el (gnus-article-next-page): Revert. (gnus-article-beginning-of-window): New macro. (gnus-article-next-page-1): Use it. (gnus-article-prev-page): Ditto. (gnus-mime-save-part-and-strip): Use insert-buffer-substring instead of insert-buffer. (gnus-mime-delete-part): Ditto. (gnus-article-edit-exit): Ditto. * lisp/gnus/gnus-util.el (gnus-beginning-of-window): Remove. (gnus-end-of-window): Remove. * lisp/gnus/lpath.el: Don't bind scroll-margin. 2005-07-25 Simon Josefsson <[e-mail]> * lisp/gnus/pgg.el (pgg-insert-url-with-w3): Don't load w3, it is possible to have the url package without w3. Reported by Daiki Ueno <[e-mail]> and Luigi Panzeri <[e-mail]>.

;;; gnus-mh.el --- mh-e interface for Gnus
;; Copyright (C) 1994, 1995, 1996, 1997, 1998, 1999, 2000
;;        Free Software Foundation, Inc.

;; Author: Masanobu UMEDA <[e-mail]>
;;	Lars Magne Ingebrigtsen <[e-mail]>
;; Keywords: news

;; This file is part of GNU Emacs.

;; GNU Emacs is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation; either version 2, or (at your option)
;; any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs; see the file COPYING.  If not, write to the
;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
;; Boston, MA 02110-1301, USA.

;;; Commentary:

;;; Send mail using mh-e.

;; The following mh-e interface is all cooperative works of
;; [e-mail] (TANAKA Hiroshi), [e-mail]
;; (Yoshikatsu Kawabe), and [e-mail] (Toshiaki
;; SHINGU).

;;; Code:

(require 'gnus)
(require 'mh-e)
(require 'mh-comp)
(require 'gnus-msg)
(require 'gnus-sum)

(eval-when-compile
  (defvar mh-lib-progs))

(defun gnus-summary-save-article-folder (&optional arg)
  "Append the current article to an mh folder.
If N is a positive number, save the N next articles.
If N is a negative number, save the N previous articles.
If N is nil and any articles have been marked with the process mark,
save those articles instead."
  (interactive "P")
  (require 'gnus-art)
  (let ((gnus-default-article-saver 'gnus-summary-save-in-folder))
    (gnus-summary-save-article arg)))

(defun gnus-summary-save-in-folder (&optional folder)
  "Save this article to MH folder (using `rcvstore' in MH library).
Optional argument FOLDER specifies folder name."
  ;; Thanks to [e-mail] and [e-mail].
  (mh-find-path)
  (let ((folder
	 (cond ((and (eq folder 'default)
		     gnus-newsgroup-last-folder)
		gnus-newsgroup-last-folder)
	       (folder folder)
	       (t (mh-prompt-for-folder
		   "Save article in"
		   (funcall gnus-folder-save-name gnus-newsgroup-name
			    gnus-current-headers gnus-newsgroup-last-folder)
		   t))))
	(errbuf (gnus-get-buffer-create " *Gnus rcvstore*"))
	;; Find the rcvstore program.
	(exec-path (cond
		    ((and (boundp 'mh-lib-progs) mh-lib-progs)
		     (cons mh-lib-progs exec-path))
		    (mh-lib (cons mh-lib exec-path))
		    (t exec-path))))
    (with-current-buffer gnus-original-article-buffer
      (save-restriction
	(widen)
	(unwind-protect
	    (call-process-region
	     (point-min) (point-max) "rcvstore" nil errbuf nil folder)
	  (set-buffer errbuf)
	  (if (zerop (buffer-size))
	      (message "Article saved in folder: %s" folder)
	    (message "%s" (buffer-string)))
	  (kill-buffer errbuf))))
    (setq gnus-newsgroup-last-folder folder)))

(defun gnus-Folder-save-name (newsgroup headers &optional last-folder)
  "Generate folder name from NEWSGROUP, HEADERS, and optional LAST-FOLDER.
If variable `gnus-use-long-file-name' is nil, it is +News.group.
Otherwise, it is like +news/group."
  (or last-folder
      (concat "+"
	      (if gnus-use-long-file-name
		  (gnus-capitalize-newsgroup newsgroup)
		(gnus-newsgroup-directory-form newsgroup)))))

(defun gnus-folder-save-name (newsgroup headers &optional last-folder)
  "Generate folder name from NEWSGROUP, HEADERS, and optional LAST-FOLDER.
If variable `gnus-use-long-file-name' is nil, it is +news.group.
Otherwise, it is like +news/group."
  (or last-folder
      (concat "+"
	      (if gnus-use-long-file-name
		  newsgroup
		(gnus-newsgroup-directory-form newsgroup)))))

(provide 'gnus-mh)

;;; arch-tag: 2d5696d3-b363-48e5-8749-c256be56acca
;;; gnus-mh.el ends here