view lisp/rot13.el @ 24990:7505930b5456

(struct x_output): Add scroll bar pixel colors, busy_cursor, busy_window. Remove cursor, computed_faces etc. Add white_relief_pixel, black_relief_pixel, white_allocated_p, black_allocated_p, relief_background. (struct x_display_info): Add gray pixmap, scroll_bar_pixel, Xatom_Scrollbar, DONE, PAGE, image cache, resx, rey, smallest_char_width, smallest_font_height. (scroll_bar): Add x_widget_low and x_widget_high. (FRAME_X_IMAGE_CACHE): New. (FRAME_SMALLEST_CHAR_WIDTH): New. (FRAME_SMALLEST_FONT_HEIGHT): New. (struct relief): New. (VERTICAL_SCROLL_BAR_PIXEL_HEIGHT): Removed. (text_cursor_kinds): New. (FRAME_FLAGS_BITMAP_HEIGHT): New. (FRAME_FLAGS_BITMAP_WIDTH): New. (FRAME_X_FLAGS_AREA_COLS): New. (FRAME_MODE_LINE_BORDER_WIDTH): Removed. (FRAME_MODE_LINE_HEIGHT): Removed. (CHAR_TO_PIXEL_WIDTH): Rrwritten. (PIXEL_TO_CHAR_WIDTH): Ditto. (WINDOW_COL_PIXEL_X etc.) Removed.

;;; rot13.el --- display a buffer in rot13.

;; Copyright (C) 1988 Free Software Foundation, Inc.

;; Author: Howard Gayle:
;; Maintainer: FSF

;; This file is part of GNU Emacs.

;; GNU Emacs is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation; either version 2, or (at your option)
;; any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs; see the file COPYING.  If not, write to the
;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
;; Boston, MA 02111-1307, USA.

;;; Commentary:

;; The single entry point, `rot13-other-window', performs a Caesar cipher
;; encrypt/decrypt on the current buffer and displays the result in another 
;; window.  Rot13 encryption is sometimes used on USENET as a read-at-your-
;; own-risk wrapper for material some might consider offensive, such as
;; ethnic humor.
;;
;; Written by Howard Gayle.
;; This hack is mainly to show off the char table stuff.

;;; Code:

(defvar rot13-display-table
  (let ((table (make-display-table))
	(i 0))
    (while (< i 26)
      (aset table (+ i ?a) (vector (+ (% (+ i 13) 26) ?a)))
      (aset table (+ i ?A) (vector (+ (% (+ i 13) 26) ?A)))
      (setq i (1+ i)))
    table)
  "Char table for rot 13 display.")

;;;###autoload
(defun rot13-other-window ()
  "Display current buffer in rot 13 in another window.
To terminate the rot13 display, delete that window."
  (interactive)
  (let ((w (display-buffer (current-buffer) t)))
    (set-window-display-table w rot13-display-table)))

;;;###autoload
(defun toggle-rot13-mode ()
  "Toggle the use of rot 13 encoding for the current window."
  (interactive)
  (if (eq (window-display-table (selected-window)) rot13-display-table)
      (set-window-display-table (selected-window) nil)
    (if (null (window-display-table (selected-window)))
	(set-window-display-table (selected-window) rot13-display-table))))

(provide 'rot13)

;;; rot13.el ends here