view msdos/sed6.inp @ 63199:6d9a2cf91f62

Revision: [e-mail]--gnu-2005/emacs--cvs-trunk--0--patch-370 Remove "-face" suffix from woman faces 2005-06-10 Miles Bader <[e-mail]> * lisp/woman.el (woman-italic, woman-bold, woman-unknown) (woman-addition, woman-symbol-face): Remove "-face" suffix from face names. (woman-italic-face, woman-bold-face, woman-unknown-face) (woman-addition-face): New backward-compatibility aliases for renamed faces. (woman-default-faces, woman-monochrome-faces, woman-man-buffer) (woman-decode-region, woman-replace-match) (woman-display-extended-fonts, woman-special-characters) (woman-font-alist, woman-change-fonts, woman2-TH, woman2-SH): Use renamed woman faces.

# -sed6.inp------------------------------------------------------------------
# Configuration script for man/Makefile, lispref/Makefile, and
# lispintro/Makefile under DJGPP v2.x
# ---------------------------------------------------------------------------
#
# Copyright (C) 1997, 2000, 2001
#   Free Software Foundation, Inc.
#
# This file is part of GNU Emacs.
#
# This file is free software; as a special exception, the author gives
# unlimited permission to copy and/or distribute it, with or without
# modifications, as long as this notice is preserved.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
#
# ----------------------------------------------------------------------
/^srcdir *=/s/@[^@\n]*@/./
/^VPATH *=/s/@[^@\n]*@/./
/^ENVADD/c\
ENVADD =\
export TEXINPUTS := $(srcdir)";"$(TEXINPUTS)\
export MAKEINFO := $(MAKEINFO) -I$(srcdir)
/^texinputdir/c\
texinputdir =\
export texinputdir := $(srcdir)";"$(TEXINPUTS)
/^SHELL *=/s/^/# /
/^elisp.dvi:/,/^$/ {
  /^	 *if \[ *\a${permuted_index}/,/^	 *fi *$/c\
	command.com /c 'if not a${permuted_index}==a sh ./permute-index' \
	command.com /c 'if not a${permuted_index}==a mv permuted.fns elisp.fns' \
	command.com /c 'if not a${permuted_index}==a texindex elisp.tp' \
	command.com /c 'if a${permuted_index}==a texindex elisp.??'
}
/^index.texi:/,/^$/ {
  /^	 *if \[ *\a${permuted_index}/,/^	 *fi *$/c\
	command.com /c 'if not a${permuted_index}==a cp -p ./index.perm index.texi' \
	command.com /c 'if a${permuted_index}==a cp -p ./index.unperm index.texi'
}

# arch-tag: defe1001-f35a-47f7-9635-3f5d33ee5e97