view lib-src/=aixcc.lex @ 30403:68e734ab7d5d

(c-looking-at-inexpr-block): Replaced a call to c-beginning-of-statement-1 that caused a bad case of recursion which could consume a lot of CPU in large classes in languages that have in-expression classes (i.e. Java and Pike). (c-guess-basic-syntax): Check for in-expression statements before top level constructs (i.e. case 6 is moved before case 5 and is now case 4) to catch in-expression classes in top level expressions correctly. (c-guess-basic-syntax): Less naive handling of objc-method-intro. Case 4 removed and case 5I added. (c-beginning-of-inheritance-list, c-guess-basic-syntax): Fixed recognition of inheritance lists when the lines begins with a comma. (c-forward-syntactic-ws): Fixed an infloop bug when the buffer ends with a macro continuation char. (c-guess-basic-syntax): Added support for function definitions as statements in Pike. The first statement in a lambda block is now labeled defun-block-intro instead of statement-block-intro. (c-narrow-out-enclosing-class): Whack the state so that the class surrounding point is selected, not the one innermost in the state. (c-guess-basic-syntax): Fixed bug in recognition of switch labels having hanging multiline statements. (c-beginning-of-member-init-list): Broke out some code in c-guess-basic-syntax to a separate function. (c-just-after-func-arglist-p): Fixed recognition of member inits with multiple line arglists. (c-guess-basic-syntax): New case 5B.3 to detect member-init-cont when the commas are in funny places. (c-looking-at-bos): New helper function. (c-looking-at-inexpr-block): More tests to tell inexpr and toplevel classes apart in Pike. (c-guess-basic-syntax): Fixed bogus recognition of case 9A. (c-guess-basic-syntax): Made the cpp-macro a syntax modifier like comment-intro, to make it possible to get syntactic indentation for preprocessor directives. It's incompatible wrt to lineup functions on cpp-macro, but it has no observable effect in the 99.9% common case where cpp-macro is set to -1000. (c-guess-basic-syntax): Fixed bug with missed member-init-cont when the preceding arglist is several lines. (c-beginning-of-statement-1): Fixed bug where we were left at comments preceding the first statement when reaching the beginning of the buffer. (c-beginning-of-closest-statement): New helper function to go back to the closest preceding statement start, which could be inside a conditional statement. (c-guess-basic-syntax): Use c-beginning-of-closest-statement in cases 10B.2, 17B and 17C. (c-guess-basic-syntax): Better handling of arglist-intro, arglist-cont-nonempty and arglist-close when the arglist is nested inside parens. Cases 7A, 7C and 7F changed. (c-beginning-of-statement-1): Fixed handling of multiline Pike type decls. (c-guess-basic-syntax): Fixed bug with fully::qualified::names in C++ member init lists. Preamble in case 5D changed.

%Start ErrorText ErrorMessage OtherText

EC	[0-9][0-9][0-9][0-9]-[0-9][0-9][0-9]
D	[0-9]
D3	[0-9 ][0-9 ][0-9]
D4	[0-9 ][0-9 ][0-9 ][0-9]
D5	[0-9 ][0-9 ][0-9 ][0-9 ][0-9]
DS	[0-9 ]

%{
/* [e-mail]

 * Hack to work around the AIX C compiler's brain-damaged error messages
 * so that emacs can parse them.  It runs /bin/cc as a subprocess, and
 * tries to rearrange the error messages so that (a) each message contains
 * both the filename and line number where the error occurred, and (b)
 * the error message(s) for a particular line get displayed *before* the
 * line itself.
 *
 * to compile: 
 * lex aixcc.lex
 * cc -o aixcc lex.yy.c
 *
 *
 * Copyright December 1991 by Keith Moore
 *
 * This program is free software; you can redistribute it and/or modify
 * it under the terms of the GNU General Public License as published by
 * the Free Software Foundation; either version 2 of the License, or
 * (at your option) any later version.
 * 
 * This program is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 * 
 * You should have received a copy of the GNU General Public License
 * along with this program; if not, write to the Free Software
 * Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
 *
 *
 * TODO: figure out how the compiler counts file numbers for included
 * files, keep track of which file corresponds to which number, and
 * always output the right file name.
 */

#include <stdio.h>
#include <string.h>

char *current_file;
int line;
int debug = 0;
char bigbuf[10240];
char *bufptr = bigbuf;
int last_line_was_error = 0;

spaces (s)
char *s;
{
    while (*s++)
	*bufptr++ = ' ';
}

char *
strsave (s)
char *s;
{
    char *ptr = malloc (strlen (s) + 1);
    strcpy (ptr, s);
    return ptr;
}

yywrap ()
{
    *bufptr = '\0';
    bufptr = bigbuf;
    while (*bufptr)
	putc (*bufptr++, yyout);
    return 1;
}

%}
%%
^File\ Line\ Column\ Message\ text[^\n]*	{
   /*
    * ignore this.  don't treat it as error text
    */
}

^{DS}{DS}{DS}\ {D5}\ \|	{
    /*
     * (optional) nesting level, followed by line number, followed
     * by the source code fragment that caused the error
     */

    /*
     * save the line number for later
     */
    line = atoi (yytext+4);

    if (debug) {
	fprintf (yyout, "line <= %d\n", line);
	fprintf (yyout, "%s\n", yytext);
    }

    /*
     * if the last line was an error message, to flush out all of
     * the old source text before starting to save the new source text.
     */
    if (last_line_was_error) {
	*bufptr = '\0';
	bufptr = bigbuf;
	while (*bufptr)
	    putc (*bufptr++, yyout);
	bufptr = bigbuf;
        last_line_was_error = 0;
    }
    /*
     * stuff enough spaces in the text buffer so that the
     * saved text will line up properly when displayed.
     */
    spaces (yytext);

    BEGIN ErrorText;	/* continue below */
}

<ErrorText>[^\n]*$	{
    char *ptr;

    /* 
     * Save the text until we see the error message(s), then print it.
     * This because emacs puts the error message at the top of the
     * window, and it's nice to be able to see the text below it.
     */

    ptr = yytext;
    while (*ptr)
	*bufptr++ = *ptr++;
    *bufptr++ = '\n';

    BEGIN 0;
}

^Processing\ include\ file\ .*$	{
    /*
     * name of a new include file being processed.  Increment file number
     * and remember the file name corresponding to this file number.
     */

    current_file = strsave (yytext+24);
    
    if (debug) {
	fprintf (yyout, "current_file <= %s\n", current_file);
	fprintf (yyout, "%s\n", yytext);
    }
}

^([a-z]\ -)?\ *{EC}:	{
    /* 
     * error message (which we print immediately) preceded by an
     * error code (which we ignore)
     */

    fprintf (yyout, "\"%s\", line %d: %c -", current_file, line, *yytext);
    last_line_was_error = 1;
    BEGIN ErrorMessage;
}

^{D3}\ {D5}\ {D4}\ {EC}:	{
    /*
     * (optional) nesting level, followed by line number, followed
     * by column number, followed by error message text.
     */

    /*
     * save the line number for later
     */
    line = atoi (yytext+4);

    if (debug) {
	fprintf (yyout, "line <= %d\n", line);
	fprintf (yyout, "%s\n", yytext);
    }

    /*
     * if the last line was an error message, flush out all of
     * the old source text before printing this error message.
     */
    if (last_line_was_error) {
	*bufptr = '\0';
	bufptr = bigbuf;
	while (*bufptr)
	    putc (*bufptr++, yyout);
	bufptr = bigbuf;
        last_line_was_error = 0;
    }
    fprintf (yyout, "\"%s\", line %d:", current_file, line);
    last_line_was_error = 1;
    BEGIN ErrorMessage;
}

<ErrorMessage>[^\n]*$	{
    fprintf (yyout, "%s\n", yytext);
    BEGIN 0;
}


^[^ :]+".c:"\ *$	{
    /* name of new source file being processed */

    char *ptr;

    if (current_file)
	free (current_file);
    ptr = strchr (yytext, ':');
    *ptr = '\0';
    current_file = strsave (yytext);
}

^[^\n]	{
    /*
     * other text starting with a newline.  We have to break it up this
     * way to keep this rule from matching any of the above patterns
     */

    if (last_line_was_error) {
	*bufptr = '\0';
	bufptr = bigbuf;
	while (*bufptr)
	    putc (*bufptr++, yyout);
	bufptr = bigbuf;
        last_line_was_error = 0;
    }

    *bufptr++ = *yytext;
    BEGIN OtherText;
}

<OtherText>[^\n]*$	{
    char *ptr;

    ptr = yytext;
    while (*ptr)
	*bufptr++ = *ptr++;
    *bufptr++ = '\n';

    BEGIN 0;
}

\n	;

%%

main (argc, argv)
char **argv;
{
    int pfd[2];
    int child_pid;
    int i;

    current_file = strsave ("/dev/null");

    line = 0;

    for (i = 1; i < argc; ++i) {
	char *ptr = strrchr (argv[i], '.');
	if (ptr && ptr[1] == 'c' && ptr[2] == '\0') {
	    current_file = strsave (argv[i]);
	    break;
	}
    }

    if (pipe (pfd) < 0) {
	perror ("pipe");
	exit (1);
    }
    if ((child_pid = fork()) > 0) {
	int status;

	close (pfd[1]);
	yyin = fdopen (pfd[0], "r");
	yyout = stderr;
	yylex();

	wait (&status);
	exit ((status >> 8) & 0xff);
    }
    else if (child_pid == 0) {
	dup2 (pfd[1], 2);
	close (pfd[0]);
	close (pfd[1]);
	argv[0] = "cc";
	execv ("/bin/cc", argv);
	perror ("/bin/cc");
	exit (1);
    }
    else {
	perror ("fork");
	exit (1);
    }
}