view msdos/sedleim.inp @ 32678:816cfb30c5de

(Info-fontify-node): Add support for @subsubsection titles, which use `Info-title-4-face'. (Info-title-4-face): New face. (Info-title-3-face): Inherit from Info-title-4-face instead of variable-pitch.
author Miles Bader <miles@gnu.org>
date Fri, 20 Oct 2000 02:57:21 +0000
parents 62100be6ca6d
children a4fb0c9be609
line wrap: on
line source

# -sedleim.inp-----------------------------------------------------------
# Configuration script for leim/Makefile under DJGPP v2.x
# ----------------------------------------------------------------------
/^SHELL *=/c\
SHELL=/xyzzy/command\
MAKESHELL=/xyzzy/command

/^version=/d
/^prefix=/d
/^datadir=/s|@datadir@|../..|
/^srcdir=/s|@srcdir@|.|

/^INSTALLDIR=/c\
INSTALLDIR=.

/RUN-EMACS *=/,/^$/c\
export EMACSLOADPATH=${buildlisppath}\
RUN-EMACS = ${BUILT-EMACS} -batch --no-init-file --no-site-file --multibyte

/^	cd ../c\
	${MAKE} -C ../src ${MFLAGS} emacs

/else make quail/c\
	if not exist quail\\nul make quail

/^leim-list.el:/,/^$/ {
	/^	if/d
	/^	else/,/^	fi/d
	s|	 *|	|
	/^	--eval/,/; \\$/s|\; \\||
}

/^install:/,/^$/c\
install: all\

/^	if test -f/d