view lisp/gnus/nngateway.el @ 82992:5de4189e659d

Got rid of the rif (window-based redisplay interface) global variable. src/dispextern.h (PRODUCE_GLYPHS): Use the rif in IT->f, not the global rif. (rif): Removed. src/dispnew.c (rif): Removed. (direct_output_for_insert, direct_output_forward_char, update_frame) (redraw_overlapped_rows, redraw_overlapping_rows, update_window) (update_marginal_area, update_text_area, update_window_line) (set_window_cursor_after_update, scrolling_window): Use the rif of the current frame, not the global rif. src/fontset.c: #include termhooks.h, for FRAME_RIF. (Finternal_char_font): Use the rif of the current frame. src/frame.c (x_set_frame_parameters): Use the rif of the current frame. src/keyboard.c (detect_input_pending_run_timers): Use the rif of the current frame. src/minibuf.c: #include termhooks.h, for FRAME_RIF. (read_minibuf): Use the rif of the current frame. src/term.c (update_begin): Removed rif update hack. src/termhooks.h (FRAME_RIF): New macro. src/xdisp.c (init_iterator, expose_frame): Removed rif update hack. (echo_area_display, x_cursor_to, draw_fringe_bitmap) (try_window_reusing_current_matrix, try_window_id) (get_glyph_face_and_encoding, x_get_glyph_overhangs) (get_char_face_and_encoding, compute_overhangs_and_x, draw_glyphs) (x_produce_glyphs, x_insert_glyphs, x_clear_end_of_line) (erase_phys_cursor, display_and_set_cursor, show_mouse_face) (define_frame_cursor1, x_draw_vertical_border): Use the rif of the current frame. src/xfns.c (Fx_create_frame): Removed rif update hack. src/xterm.c (frame_highlight, frame_unhighlight): Ditto. git-archimport-id: [e-mail]--2004/emacs--multi-tty--0--patch-32

;;; nngateway.el --- posting news via mail gateways

;; Copyright (C) 1996, 1997, 1998, 1999, 2000
;;	Free Software Foundation, Inc.

;; Author: Lars Magne Ingebrigtsen <[e-mail]>
;; Keywords: news, mail

;; This file is part of GNU Emacs.

;; GNU Emacs is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation; either version 2, or (at your option)
;; any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs; see the file COPYING.  If not, write to the
;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
;; Boston, MA 02111-1307, USA.

;;; Commentary:

;;; Code:

(eval-when-compile (require 'cl))
(require 'nnoo)
(require 'message)

(nnoo-declare nngateway)

(defvoo nngateway-address nil
  "Address of the mail-to-news gateway.")

(defvoo nngateway-header-transformation 'nngateway-simple-header-transformation
  "Function to be called to rewrite the news headers into mail headers.
It is called narrowed to the headers to be transformed with one
parameter -- the gateway address.")

;;; Interface functions

(nnoo-define-basics nngateway)

(deffoo nngateway-open-server (server &optional defs)
  (if (nngateway-server-opened server)
      t
    (unless (assq 'nngateway-address defs)
      (setq defs (append defs (list (list 'nngateway-address server)))))
    (nnoo-change-server 'nngateway server defs)))

(deffoo nngateway-request-post (&optional server)
  (when (or (nngateway-server-opened server)
	    (nngateway-open-server server))
    ;; Rewrite the header.
    (let ((buf (current-buffer)))
      (with-temp-buffer
	(insert-buffer-substring buf)
	(message-narrow-to-head)
	(funcall nngateway-header-transformation nngateway-address)
	(goto-char (point-max))
	(insert mail-header-separator "\n")
	(widen)
	(let (message-required-mail-headers)
	  (funcall message-send-mail-function))
	t))))

;;; Internal functions

(defun nngateway-simple-header-transformation (gateway)
  "Transform the headers to use GATEWAY."
  (let ((newsgroups (mail-fetch-field "newsgroups")))
    (message-remove-header "to")
    (message-remove-header "cc")
    (goto-char (point-min))
    (insert "To: " (nnheader-replace-chars-in-string newsgroups ?. ?-)
	    "@" gateway "\n")))

(defun nngateway-mail2news-header-transformation (gateway)
  "Transform the headers for sending to a mail2news gateway."
  (message-remove-header "to")
  (message-remove-header "cc")
  (goto-char (point-min))
  (insert "To: " gateway "\n"))

(nnoo-define-skeleton nngateway)

(provide 'nngateway)

;;; arch-tag: f7ecb92e-b10c-43d5-9a9b-1314233341fc
;;; nngateway.el ends here