view lisp/url/url-ns.el @ 58229:7f5b01c17652

(math-integrate-by-parts): Removed unused variable var-thing. (math-integ-depth, math-integ-level, math-integral-limit) (math-enable-subst, math-any-substs, math-integ-msg) (math-prev-parts-v, math-good-parts, math-max-integral-limit) (math-int-threshold, math-int-factors, math-double-roots) (math-solve-simplifying, var-IntegLimit, math-solve-sign) (var-GenCount): Declared these variables. (calcFunc-integ): Don't check if var-IntegLimit is bound. (math-integral-cache, math-integral-cache-state): Move declarations to earlier in the file. (math-deriv-var, math-deriv-total, math-deriv-symb): New variables. (math-derivative, calcFunc-deriv, calcFunc-tderiv): Replace variables deriv-var, deriv-total and deriv-symb by declared variables math-deriv-var, math-deriv-total and math-deriv-symb. (math-cur-record): New variable. (math-integral, math-replace-integral-parts, math-integrate-by-parts) (calc-dump-integral-cache, math-try-integral): Replace variable cur-record by declared variable math-cur-record. (math-has-rules): New variable. (math-try-integral, math-do-integral): Use declared variable math-has-rules instead of has-rules. (math-t1, math-t2, math-t3): New variables. (math-do-integral, math-do-integral-methods, math-try-solve-for) (math-try-solve-prod, math-solve-poly-funny-powers) (math-solve-crunch-poly, math-decompose-poly) (math-solve-find-root-term, math-find-root-in-prod): Replace variables t1, t2, t3 by declared variables math-t1, math-t2, math-t3. (math-so-far, math-integ-expr): New variables. (math-do-integral-methods, math-integ-try-linear-substitutions) (math-integ-try-substitutions): Replace variables so-far and expr by declared variables math-so-far and math-integ-expr. (math-expr-parts): New variable. (math-expr-rational-in, math-expr-rational-in-rec): Replace variable parts by declared variable math-expr-parts. (calc-low, calc-high): New variables. (calcFunc-table, math-scan-for-limits): Replaced variable low and high with the declared variable calc-low and calc-high. (math-solve-var, math-solve-full): New variables. (math-try-solve-for, math-try-solve-prod, math-solve-prod) (math-decompose-poly, math-solve-quartic, math-poly-all-roots) (math-solve-find-root-in-prod, math-solve-for, math-solve-system) (math-solve-system-rec, math-solve-get-sign, math-solve-get-int): Replace variables solve-var and solve-full with declared variables math-solve-var and math-solve-full. (math-solve-vars): New variable. (math-solve-system, math-solve-system-rec): Replace variable solve-vars with declared variable math-solve-vars. (math-try-solve-sign): New variable. (math-try-solve-for, math-try-solve-prod): Replace variable sign by declared variable math-try-solve-sign. (math-solve-b): New variable. (math-solve-poly-funny-powers, math-decompose-poly): Replace variable b by declared variable math-solve-b. (math-solve-system-vv, math-solve-res): New variables (math-solve-system-rec, math-solve-system-subst): Replaced variables vv and res with declared variables math-solve-system-vv and math-solve-system-res.

;;; url-ns.el --- Various netscape-ish functions for proxy definitions

;; Copyright (c) 1997 - 1999 Free Software Foundation, Inc.

;; Keywords: comm, data, processes, hypermedia

;; This file is part of GNU Emacs.

;; GNU Emacs is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation; either version 2, or (at your option)
;; any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs; see the file COPYING.  If not, write to the
;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
;; Boston, MA 02111-1307, USA.

;;; Code:

(require 'url-gw)

;;;###autoload
(defun isPlainHostName (host)
  (not (string-match "\\." host)))

;;;###autoload
(defun dnsDomainIs (host dom)
  (string-match (concat (regexp-quote dom) "$") host))

;;;###autoload
(defun dnsResolve (host)
  (url-gateway-nslookup-host host))

;;;###autoload
(defun isResolvable (host)
  (if (string-match "^[0-9.]+$" host)
      t
    (not (string= host (url-gateway-nslookup-host host)))))

;;;###autoload
(defun isInNet (ip net mask)
  (let ((netc (split-string ip "\\."))
	(ipc  (split-string net "\\."))
	(maskc (split-string mask "\\.")))
    (if (or (/= (length netc) (length ipc))
	    (/= (length ipc) (length maskc)))
	nil
      (setq netc (mapcar 'string-to-int netc)
	    ipc (mapcar 'string-to-int ipc)
	    maskc (mapcar 'string-to-int maskc))
      (and
       (= (logand (nth 0 netc) (nth 0 maskc))
	  (logand (nth 0 ipc)  (nth 0 maskc)))
       (= (logand (nth 1 netc) (nth 1 maskc))
	  (logand (nth 1 ipc)  (nth 1 maskc)))
       (= (logand (nth 2 netc) (nth 2 maskc))
	  (logand (nth 2 ipc)  (nth 2 maskc)))
       (= (logand (nth 3 netc) (nth 3 maskc))
	  (logand (nth 3 ipc)  (nth 3 maskc)))))))

;; Netscape configuration file parsing
(defvar url-ns-user-prefs nil
  "Internal, do not use.")

;;;###autoload
(defun url-ns-prefs (&optional file)
  (if (not file)
      (setq file (expand-file-name "~/.netscape/preferences.js")))
  (if (not (and (file-exists-p file)
		(file-readable-p file)))
      (message "Could not open %s for reading" file)
    (save-excursion
      (let ((false nil)
	    (true t))
	(setq url-ns-user-prefs (make-hash-table :size 13 :test 'equal))
	(set-buffer (get-buffer-create " *ns-parse*"))
	(erase-buffer)
	(insert-file-contents file)
	(goto-char (point-min))
	(while (re-search-forward "^//" nil t)
	  (replace-match ";;"))
	(goto-char (point-min))
	(while (re-search-forward "^user_pref(" nil t)
	  (replace-match "(url-ns-set-user-pref "))
	(goto-char (point-min))
	(while (re-search-forward "\"," nil t)
	  (replace-match "\""))
	(goto-char (point-min))
	(eval-buffer)))))

(defun url-ns-set-user-pref (key val)
  (puthash key val url-ns-user-prefs))

;;;###autoload
(defun url-ns-user-pref (key &optional default)
  (gethash key url-ns-user-prefs default))

(provide 'url-ns)

;;; arch-tag: 69520992-cf97-40b4-9ad1-c866d3cae5bf
;;; url-ns.el ends here