Mercurial > emacs

view msdos/sed1v2.inp @ 15156:69941576c244

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
[BUILD_TYPE]: Build optimized version in its own dir. (ARCH_CFLAGS) [BUILD_TYPE == spd]: Build optimized version.
author Geoff Voelker <voelker@cs.washington.edu>
date Fri, 03 May 1996 19:09:53 +0000
parents 5c431b2e0f95
children 48fd714b8115
line wrap: on
line source

# -sed1v2.inp-----------------------------------------------------------
# Configuration script for src/makefile under DJGPP v2.x
# ----------------------------------------------------------------------
s/^#.*//
s/^[ \f\t][ \f\t]*$//
s/^ /	/
s/\.h\.in/.h-in/
/^	\.\/temacs/i\
	stubedit temacs.exe minstack=40k
/^MAKE *=/s/^/# /
/^SHELL *=/s/^/# /
/^srcdir *=/s/@[^@\n]*@/./
/^VPATH *=/s/@[^@\n]*@/./
/^CC *=/s/@[^@\n]*@/gcc/
/^CPP *=/s/@[^@\n]*@/gcc -e/
/^CFLAGS *=/s/@[^@\n]*@/-O2 -g/
/^LN_S *=/s/@[^@\n]*@/ln -s/
/^M_FILE *=/s!@[^@\n]*@!m/intel386.h!
/^S_FILE *=/s!@[^@\n]*@!s/msdos.h!
/^@SET_MAKE@$/s/@SET_MAKE@//
/^.\${libsrc}make-docfile.*>/s!make-docfile!make-docfile -o ../etc/DOC!
/^.\${libsrc}make-doc/s!>.*$!!
/^[ 	]*$/d
/^temacs:/s/prefix-args//
/^	#/d