view lisp/unused.el @ 30057:6413c7b9a6c3

(easy-menu-define): Docstring fix. (easy-menu-do-define): Use `menu-item' format. Handle case where easy-menu-create-menu returns a symbol. Manually call the potential top-level filter in the function binding. (easy-menu-filter-return): New arg NAME. Convert to a keymap if MENU is an XEmacs menu. (easy-menu-convert-item-1): New. Extracted from easy-menu-do-add-item. (easy-menu-converted-items-table, easy-menu-convert-item): New. (easy-menu-do-add-item): Use it. (easy-menu-create-menu): Use easy-menu-convert-item. Wrap easy-menu-filter-return around any :filter specification. Don't convert the menu if a filter was specified. Tell easy-menu-make-symbol not to check for MENU being an expression. (easy-menu-make-symbol): New arg NOEXP.

;;; unused.el --- editing commands in GNU Emacs that turned out not to be used.
;;; This file is in the public domain, as it was distributed in
;;; 1985 or 1986 without a copyright notice.  Written by RMS.

;; Maintainer: FSF
;; Keywords: emulations

;;; Commentary:

;; These were added with an eye to making possible a more CCA-compatible
;; command set; but that turned out not to be interesting.

;;; Code:

(defun mark-beginning-of-buffer ()
  "Set mark at the beginning of the buffer."
  (interactive)
  (push-mark (point-min)))

(defun mark-end-of-buffer ()
  "Set mark at the end of the buffer."
  (interactive)
  (push-mark (point-max)))

(defun upcase-char (arg)
  "Uppercasify ARG chars starting from point.  Point doesn't move"
  (interactive "p")
  (save-excursion
    (upcase-region (point) (progn (forward-char arg) (point)))))

(defun forward-to-word (arg)
  "Move forward until encountering the beginning of a word.
With argument, do this that many times."
  (interactive "p")
  (or (re-search-forward (if (> arg 0) "\\W\\b" "\\b\\W") nil t arg)
      (goto-char (if (> arg 0) (point-max) (point-min)))))

(defun backward-to-word (arg)
  "Move backward until encountering the end of a word.
With argument, do this that many times."
  (interactive "p")
  (forward-to-word (- arg)))

;;; unused.el ends here