view msdos/sed1.inp @ 25048:6d32371bea44

(top-level): Add jit-lock-mode as new support mode. (font-lock-fontify-keywords-region): Stop when reaching end instead of letting re-search-forward signal an error. (jit-lock-mode): New. (font-lock-turn-on-thing-lock): Add jit-lock-mode. (font-lock-turn-off-thing-lock): Ditto. (font-lock-after-fontify-buffer): Ditto. (font-lock-after-unfontify-buffer): Ditto. (font-lock-comment-face): Add spec for color tty. (font-lock-string-face): Ditto. (font-lock-keyword-face): Ditto. (font-lock-builtin-face): Ditto. (font-lock-function-name-face): Ditto. (font-lock-variable-name-face): Ditto. (font-lock-type-face): Ditto. (font-lock-constant-face): Ditto. (font-lock-warning-face): Ditto. (font-lock-comment-face): Use new face attribute names. (font-lock-string-face): Ditto. (font-lock-keyword-face): Ditto. (font-lock-builtin-face): Ditto. (font-lock-function-name-face): Ditto. (font-lock-variable-name-face): Ditto. (font-lock-type-face): Ditto. (font-lock-reference-face): Ditto. (font-lock-warning-face): Ditto.

# -sed1.inp-------------------------------------------------------------
# Configuration script for src/makefile
# ----------------------------------------------------------------------
#
# In case src/Makefile needs to rebuild `make-doc.exe' (might happen under
# Windows 95), make sure it gets built with commands that DOS
# understands (one command per line).
s/^#.*//
s/^[ \f\t][ \f\t]*$//
s/^ /	/
s/\.h\.in/.h-in/
s!^	\./temacs!	go32 temacs!
s!/bin/sh!command.com!
/^MAKE *=/s/^/# /
/^SHELL *=/s/^/# /
/^srcdir *=/s/@[^@\n]*@/./
/^VPATH *=/s/@[^@\n]*@/./
/^CC *=/s/@[^@\n]*@/gcc/
/^CPP *=/s/@[^@\n]*@/gcc -e/
/^CFLAGS *=/s/@[^@\n]*@/-O2 -g/
/^LN_S *=/s/@[^@\n]*@/ln -s/
/^M_FILE *=/s!@[^@\n]*@!m/intel386.h!
/^S_FILE *=/s!@[^@\n]*@!s/msdos.h!
/^@SET_MAKE@$/s/@SET_MAKE@//
/^.\${libsrc}make-docfile.*>/s!make-docfile!make-doc.exe -o ../etc/DOC!
/^.\${libsrc}make-doc/s!>.*$!!
/^\${libsrc}make-docfile:/c\
${libsrc}make-doc.exe:\
	cd ..\
	cd lib-src\
	$(MAKE) ${MFLAGS} make-docfile -W make-docfile.c\
	cd ..\
	cd src
/^	cd \${libsrc}; \${MAKE} \${MFLAGS} make-docfile/d
/\${libsrc}make-docfile/s/-docfile[ 	]/-doc.exe /
/^[ 	]*$/d
/^temacs:/s/prefix-args//
/^temacs:/s/stamp-oldxmenu//
/^	#/d