view msdos/sed1v2.inp @ 103444:61b1b668390e

(Top): Mention which Emacs version this FAQ is about. Recommend the latest release. Mention how to get older FAQs. Recommend the Emacs manual. (Guidelines for newsgroup postings): Discourage cross-posts. (Underlining paragraphs): Remove. (Editing MS-DOS files): Remove pre-Emacs 20 information. (Bugs and problems): Update key-binding. (Problems with very large files): Mention 64-bit. (Shell process exits abnormally): Remove. (Problems with Shell Mode): Rename and update. (Spontaneous entry into isearch-mode) (Problems talking to certain hosts): Remove. This is old information, in etc/PROBLEMS if needed. (Emacs takes a long time to visit files, Updating Emacs): Remove. (Dired claims that no file is on this line): Update. (Installing Emacs, Problems building Emacs): Simplify. (Emacs for MS-DOS): Refer to msdos/INSTALL rather than duplicating information. (Emacs for MS-Windows): Rename from "Emacs for Windows". Simplify. (Emacs for Mac OS X): Rename from "Emacs for Apple computers". (JDEE): "JDEE", not "JDE". (Handling C-s and C-q with flow control, Binding C-s and C-q): Remove. This is old information, in etc/PROBLEMS if needed. (stty and Backspace key, Kanji and Chinese characters): Remove. (Right-to-left alphabets): Update section. (Changing the included text prefix): Gnus uses message-yank-prefix. Add cross-reference to Supercite manual. (Saving a copy of outgoing mail): Simplify output file description. (Expanding aliases when sending mail): Refer to Emacs manual. Remove old info about RFC822. Correct description of how to rebuild aliases. (Rmail writes to /var/spool/mail): Update location from /usr/spool/mail. (MIME with Emacs mail packages) (Viewing articles with embedded underlining) (Saving a multi-part Gnus posting, Gnus hangs for a long time): Remove old sections. (Killing based on nonstandard headers): Remove. Scoring is preferable, and is well-documented in the Gnus manual. (Reading news with Emacs): Merge "Learning more about Gnus" into here. (Making Gnus faster): Rename from "Starting Gnus faster". Merge "Catch-up is slow in Gnus" into here.

# -sed1v2.inp-----------------------------------------------------------
# Configuration script for src/Makefile under DJGPP v2.x
# ----------------------------------------------------------------------
#
# Copyright (C) 1996, 1997, 1999, 2000, 2001, 2002, 2003, 2004,
#   2005, 2006, 2007, 2008, 2009  Free Software Foundation, Inc.
#
# This file is part of GNU Emacs.
#
# This file is free software; as a special exception, the author gives
# unlimited permission to copy and/or distribute it, with or without
# modifications, as long as this notice is preserved.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
#
# ----------------------------------------------------------------------
s/^#.*//
s/^[ \f\t][ \f\t]*$//
s/^ /	/
s/\.h\.in/.h-in/
/^	LC_ALL=C \$(RUN_TEMACS)/i\
	stubedit temacs.exe minstack=1024k
/^	LC_ALL=C.*\$(RUN_TEMACS)/s/LC_ALL=C/set &;/
/-batch -l loadup/a\
	stubify emacs\
	stubedit emacs.exe minstack=2048k
/^MAKE *=/s/^/# /
/^SHELL *=/s/^/# /
/^srcdir *=/s/@[^@\n]*@/./
/^VPATH *=/s/@[^@\n]*@/./
/^CC *=/s/@[^@\n]*@/gcc/
/^CPP *=/s/@[^@\n]*@/gcc -e/
/^CFLAGS *=/s/@[^@\n]*@/-O2 -gcoff/
/^ALL_CFLAGS *=/s/@[^@\n]*@//g
/^CPPFLAGS *=/s/@[^@\n]*@//
/^LDFLAGS *=/s/@[^@\n]*@//
/^LIBS *=/s/@[^@\n]*@//
/^LIBES *=/,/^ *$/ {
  s/@[^@\n]*@//g
}
/^LIBOBJS *=/s/@[^@\n]*@/getloadavg.o/
/^GETLOADAVG_LIBS *=/s/@[^@\n]*@//
/^LIBSOUND *=/s/@LIBSOUND@//
/^CFLAGS_SOUND *=/s/@CFLAGS_SOUND@//
/^RSVG_LIBS *=/s/@RSVG_LIBS@//
/^RSVG_CFLAGS *=/s/@RSVG_CFLAGS@//
/^EXEEXT *=/s/@EXEEXT@/.exe/
/^version *=/s/@[^@\n]*@//
/^LN_S *=/s/@[^@\n]*@/ln -s/
/^M_FILE *=/s!@[^@\n]*@!m/intel386.h!
/^S_FILE *=/s!@[^@\n]*@!s/msdos.h!
/^@SET_MAKE@$/s/@SET_MAKE@//
/^.\${libsrc}make-docfile.*>/s!make-docfile!make-docfile -o ../etc/DOC!
/^.\${libsrc}make-doc/s!>.*$!!
/^[ 	]*$/d
/^temacs:/s/prefix-args//
/^temacs:/s/stamp-oldxmenu//
/^RUN_TEMACS *=/s|`/bin/pwd`|.|
/^	mv \.\/\.gdbinit/d
/^	if test -f/c\
	command.com /c if exist .gdbinit rm -f _gdbinit
/^	else mv \.\/\.gdbinit/d
/^	#/d
/^	cd.*make-docfile/s!$!; cd ${dot}${dot}/src!
/^	@: /d
/^	-\{0,1\}ln -/s/ln -f/cp -pf/
/^[ 	]touch /s/touch/djecho $@ >/
s/bootstrap-emacs/b-emacs/
s/bootstrap-temacs/b-temacs/
s/bootstrap-doc/b-doc/
/rm -f bootstrap-emacs/s/b-emacs/b-emacs b-emacs.exe/
s/echo.*buildobj.lst/dj&/
/ --load loadup bootstrap/i\
	stubedit temacs.exe minstack=1024k
/ --load loadup bootstrap/a\
	stubify emacs
/^	mv -f emacs/a\
	stubedit b-emacs.exe minstack=3072k\
	djecho bootlisp > bootlisp
/^	-\{0,1\}rm -f/s/\\#/#/
/^	@\{0,1\}cd ..\/lisp; /s|$|\; cd ../src|

# arch-tag: c7e3aacb-4162-460e-99f9-4252bca68d2c