view lisp/emacs-lisp/tq.el @ 67342:5790642c4a89

(org-occur-highlights): New variable. (org-highlight-new-match, org-remove-occur-highlights): New functions. (org-highlight-sparse-tree-matches): New option. (org-do-occur): New function. (org-get-heading): Make it work also at beginning of line. (org-category-table): New variable. (org-get-category-table, org-get-category) (org-camel-to-words, org-link-search): New functions. (org-select-this-todo-keyword): New variable. (org-todo-list): New command. (org-shiftright, org-shiftleft): New commands. (org-agenda-todo): Added prefix argument. (org-show-hierarchy-above): New option. (org-show-todo-tree): Numerical prefix creates tree for specific TODO keyword. (org-outline-level): New function, to assign a level to plain lists items. (org-cycle-include-plain-lists): New option. (org-mode): Use `org-outline-level' as value of `outline-level'. (org-cycle): Temporarily switch `outline-regexp' if `org-cycle-include-plain-lists' is non-nil. (org-start-icalendar-file): Fixed format bug. (org-agenda-get-day-entries): Create category table. (org-agenda-get-todos, org-agenda-get-timestamps) (org-agenda-get-deadlines, org-agenda-get-scheduled) (org-agenda-get-blocks): Use `org-get-category'. (org-context-in-file-links): Renamed from `org-line-numbers-in-file-links' .

;;; tq.el --- utility to maintain a transaction queue

;; Copyright (C) 1985, 1986, 1987, 1992, 2002, 2003, 2004,
;;   2005 Free Software Foundation, Inc.

;; Author: Scott Draves <[e-mail]>
;; Maintainer: FSF
;; Adapted-By: ESR
;; Keywords: extensions

;; This file is part of GNU Emacs.

;; GNU Emacs is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation; either version 2, or (at your option)
;; any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs; see the file COPYING.  If not, write to the
;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
;; Boston, MA 02110-1301, USA.

;;; Commentary:

;; manages receiving a stream asynchronously,
;; parsing it into transactions, and then calling
;; handler functions

;; Our basic structure is the queue/process/buffer triple.  Each entry
;; of the queue is a regexp/closure/function triple.  We buffer
;; bytes from the process until we see the regexp at the head of the
;; queue.  Then we call the function with the closure and the
;; collected bytes.

;;; Code:

;;;###autoload
(defun tq-create (process)
  "Create and return a transaction queue communicating with PROCESS.
PROCESS should be a subprocess capable of sending and receiving
streams of bytes.  It may be a local process, or it may be connected
to a tcp server on another machine."
  (let ((tq (cons nil (cons process
			    (generate-new-buffer
			     (concat " tq-temp-"
				     (process-name process)))))))
    (set-process-filter process
			`(lambda (proc string)
			   (tq-filter ',tq string)))
    tq))

;;; accessors
(defun tq-queue   (tq) (car tq))
(defun tq-process (tq) (car (cdr tq)))
(defun tq-buffer  (tq) (cdr (cdr tq)))

(defun tq-queue-add (tq re closure fn)
  (setcar tq (nconc (tq-queue tq)
		    (cons (cons re (cons closure fn)) nil)))
  'ok)

(defun tq-queue-head-regexp  (tq) (car (car (tq-queue tq))))
(defun tq-queue-head-fn      (tq) (cdr (cdr (car (tq-queue tq)))))
(defun tq-queue-head-closure (tq) (car (cdr (car (tq-queue tq)))))
(defun tq-queue-empty        (tq) (not (tq-queue tq)))
(defun tq-queue-pop          (tq) (setcar tq (cdr (car tq))) (null (car tq)))


;;; must add to queue before sending!
(defun tq-enqueue (tq question regexp closure fn)
  "Add a transaction to transaction queue TQ.
This sends the string QUESTION to the process that TQ communicates with.
When the corresponding answer comes back, we call FN
with two arguments: CLOSURE, and the answer to the question.
REGEXP is a regular expression to match the entire answer;
that's how we tell where the answer ends."
  (tq-queue-add tq regexp closure fn)
  (process-send-string (tq-process tq) question))

(defun tq-close (tq)
  "Shut down transaction queue TQ, terminating the process."
  (delete-process (tq-process tq))
  (kill-buffer (tq-buffer tq)))

(defun tq-filter (tq string)
  "Append STRING to the TQ's buffer; then process the new data."
  (with-current-buffer (tq-buffer tq)
    (goto-char (point-max))
    (insert string)
    (tq-process-buffer tq)))

(defun tq-process-buffer (tq)
  "Check TQ's buffer for the regexp at the head of the queue."
  (set-buffer (tq-buffer tq))
  (if (= 0 (buffer-size)) ()
    (if (tq-queue-empty tq)
	(let ((buf (generate-new-buffer "*spurious*")))
	  (copy-to-buffer buf (point-min) (point-max))
	  (delete-region (point-min) (point))
	  (pop-to-buffer buf nil)
	  (error "Spurious communication from process %s, see buffer %s"
		 (process-name (tq-process tq))
		 (buffer-name buf)))
      (goto-char (point-min))
      (if (re-search-forward (tq-queue-head-regexp tq) nil t)
	  (let ((answer (buffer-substring (point-min) (point))))
	    (delete-region (point-min) (point))
	    (unwind-protect
		(condition-case nil
		    (funcall (tq-queue-head-fn tq)
			     (tq-queue-head-closure tq)
			     answer)
		  (error nil))
	      (tq-queue-pop tq))
	    (tq-process-buffer tq))))))

(provide 'tq)

;;; arch-tag: 65dea08c-4edd-4cde-83a5-e8a15b993b79
;;; tq.el ends here