view lisp/elide-head.el @ 62929:4929fb0b87a7

(mode_line_noprop_buf, mode_line_noprop_buf_end) (mode_line_noprop_ptr): Rename from frame_title_*. (store_mode_line_noprop_char): Rename from store_frame_title_char. (store_mode_line_noprop): Rename from store_frame_title. (mode_line_target): New enum to specify current output target for mode line formatting. (display_mode_element): Test it rather than frame_title_ptr and mode_line_string_list to determine where output should go. (mode_line_proptrans_alist, mode_line_string_alist): Make static. (Vmode_line_unwind_vector): New variable. (format_mode_line_unwind_data, unwind_format_mode_line): New functions for unwind protection in mode line formatting. (x_consider_frame_title): Use them and new local var 'title_start' to support nested calls to format-mode-line. Set mode_line_target to MODE_LINE_TITLE. (Fformat_mode_line): Use them and new local var 'string_start' to support nested calls to format-mode-line. Set mode_line_target to MODE_LINE_NOPROP or MODE_LINE_STRING. Don't trim trailing dashes. (decode_mode_spec): Don't make infinite number of trailing dashes for MODE_LINE_NOPROP and MODE_LINE_STRING targets. (syms_of_xdisp): Initialize and staticpro mode_line_string_face, mode_line_string_face_prop, and Vmode_line_unwind_vector. (init_xdisp): Initialize mode_line_noprop_ptr to start of _buf. Initialize mode_line_target to MODE_LINE_DISPLAY.

;;; elide-head.el --- hide headers in files

;; Copyright (C) 1999 Free Software Foundation, Inc.

;; Author: Dave Love <[e-mail]>
;; Keywords: outlines tools

;; This file is part of GNU Emacs.

;; GNU Emacs is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation; either version 2, or (at your option)
;; any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs; see the file COPYING.  If not, write to the
;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
;; Boston, MA 02111-1307, USA.

;;; Commentary:

;; Functionality for eliding boilerplate text (normally copyright
;; notices) in file headers to avoid clutter when you know what it
;; says.
;;
;; `elide-head-headers-to-hide' controls what is elided by the command
;; `elide-head'.  A buffer-local invisible overlay manages the
;; elision.

;; You might add `elide-head' to appropriate major mode hooks or to
;; `find-file-hook'.  Please do not do this in site init files.  If
;; you do, information may be hidden from users who don't know it
;; already.

;; Note that `hs-minor-mode' will do a similar job by default, but
;; it's not selective about what leading commentary it hides.

;; Inspired by jwz's hide-copyleft.el, for which we don't have an
;; assignment.

;;; Code:

(defgroup elide-head nil
  "Eliding copyright headers and the like in source files."
  :version "21.1"
  :prefix "elide-head"
  :group 'tools)

(defcustom elide-head-headers-to-hide
  '(("is free software; you can redistribute it" . ; GNU boilerplate
     "Boston, MA 02111-1307, USA\\.")
    ("The Regents of the University of California\\.  All rights reserved\\." .
     "SUCH DAMAGE\\.")			; BSD
    ("Permission is hereby granted, free of charge" . ; X11
     "authorization from the X Consortium\\."))
  "Alist of regexps defining start end end of text to elide.

The cars of elements of the list are searched for in order.  Text is
elided with an invisible overlay from the end of the line where the
first match is found to the end of the match for the corresponding
cdr."
  :group 'elide-head
  :type '(alist :key-type  (string :tag "Start regexp")
		:value-type (string :tag "End regexp")))

(defvar elide-head-overlay nil)
(make-variable-buffer-local 'elide-head-overlay)

;;;###autoload
(defun elide-head (&optional arg)
  "Hide header material in buffer according to `elide-head-headers-to-hide'.

The header is made invisible with an overlay.  With a prefix arg, show
an elided material again.

This is suitable as an entry on `find-file-hook' or appropriate mode hooks."
  (interactive "P")
  (if arg
      (elide-head-show)
    (save-excursion
      (save-restriction
	(let ((rest elide-head-headers-to-hide)
	      beg end)
	  (widen)
	  (goto-char (point-min))
	  (while rest
	    (save-excursion
	      (when (re-search-forward (caar rest) nil t)
		(setq beg (point))
		(when (re-search-forward (cdar rest) nil t)
		  (setq end (point-marker)
			rest nil))))
	    (if rest (setq rest (cdr rest))))
	  (if (not (and beg end))
	      (if (interactive-p)
		  (message "No header found"))
	    (goto-char beg)
	    (end-of-line)
	    (if (overlayp elide-head-overlay)
		(move-overlay elide-head-overlay (point-marker) end)
	      (setq elide-head-overlay (make-overlay (point-marker) end)))
	    (overlay-put elide-head-overlay 'invisible t)
	    (overlay-put elide-head-overlay 'evaporate t)
	    (overlay-put elide-head-overlay 'after-string "...")))))))

(defun elide-head-show ()
  "Show a header elided current buffer by \\[elide-head]."
  (interactive)
  (if (and (overlayp elide-head-overlay)
	   (overlay-buffer elide-head-overlay))
      (delete-overlay elide-head-overlay)
    (if (interactive-p)
	(message "No header hidden"))))

(provide 'elide-head)

;;; arch-tag: a00e6b5b-6aeb-45b1-b734-63e23df80928
;;; elide-head.el ends here