view admin/admin.el @ 70866:7d0efe895341

(org-open-at-point): Use renamed variable `org-confirm-shell-link-function'. (org-confirm-shell-link-function): Renamed from `org-confirm-shell-links'. (org-export-directory): New function. (org-export-as-ascii, org-export-as-html, org-export-as-xoxo) (org-export-icalendar): Use `org-export-directory'. (org-indent-item): Keep cursor position. (org-link-file-path-type): New option. (org-export-as-html): Fixed bug with plain lists starting in column 0. (org-export-as-html): Removed deadline formatting, this happens now already in `org-html-handle-time-stamps'. (org-export-html-style): Deadline class removed. (org-insert-labeled-timestamps-at-point): New option. (org-cycle, org-occur, org-scan-tags): Use `org-overview' instead of `hide-sublevels 1', in case the first headline is not level 1. (org-overview, org-content): New fuction. (org-cycle-global-status, org-cycle-subtree-status): Make these variables buffer-local. (org-global-cycle): New command. (org-shifttab): Use `org-global-cycle'. (org-insert-heading, org-insert-item): Go to end of new headline/item after creating it. (org-export-visible): Renames from `org-export-copy-visible'. Now creates a temporary org-file and applies an exporting command to it. (org-table-eval-formula): Support for lisp forms. (org-agenda-todo-ignore-scheduled): New option. (org-agenda-get-todos): Use new option `org-agenda-todo-ignore-scheduled'. (org-export-html-inline-images): New value `maybe'. (org-export-as-html): Inlining of images dependent on link description. (org-archive-subtree): Check for end-of-buffer before trying `kill-line'. (org-agenda-follow-mode): New option. (org-export-with-tags, org-export-with-timestamps): New options. (org-html-handle-time-stamps): New function. (org-keyword-time-regexp): New variable. (org-agenda-get-todos): Use `org-agenda-todo-list-sublevels'. (org-agenda-todo-list-sublevels): New option. (org-html-level-start): When TITLE is nil, just close all levels. (org-parse-key-lines, org-parse-export-options): Functions removed, replaced by `org-infile-export-plist'. (org-combine-plists, org-infile-export-plist) (org-default-export-plist): New functions. (org-export-html-preamble, org-export-html-postamble) (org-export-html-auto-preamble, org-export-html-auto-postamble): New variables. (org-export-publishing-directory): New option. (org-export-as-html, org-export-as-ascii): Use the new property lists for settings. (org-export-copy-visible, org-export-as-xoxo): Respect `org-export-publishing-directory'. (org-link-search, org-store-link, org-file-apps): Support for links to BibTeX database entries.. (org-get-current-options, org-set-regexps-and-options): Implement logging as a startup option. (org-store-link): Make sure context string is never empty (org-insert-link): Use relative path when possible. (org-at-item-checklet-p): New function. (org-shifttab, org-shiftmetaleft, org-shiftmetaright) (org-shiftmetaup, org-shiftmetadown, org-metaleft) (org-metaright, org-metaup, org-metadown, org-shiftup) (org-shiftdown, org-shiftright, org-shiftleft) (org-ctrl-c-ctrl-c, org-cycle, org-return, org-meta-return): Dispatch using `call-interactively'. (org-call-with-arg): New defsubst. (org-tag-alist, org-use-fast-tag-selection): New options. (org-complete): Use `org-tag-alist'. (org-fast-tag-insert, org-fast-tag-selection): New functions. (org-next-item, org-previous-item): New commands. (org-beginning-of-item, org-end-of-item): Added (interactive) to make command. (org-shiftup, org-shiftdown): Accommodate the item-navigation commands.

;;; admin.el --- utilities for Emacs administration

;; Copyright (C) 2001, 2005 Free Software Foundation, Inc.

;; This file is part of GNU Emacs.

;; GNU Emacs is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation; either version 2, or (at your option)
;; any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs; see the file COPYING.  If not, write to the
;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
;; Boston, MA 02110-1301, USA.

;;; Commentary:

;; add-release-logs	Add ``Version X released'' change log entries.
;; set-version		Change Emacs version number in source tree.

;;; Code:

(defun process-lines (program &rest args)
  "Execute PROGRAM with ARGS, returning its output as a list of lines.
Signal an error if the program returns with a non-zero exit status."
  (with-temp-buffer
    (let ((status (apply 'call-process program nil (current-buffer) nil args)))
      (unless (eq status 0)
	(error "%s exited with status %s" program status))
      (goto-char (point-min))
      (let (lines)
	(while (not (eobp))
	  (setq lines (cons (buffer-substring-no-properties
			     (line-beginning-position)
			     (line-end-position))
			    lines))
	  (forward-line 1))
	(nreverse lines)))))

(defun add-release-logs (root version)
  "Add \"Version VERSION released.\" change log entries in ROOT.
Root must be the root of an Emacs source tree."
  (interactive "DEmacs root directory: \nNVersion number: ")
  (setq root (expand-file-name root))
  (unless (file-exists-p (expand-file-name "src/emacs.c" root))
    (error "%s doesn't seem to be the root of an Emacs source tree" root))
  (require 'add-log)
  (let* ((logs (process-lines "find" root "-name" "ChangeLog"))
	 (entry (format "%s  %s  <%s>\n\n\t* Version %s released.\n\n"
			(funcall add-log-time-format)
			(or add-log-full-name (user-full-name))
			(or add-log-mailing-address user-mail-address)
			version)))
    (dolist (log logs)
      (unless (string-match "/gnus/" log)
	(find-file log)
	(goto-char (point-min))
	(insert entry)))))

(defun set-version-in-file (root file version rx)
  (find-file (expand-file-name file root))
  (goto-char (point-min))
  (unless (re-search-forward rx nil t)
    (error "Version not found in %s" file))
  (replace-match (format "%s" version) nil nil nil 1))

(defun set-version (root version)
  "Set Emacs version to VERSION in relevant files under ROOT.
Root must be the root of an Emacs source tree."
  (interactive "DEmacs root directory: \nsVersion number: ")
  (unless (file-exists-p (expand-file-name "src/emacs.c" root))
    (error "%s doesn't seem to be the root of an Emacs source tree" root))
  (set-version-in-file root "lisp/version.el" version
		       (rx (and "emacs-version" (0+ space)
				?\" (submatch (1+ (not (in ?\")))) ?\")))
  (set-version-in-file root "README" version
		       (rx (and "version" (1+ space)
				(submatch (1+ (in "0-9."))))))
  (set-version-in-file root "man/emacs.texi" version
		       (rx (and "EMACSVER" (1+ space)
				(submatch (1+ (in "0-9."))))))
  (set-version-in-file root "lispref/elisp.texi" version
		       (rx (and "EMACSVER" (1+ space)
				(submatch (1+ (in "0-9."))))))
  ;; nt/emacs.rc also contains the version number, but in an awkward
  ;; format. It must contain four components, separated by commas, and
  ;; in two places those commas are followed by space, in two other
  ;; places they are not.
  (let* ((version-components (append (split-string version "\\.")
				    '("0" "0")))
	 (comma-version
	  (concat (car version-components) ","
		  (cadr version-components) ","
		  (cadr (cdr version-components)) "," 
		  (cadr (cdr (cdr version-components)))))
	 (comma-space-version
	  (concat (car version-components) ", "
		  (cadr version-components) ", "
		  (cadr (cdr version-components)) ", " 
		  (cadr (cdr (cdr version-components))))))
    (set-version-in-file root "nt/emacs.rc" comma-version
			 (rx (and "FILEVERSION" (1+ space)
				  (submatch (1+ (in "0-9,"))))))
    (set-version-in-file root "nt/emacs.rc" comma-version
			 (rx (and "PRODUCTVERSION" (1+ space)
				  (submatch (1+ (in "0-9,"))))))
    (set-version-in-file root "nt/emacs.rc" comma-space-version
			 (rx (and "\"FileVersion\"" (0+ space) ?, (0+ space)
				  ?\" (submatch (1+ (in "0-9, "))) "\\0\"")))
    (set-version-in-file root "nt/emacs.rc" comma-space-version
			 (rx (and "\"ProductVersion\"" (0+ space) ?,
				  (0+ space) ?\" (submatch (1+ (in "0-9, ")))
				  "\\0\"")))))

;;; arch-tag: 4ea83636-2293-408b-884e-ad64f22a3bf5
;; admin.el ends here.